◆ ssytrs()

subroutine ssytrs	(	character	UPLO,
		integer	N,
		integer	NRHS,
		real, dimension( lda, * )	A,
		integer	LDA,
		integer, dimension( * )	IPIV,
		real, dimension( ldb, * )	B,
		integer	LDB,
		integer	INFO
	)

SSYTRS

Download SSYTRS + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SSYTRS solves a system of linear equations A*X = B with a real
 symmetric matrix A using the factorization A = U*D*U**T or
 A = L*D*L**T computed by SSYTRF.

Parameters

[in]	UPLO	UPLO is CHARACTER1 Specifies whether the details of the factorization are stored as an upper or lower triangular matrix. = 'U': Upper triangular, form is A = UDUT; = 'L': Lower triangular, form is A = LDL*T.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.
[in]	A	A is REAL array, dimension (LDA,N) The block diagonal matrix D and the multipliers used to obtain the factor U or L as computed by SSYTRF.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	IPIV	IPIV is INTEGER array, dimension (N) Details of the interchanges and the block structure of D as determined by SSYTRF.
[in,out]	B	B is REAL array, dimension (LDB,NRHS) On entry, the right hand side matrix B. On exit, the solution matrix X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Date: December 2016

Definition at line 122 of file ssytrs.f.

 *
 *  -- LAPACK computational routine (version 3.7.0) --
 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 *     December 2016
 *
 *     .. Scalar Arguments ..
       CHARACTER          UPLO
       INTEGER            INFO, LDA, LDB, N, NRHS
 *     ..
 *     .. Array Arguments ..
       INTEGER            IPIV( * )
       REAL               A( LDA, * ), B( LDB, * )
 *     ..
 *
 *  =====================================================================
 *
 *     .. Parameters ..
       REAL               ONE
       parameter( one = 1.0e+0 )
 *     ..
 *     .. Local Scalars ..
       LOGICAL            UPPER
       INTEGER            J, K, KP
       REAL               AK, AKM1, AKM1K, BK, BKM1, DENOM
 *     ..
 *     .. External Functions ..
       LOGICAL            LSAME
       EXTERNAL           lsame
 *     ..
 *     .. External Subroutines ..
       EXTERNAL           sgemv, sger, sscal, sswap, xerbla
 *     ..
 *     .. Intrinsic Functions ..
       INTRINSIC          max
 *     ..
 *     .. Executable Statements ..
 *
       info = 0
       upper = lsame( uplo, 'U' )
       IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
          info = -1
       ELSE IF( n.LT.0 ) THEN
          info = -2
       ELSE IF( nrhs.LT.0 ) THEN
          info = -3
       ELSE IF( lda.LT.max( 1, n ) ) THEN
          info = -5
       ELSE IF( ldb.LT.max( 1, n ) ) THEN
          info = -8
       END IF
       IF( info.NE.0 ) THEN
          CALL xerbla( 'SSYTRS', -info )
          RETURN
       END IF
 *
 *     Quick return if possible
 *
       IF( n.EQ.0 .OR. nrhs.EQ.0 )
      $   RETURN
 *
       IF( upper ) THEN
 *
 *        Solve A*X = B, where A = U*D*U**T.
 *
 *        First solve U*D*X = B, overwriting B with X.
 *
 *        K is the main loop index, decreasing from N to 1 in steps of
 *        1 or 2, depending on the size of the diagonal blocks.
 *
          k = n
    10    CONTINUE
 *
 *        If K < 1, exit from loop.
 *
          IF( k.LT.1 )
      $      GO TO 30
 *
          IF( ipiv( k ).GT.0 ) THEN
 *
 *           1 x 1 diagonal block
 *
 *           Interchange rows K and IPIV(K).
 *
             kp = ipiv( k )
             IF( kp.NE.k )
      $         CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
 *
 *           Multiply by inv(U(K)), where U(K) is the transformation
 *           stored in column K of A.
 *
             CALL sger( k-1, nrhs, -one, a( 1, k ), 1, b( k, 1 ), ldb,
      $                 b( 1, 1 ), ldb )
 *
 *           Multiply by the inverse of the diagonal block.
 *
             CALL sscal( nrhs, one / a( k, k ), b( k, 1 ), ldb )
             k = k - 1
          ELSE
 *
 *           2 x 2 diagonal block
 *
 *           Interchange rows K-1 and -IPIV(K).
 *
             kp = -ipiv( k )
             IF( kp.NE.k-1 )
      $         CALL sswap( nrhs, b( k-1, 1 ), ldb, b( kp, 1 ), ldb )
 *
 *           Multiply by inv(U(K)), where U(K) is the transformation
 *           stored in columns K-1 and K of A.
 *
             CALL sger( k-2, nrhs, -one, a( 1, k ), 1, b( k, 1 ), ldb,
      $                 b( 1, 1 ), ldb )
             CALL sger( k-2, nrhs, -one, a( 1, k-1 ), 1, b( k-1, 1 ),
      $                 ldb, b( 1, 1 ), ldb )
 *
 *           Multiply by the inverse of the diagonal block.
 *
             akm1k = a( k-1, k )
             akm1 = a( k-1, k-1 ) / akm1k
             ak = a( k, k ) / akm1k
             denom = akm1*ak - one
             DO 20 j = 1, nrhs
                bkm1 = b( k-1, j ) / akm1k
                bk = b( k, j ) / akm1k
                b( k-1, j ) = ( ak*bkm1-bk ) / denom
                b( k, j ) = ( akm1*bk-bkm1 ) / denom
    20       CONTINUE
             k = k - 2
          END IF
 *
          GO TO 10
    30    CONTINUE
 *
 *        Next solve U**T *X = B, overwriting B with X.
 *
 *        K is the main loop index, increasing from 1 to N in steps of
 *        1 or 2, depending on the size of the diagonal blocks.
 *
          k = 1
    40    CONTINUE
 *
 *        If K > N, exit from loop.
 *
          IF( k.GT.n )
      $      GO TO 50
 *
          IF( ipiv( k ).GT.0 ) THEN
 *
 *           1 x 1 diagonal block
 *
 *           Multiply by inv(U**T(K)), where U(K) is the transformation
 *           stored in column K of A.
 *
             CALL sgemv( 'Transpose', k-1, nrhs, -one, b, ldb, a( 1, k ),
      $                  1, one, b( k, 1 ), ldb )
 *
 *           Interchange rows K and IPIV(K).
 *
             kp = ipiv( k )
             IF( kp.NE.k )
      $         CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
             k = k + 1
          ELSE
 *
 *           2 x 2 diagonal block
 *
 *           Multiply by inv(U**T(K+1)), where U(K+1) is the transformation
 *           stored in columns K and K+1 of A.
 *
             CALL sgemv( 'Transpose', k-1, nrhs, -one, b, ldb, a( 1, k ),
      $                  1, one, b( k, 1 ), ldb )
             CALL sgemv( 'Transpose', k-1, nrhs, -one, b, ldb,
      $                  a( 1, k+1 ), 1, one, b( k+1, 1 ), ldb )
 *
 *           Interchange rows K and -IPIV(K).
 *
             kp = -ipiv( k )
             IF( kp.NE.k )
      $         CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
             k = k + 2
          END IF
 *
          GO TO 40
    50    CONTINUE
 *
       ELSE
 *
 *        Solve A*X = B, where A = L*D*L**T.
 *
 *        First solve L*D*X = B, overwriting B with X.
 *
 *        K is the main loop index, increasing from 1 to N in steps of
 *        1 or 2, depending on the size of the diagonal blocks.
 *
          k = 1
    60    CONTINUE
 *
 *        If K > N, exit from loop.
 *
          IF( k.GT.n )
      $      GO TO 80
 *
          IF( ipiv( k ).GT.0 ) THEN
 *
 *           1 x 1 diagonal block
 *
 *           Interchange rows K and IPIV(K).
 *
             kp = ipiv( k )
             IF( kp.NE.k )
      $         CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
 *
 *           Multiply by inv(L(K)), where L(K) is the transformation
 *           stored in column K of A.
 *
             IF( k.LT.n )
      $         CALL sger( n-k, nrhs, -one, a( k+1, k ), 1, b( k, 1 ),
      $                    ldb, b( k+1, 1 ), ldb )
 *
 *           Multiply by the inverse of the diagonal block.
 *
             CALL sscal( nrhs, one / a( k, k ), b( k, 1 ), ldb )
             k = k + 1
          ELSE
 *
 *           2 x 2 diagonal block
 *
 *           Interchange rows K+1 and -IPIV(K).
 *
             kp = -ipiv( k )
             IF( kp.NE.k+1 )
      $         CALL sswap( nrhs, b( k+1, 1 ), ldb, b( kp, 1 ), ldb )
 *
 *           Multiply by inv(L(K)), where L(K) is the transformation
 *           stored in columns K and K+1 of A.
 *
             IF( k.LT.n-1 ) THEN
                CALL sger( n-k-1, nrhs, -one, a( k+2, k ), 1, b( k, 1 ),
      $                    ldb, b( k+2, 1 ), ldb )
                CALL sger( n-k-1, nrhs, -one, a( k+2, k+1 ), 1,
      $                    b( k+1, 1 ), ldb, b( k+2, 1 ), ldb )
             END IF
 *
 *           Multiply by the inverse of the diagonal block.
 *
             akm1k = a( k+1, k )
             akm1 = a( k, k ) / akm1k
             ak = a( k+1, k+1 ) / akm1k
             denom = akm1*ak - one
             DO 70 j = 1, nrhs
                bkm1 = b( k, j ) / akm1k
                bk = b( k+1, j ) / akm1k
                b( k, j ) = ( ak*bkm1-bk ) / denom
                b( k+1, j ) = ( akm1*bk-bkm1 ) / denom
    70       CONTINUE
             k = k + 2
          END IF
 *
          GO TO 60
    80    CONTINUE
 *
 *        Next solve L**T *X = B, overwriting B with X.
 *
 *        K is the main loop index, decreasing from N to 1 in steps of
 *        1 or 2, depending on the size of the diagonal blocks.
 *
          k = n
    90    CONTINUE
 *
 *        If K < 1, exit from loop.
 *
          IF( k.LT.1 )
      $      GO TO 100
 *
          IF( ipiv( k ).GT.0 ) THEN
 *
 *           1 x 1 diagonal block
 *
 *           Multiply by inv(L**T(K)), where L(K) is the transformation
 *           stored in column K of A.
 *
             IF( k.LT.n )
      $         CALL sgemv( 'Transpose', n-k, nrhs, -one, b( k+1, 1 ),
      $                     ldb, a( k+1, k ), 1, one, b( k, 1 ), ldb )
 *
 *           Interchange rows K and IPIV(K).
 *
             kp = ipiv( k )
             IF( kp.NE.k )
      $         CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
             k = k - 1
          ELSE
 *
 *           2 x 2 diagonal block
 *
 *           Multiply by inv(L**T(K-1)), where L(K-1) is the transformation
 *           stored in columns K-1 and K of A.
 *
             IF( k.LT.n ) THEN
                CALL sgemv( 'Transpose', n-k, nrhs, -one, b( k+1, 1 ),
      $                     ldb, a( k+1, k ), 1, one, b( k, 1 ), ldb )
                CALL sgemv( 'Transpose', n-k, nrhs, -one, b( k+1, 1 ),
      $                     ldb, a( k+1, k-1 ), 1, one, b( k-1, 1 ),
      $                     ldb )
             END IF
 *
 *           Interchange rows K and -IPIV(K).
 *
             kp = -ipiv( k )
             IF( kp.NE.k )
      $         CALL sswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
             k = k - 2
          END IF
 *
          GO TO 90
   100    CONTINUE
       END IF
 *
       RETURN
 *
 *     End of SSYTRS
 *

Here is the call graph for this function:

Here is the caller graph for this function: