zlarcm()

subroutine zlarcm	(	integer	M,
		integer	N,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		complex*16, dimension( ldb, * )	B,
		integer	LDB,
		complex*16, dimension( ldc, * )	C,
		integer	LDC,
		double precision, dimension( * )	RWORK
	)

ZLARCM copies all or part of a real two-dimensional array to a complex array.

Download ZLARCM + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLARCM performs a very simple matrix-matrix multiplication:
          C := A * B,
 where A is M by M and real; B is M by N and complex;
 C is M by N and complex.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A and of the matrix C. M >= 0.
[in]	N	N is INTEGER The number of columns and rows of the matrix B and the number of columns of the matrix C. N >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA, M) On entry, A contains the M by M matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >=max(1,M).
[in]	B	B is COMPLEX*16 array, dimension (LDB, N) On entry, B contains the M by N matrix B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >=max(1,M).
[out]	C	C is COMPLEX*16 array, dimension (LDC, N) On exit, C contains the M by N matrix C.
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >=max(1,M).
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (2*M*N)

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

June 2016

Definition at line 116 of file zlarcm.f.

*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     June 2016
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, LDC, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), RWORK( * )
      COMPLEX*16         B( LDB, * ), C( LDC, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d0, zero = 0.0d0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, L
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, dimag
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible.
*
      IF( ( m.EQ.0 ) .OR. ( n.EQ.0 ) )
     $   RETURN
*
      DO 20 j = 1, n
         DO 10 i = 1, m
            rwork( ( j-1 )*m+i ) = dble( b( i, j ) )
   10    CONTINUE
   20 CONTINUE
*
      l = m*n + 1
      CALL dgemm( 'N', 'N', m, n, m, one, a, lda, rwork, m, zero,
     $            rwork( l ), m )
      DO 40 j = 1, n
         DO 30 i = 1, m
            c( i, j ) = rwork( l+( j-1 )*m+i-1 )
   30    CONTINUE
   40 CONTINUE
*
      DO 60 j = 1, n
         DO 50 i = 1, m
            rwork( ( j-1 )*m+i ) = dimag( b( i, j ) )
   50    CONTINUE
   60 CONTINUE
      CALL dgemm( 'N', 'N', m, n, m, one, a, lda, rwork, m, zero,
     $            rwork( l ), m )
      DO 80 j = 1, n
         DO 70 i = 1, m
            c( i, j ) = dcmplx( dble( c( i, j ) ),
     $                  rwork( l+( j-1 )*m+i-1 ) )
   70    CONTINUE
   80 CONTINUE
*
      RETURN
*
*     End of ZLARCM
*

Here is the call graph for this function:

Here is the caller graph for this function: