ssytrs_aa_2stage()

subroutine ssytrs_aa_2stage	(	character	UPLO,
		integer	N,
		integer	NRHS,
		real, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( * )	TB,
		integer	LTB,
		integer, dimension( * )	IPIV,
		integer, dimension( * )	IPIV2,
		real, dimension( ldb, * )	B,
		integer	LDB,
		integer	INFO
	)

SSYTRS_AA_2STAGE

Download SSYTRS_AA_2STAGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SSYTRS_AA_2STAGE solves a system of linear equations A*X = B with a real
 symmetric matrix A using the factorization A = U**T*T*U or
 A = L*T*L**T computed by SSYTRF_AA_2STAGE.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the details of the factorization are stored as an upper or lower triangular matrix. = 'U': Upper triangular, form is A = U**T*T*U; = 'L': Lower triangular, form is A = L*T*L**T.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.
[in]	A	A is REAL array, dimension (LDA,N) Details of factors computed by SSYTRF_AA_2STAGE.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	TB	TB is REAL array, dimension (LTB) Details of factors computed by SSYTRF_AA_2STAGE.
[in]	LTB	LTB is INTEGER The size of the array TB. LTB >= 4*N.
[in]	IPIV	IPIV is INTEGER array, dimension (N) Details of the interchanges as computed by SSYTRF_AA_2STAGE.
[in]	IPIV2	IPIV2 is INTEGER array, dimension (N) Details of the interchanges as computed by SSYTRF_AA_2STAGE.
[in,out]	B	B is REAL array, dimension (LDB,NRHS) On entry, the right hand side matrix B. On exit, the solution matrix X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2017

Definition at line 141 of file ssytrs_aa_2stage.f.

*
*  -- LAPACK computational routine (version 3.8.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2017
*
      IMPLICIT NONE
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            N, NRHS, LDA, LTB, LDB, INFO
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * ), IPIV2( * )
      REAL               A( LDA, * ), TB( * ), B( LDB, * )
*     ..
*
*  =====================================================================
*
      REAL               ONE
      parameter( one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            LDTB, NB
      LOGICAL            UPPER
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgbtrs, slaswp, strsm, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( nrhs.LT.0 ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( ltb.LT.( 4*n ) ) THEN
         info = -7
      ELSE IF( ldb.LT.max( 1, n ) ) THEN
         info = -11
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SSYTRS_AA_2STAGE', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. nrhs.EQ.0 )
     $   RETURN
*
*     Read NB and compute LDTB
*
      nb = int( tb( 1 ) )
      ldtb = ltb/n
*
      IF( upper ) THEN
*
*        Solve A*X = B, where A = U**T*T*U.
*
         IF( n.GT.nb ) THEN
*
*           Pivot, P**T * B -> B
*
            CALL slaswp( nrhs, b, ldb, nb+1, n, ipiv, 1 )
*
*           Compute (U**T \ B) -> B    [ (U**T \P**T * B) ]
*
            CALL strsm( 'L', 'U', 'T', 'U', n-nb, nrhs, one, a(1, nb+1),
     $                 lda, b(nb+1, 1), ldb)
*
         END IF
*
*        Compute T \ B -> B   [ T \ (U**T \P**T * B) ]
*
         CALL sgbtrs( 'N', n, nb, nb, nrhs, tb, ldtb, ipiv2, b, ldb,
     $               info)
         IF( n.GT.nb ) THEN
*
*           Compute (U \ B) -> B   [ U \ (T \ (U**T \P**T * B) ) ]
*
            CALL strsm( 'L', 'U', 'N', 'U', n-nb, nrhs, one, a(1, nb+1),
     $                  lda, b(nb+1, 1), ldb)
*
*           Pivot, P * B -> B  [ P * (U \ (T \ (U**T \P**T * B) )) ]
*
            CALL slaswp( nrhs, b, ldb, nb+1, n, ipiv, -1 )
*
         END IF
*
      ELSE
*
*        Solve A*X = B, where A = L*T*L**T.
*
         IF( n.GT.nb ) THEN
*
*           Pivot, P**T * B -> B
*
            CALL slaswp( nrhs, b, ldb, nb+1, n, ipiv, 1 )
*
*           Compute (L \ B) -> B    [ (L \P**T * B) ]
*
            CALL strsm( 'L', 'L', 'N', 'U', n-nb, nrhs, one, a(nb+1, 1),
     $                 lda, b(nb+1, 1), ldb)
*
         END IF
*
*        Compute T \ B -> B   [ T \ (L \P**T * B) ]
*
         CALL sgbtrs( 'N', n, nb, nb, nrhs, tb, ldtb, ipiv2, b, ldb,
     $               info)
         IF( n.GT.nb ) THEN
*
*           Compute (L**T \ B) -> B   [ L**T \ (T \ (L \P**T * B) ) ]
*
            CALL strsm( 'L', 'L', 'T', 'U', n-nb, nrhs, one, a(nb+1, 1),
     $                  lda, b(nb+1, 1), ldb)
*
*           Pivot, P * B -> B  [ P * (L**T \ (T \ (L \P**T * B) )) ]
*
            CALL slaswp( nrhs, b, ldb, nb+1, n, ipiv, -1 )
*
         END IF
      END IF
*
      RETURN
*
*     End of SSYTRS_AA_2STAGE
*

Here is the call graph for this function:

Here is the caller graph for this function: