LAPACK  3.9.0
LAPACK: Linear Algebra PACKage

◆ ssytrd_2stage()

subroutine ssytrd_2stage ( character  VECT,
character  UPLO,
integer  N,
real, dimension( lda, * )  A,
integer  LDA,
real, dimension( * )  D,
real, dimension( * )  E,
real, dimension( * )  TAU,
real, dimension( * )  HOUS2,
integer  LHOUS2,
real, dimension( * )  WORK,
integer  LWORK,
integer  INFO 
)

SSYTRD_2STAGE

Download SSYTRD_2STAGE + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 SSYTRD_2STAGE reduces a real symmetric matrix A to real symmetric
 tridiagonal form T by a orthogonal similarity transformation:
 Q1**T Q2**T* A * Q2 * Q1 = T.
Parameters
[in]VECT
          VECT is CHARACTER*1
          = 'N':  No need for the Housholder representation, 
                  in particular for the second stage (Band to
                  tridiagonal) and thus LHOUS2 is of size max(1, 4*N);
          = 'V':  the Householder representation is needed to 
                  either generate Q1 Q2 or to apply Q1 Q2, 
                  then LHOUS2 is to be queried and computed.
                  (NOT AVAILABLE IN THIS RELEASE).
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  Upper triangle of A is stored;
          = 'L':  Lower triangle of A is stored.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in,out]A
          A is REAL array, dimension (LDA,N)
          On entry, the symmetric matrix A.  If UPLO = 'U', the leading
          N-by-N upper triangular part of A contains the upper
          triangular part of the matrix A, and the strictly lower
          triangular part of A is not referenced.  If UPLO = 'L', the
          leading N-by-N lower triangular part of A contains the lower
          triangular part of the matrix A, and the strictly upper
          triangular part of A is not referenced.
          On exit, if UPLO = 'U', the band superdiagonal
          of A are overwritten by the corresponding elements of the
          internal band-diagonal matrix AB, and the elements above 
          the KD superdiagonal, with the array TAU, represent the orthogonal
          matrix Q1 as a product of elementary reflectors; if UPLO
          = 'L', the diagonal and band subdiagonal of A are over-
          written by the corresponding elements of the internal band-diagonal
          matrix AB, and the elements below the KD subdiagonal, with
          the array TAU, represent the orthogonal matrix Q1 as a product
          of elementary reflectors. See Further Details.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[out]D
          D is REAL array, dimension (N)
          The diagonal elements of the tridiagonal matrix T.
[out]E
          E is REAL array, dimension (N-1)
          The off-diagonal elements of the tridiagonal matrix T.
[out]TAU
          TAU is REAL array, dimension (N-KD)
          The scalar factors of the elementary reflectors of 
          the first stage (see Further Details).
[out]HOUS2
          HOUS2 is REAL array, dimension (LHOUS2)
          Stores the Householder representation of the stage2
          band to tridiagonal.
[in]LHOUS2
          LHOUS2 is INTEGER
          The dimension of the array HOUS2.
          If LWORK = -1, or LHOUS2 = -1,
          then a query is assumed; the routine
          only calculates the optimal size of the HOUS2 array, returns
          this value as the first entry of the HOUS2 array, and no error
          message related to LHOUS2 is issued by XERBLA.
          If VECT='N', LHOUS2 = max(1, 4*n);
          if VECT='V', option not yet available.
[out]WORK
          WORK is REAL array, dimension (LWORK)
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK. LWORK = MAX(1, dimension)
          If LWORK = -1, or LHOUS2=-1,
          then a workspace query is assumed; the routine
          only calculates the optimal size of the WORK array, returns
          this value as the first entry of the WORK array, and no error
          message related to LWORK is issued by XERBLA.
          LWORK = MAX(1, dimension) where
          dimension   = max(stage1,stage2) + (KD+1)*N
                      = N*KD + N*max(KD+1,FACTOPTNB) 
                        + max(2*KD*KD, KD*NTHREADS) 
                        + (KD+1)*N 
          where KD is the blocking size of the reduction,
          FACTOPTNB is the blocking used by the QR or LQ
          algorithm, usually FACTOPTNB=128 is a good choice
          NTHREADS is the number of threads used when
          openMP compilation is enabled, otherwise =1.
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
November 2017
Further Details:
  Implemented by Azzam Haidar.

  All details are available on technical report, SC11, SC13 papers.

  Azzam Haidar, Hatem Ltaief, and Jack Dongarra.
  Parallel reduction to condensed forms for symmetric eigenvalue problems
  using aggregated fine-grained and memory-aware kernels. In Proceedings
  of 2011 International Conference for High Performance Computing,
  Networking, Storage and Analysis (SC '11), New York, NY, USA,
  Article 8 , 11 pages.
  http://doi.acm.org/10.1145/2063384.2063394

  A. Haidar, J. Kurzak, P. Luszczek, 2013.
  An improved parallel singular value algorithm and its implementation 
  for multicore hardware, In Proceedings of 2013 International Conference
  for High Performance Computing, Networking, Storage and Analysis (SC '13).
  Denver, Colorado, USA, 2013.
  Article 90, 12 pages.
  http://doi.acm.org/10.1145/2503210.2503292

  A. Haidar, R. Solca, S. Tomov, T. Schulthess and J. Dongarra.
  A novel hybrid CPU-GPU generalized eigensolver for electronic structure 
  calculations based on fine-grained memory aware tasks.
  International Journal of High Performance Computing Applications.
  Volume 28 Issue 2, Pages 196-209, May 2014.
  http://hpc.sagepub.com/content/28/2/196

Definition at line 226 of file ssytrd_2stage.f.

226 *
227  IMPLICIT NONE
228 *
229 * -- LAPACK computational routine (version 3.8.0) --
230 * -- LAPACK is a software package provided by Univ. of Tennessee, --
231 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
232 * November 2017
233 *
234 * .. Scalar Arguments ..
235  CHARACTER VECT, UPLO
236  INTEGER N, LDA, LWORK, LHOUS2, INFO
237 * ..
238 * .. Array Arguments ..
239  REAL D( * ), E( * )
240  REAL A( LDA, * ), TAU( * ),
241  $ HOUS2( * ), WORK( * )
242 * ..
243 *
244 * =====================================================================
245 * ..
246 * .. Local Scalars ..
247  LOGICAL LQUERY, UPPER, WANTQ
248  INTEGER KD, IB, LWMIN, LHMIN, LWRK, LDAB, WPOS, ABPOS
249 * ..
250 * .. External Subroutines ..
251  EXTERNAL xerbla, ssytrd_sy2sb, ssytrd_sb2st
252 * ..
253 * .. External Functions ..
254  LOGICAL LSAME
255  INTEGER ILAENV2STAGE
256  EXTERNAL lsame, ilaenv2stage
257 * ..
258 * .. Executable Statements ..
259 *
260 * Test the input parameters
261 *
262  info = 0
263  wantq = lsame( vect, 'V' )
264  upper = lsame( uplo, 'U' )
265  lquery = ( lwork.EQ.-1 ) .OR. ( lhous2.EQ.-1 )
266 *
267 * Determine the block size, the workspace size and the hous size.
268 *
269  kd = ilaenv2stage( 1, 'SSYTRD_2STAGE', vect, n, -1, -1, -1 )
270  ib = ilaenv2stage( 2, 'SSYTRD_2STAGE', vect, n, kd, -1, -1 )
271  lhmin = ilaenv2stage( 3, 'SSYTRD_2STAGE', vect, n, kd, ib, -1 )
272  lwmin = ilaenv2stage( 4, 'SSYTRD_2STAGE', vect, n, kd, ib, -1 )
273 * WRITE(*,*),'SSYTRD_2STAGE N KD UPLO LHMIN LWMIN ',N, KD, UPLO,
274 * $ LHMIN, LWMIN
275 *
276  IF( .NOT.lsame( vect, 'N' ) ) THEN
277  info = -1
278  ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
279  info = -2
280  ELSE IF( n.LT.0 ) THEN
281  info = -3
282  ELSE IF( lda.LT.max( 1, n ) ) THEN
283  info = -5
284  ELSE IF( lhous2.LT.lhmin .AND. .NOT.lquery ) THEN
285  info = -10
286  ELSE IF( lwork.LT.lwmin .AND. .NOT.lquery ) THEN
287  info = -12
288  END IF
289 *
290  IF( info.EQ.0 ) THEN
291  hous2( 1 ) = lhmin
292  work( 1 ) = lwmin
293  END IF
294 *
295  IF( info.NE.0 ) THEN
296  CALL xerbla( 'SSYTRD_2STAGE', -info )
297  RETURN
298  ELSE IF( lquery ) THEN
299  RETURN
300  END IF
301 *
302 * Quick return if possible
303 *
304  IF( n.EQ.0 ) THEN
305  work( 1 ) = 1
306  RETURN
307  END IF
308 *
309 * Determine pointer position
310 *
311  ldab = kd+1
312  lwrk = lwork-ldab*n
313  abpos = 1
314  wpos = abpos + ldab*n
315  CALL ssytrd_sy2sb( uplo, n, kd, a, lda, work( abpos ), ldab,
316  $ tau, work( wpos ), lwrk, info )
317  IF( info.NE.0 ) THEN
318  CALL xerbla( 'SSYTRD_SY2SB', -info )
319  RETURN
320  END IF
321  CALL ssytrd_sb2st( 'Y', vect, uplo, n, kd,
322  $ work( abpos ), ldab, d, e,
323  $ hous2, lhous2, work( wpos ), lwrk, info )
324  IF( info.NE.0 ) THEN
325  CALL xerbla( 'SSYTRD_SB2ST', -info )
326  RETURN
327  END IF
328 *
329 *
330  hous2( 1 ) = lhmin
331  work( 1 ) = lwmin
332  RETURN
333 *
334 * End of SSYTRD_2STAGE
335 *
Here is the call graph for this function:
Here is the caller graph for this function:
ssytrd_sy2sb
subroutine ssytrd_sy2sb(UPLO, N, KD, A, LDA, AB, LDAB, TAU, WORK, LWORK, INFO)
SSYTRD_SY2SB
Definition: ssytrd_sy2sb.f:245
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
lsame
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
ssytrd_sb2st
subroutine ssytrd_sb2st(STAGE1, VECT, UPLO, N, KD, AB, LDAB, D, E, HOUS, LHOUS, WORK, LWORK, INFO)
SSYTRD_SB2ST reduces a real symmetric band matrix A to real symmetric tridiagonal form T
Definition: ssytrd_sb2st.F:232
ilaenv2stage
integer function ilaenv2stage(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV2STAGE
Definition: ilaenv2stage.f:151