zlahr2()

subroutine zlahr2	(	integer	N,
		integer	K,
		integer	NB,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		complex*16, dimension( nb )	TAU,
		complex*16, dimension( ldt, nb )	T,
		integer	LDT,
		complex*16, dimension( ldy, nb )	Y,
		integer	LDY
	)

ZLAHR2 reduces the specified number of first columns of a general rectangular matrix A so that elements below the specified subdiagonal are zero, and returns auxiliary matrices which are needed to apply the transformation to the unreduced part of A.

Download ZLAHR2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLAHR2 reduces the first NB columns of A complex general n-BY-(n-k+1)
 matrix A so that elements below the k-th subdiagonal are zero. The
 reduction is performed by an unitary similarity transformation
 Q**H * A * Q. The routine returns the matrices V and T which determine
 Q as a block reflector I - V*T*V**H, and also the matrix Y = A * V * T.

 This is an auxiliary routine called by ZGEHRD.

Parameters

[in]	N	N is INTEGER The order of the matrix A.
[in]	K	K is INTEGER The offset for the reduction. Elements below the k-th subdiagonal in the first NB columns are reduced to zero. K < N.
[in]	NB	NB is INTEGER The number of columns to be reduced.
[in,out]	A	A is COMPLEX*16 array, dimension (LDA,N-K+1) On entry, the n-by-(n-k+1) general matrix A. On exit, the elements on and above the k-th subdiagonal in the first NB columns are overwritten with the corresponding elements of the reduced matrix; the elements below the k-th subdiagonal, with the array TAU, represent the matrix Q as a product of elementary reflectors. The other columns of A are unchanged. See Further Details.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	TAU	TAU is COMPLEX*16 array, dimension (NB) The scalar factors of the elementary reflectors. See Further Details.
[out]	T	T is COMPLEX*16 array, dimension (LDT,NB) The upper triangular matrix T.
[in]	LDT	LDT is INTEGER The leading dimension of the array T. LDT >= NB.
[out]	Y	Y is COMPLEX*16 array, dimension (LDY,NB) The n-by-nb matrix Y.
[in]	LDY	LDY is INTEGER The leading dimension of the array Y. LDY >= N.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Further Details:

  The matrix Q is represented as a product of nb elementary reflectors

     Q = H(1) H(2) . . . H(nb).

  Each H(i) has the form

     H(i) = I - tau * v * v**H

  where tau is a complex scalar, and v is a complex vector with
  v(1:i+k-1) = 0, v(i+k) = 1; v(i+k+1:n) is stored on exit in
  A(i+k+1:n,i), and tau in TAU(i).

  The elements of the vectors v together form the (n-k+1)-by-nb matrix
  V which is needed, with T and Y, to apply the transformation to the
  unreduced part of the matrix, using an update of the form:
  A := (I - V*T*V**H) * (A - Y*V**H).

  The contents of A on exit are illustrated by the following example
  with n = 7, k = 3 and nb = 2:

     ( a   a   a   a   a )
     ( a   a   a   a   a )
     ( a   a   a   a   a )
     ( h   h   a   a   a )
     ( v1  h   a   a   a )
     ( v1  v2  a   a   a )
     ( v1  v2  a   a   a )

  where a denotes an element of the original matrix A, h denotes a
  modified element of the upper Hessenberg matrix H, and vi denotes an
  element of the vector defining H(i).

  This subroutine is a slight modification of LAPACK-3.0's DLAHRD
  incorporating improvements proposed by Quintana-Orti and Van de
  Gejin. Note that the entries of A(1:K,2:NB) differ from those
  returned by the original LAPACK-3.0's DLAHRD routine. (This
  subroutine is not backward compatible with LAPACK-3.0's DLAHRD.)

References:

Gregorio Quintana-Orti and Robert van de Geijn, "Improving the performance of reduction to Hessenberg form," ACM Transactions on Mathematical Software, 32(2):180-194, June 2006.

Definition at line 183 of file zlahr2.f.

*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LDT, LDY, N, NB
*     ..
*     .. Array Arguments ..
      COMPLEX*16        A( LDA, * ), T( LDT, NB ), TAU( NB ),
     $                   Y( LDY, NB )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16        ZERO, ONE
      parameter( zero = ( 0.0d+0, 0.0d+0 ),
     $                     one = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I
      COMPLEX*16        EI
*     ..
*     .. External Subroutines ..
      EXTERNAL           zaxpy, zcopy, zgemm, zgemv, zlacpy,
     $                   zlarfg, zscal, ztrmm, ztrmv, zlacgv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( n.LE.1 )
     $   RETURN
*
      DO 10 i = 1, nb
         IF( i.GT.1 ) THEN
*
*           Update A(K+1:N,I)
*
*           Update I-th column of A - Y * V**H
*
            CALL zlacgv( i-1, a( k+i-1, 1 ), lda )
            CALL zgemv( 'NO TRANSPOSE', n-k, i-1, -one, y(k+1,1), ldy,
     $                  a( k+i-1, 1 ), lda, one, a( k+1, i ), 1 )
            CALL zlacgv( i-1, a( k+i-1, 1 ), lda )
*
*           Apply I - V * T**H * V**H to this column (call it b) from the
*           left, using the last column of T as workspace
*
*           Let  V = ( V1 )   and   b = ( b1 )   (first I-1 rows)
*                    ( V2 )             ( b2 )
*
*           where V1 is unit lower triangular
*
*           w := V1**H * b1
*
            CALL zcopy( i-1, a( k+1, i ), 1, t( 1, nb ), 1 )
            CALL ztrmv( 'Lower', 'Conjugate transpose', 'UNIT',
     $                  i-1, a( k+1, 1 ),
     $                  lda, t( 1, nb ), 1 )
*
*           w := w + V2**H * b2
*
            CALL zgemv( 'Conjugate transpose', n-k-i+1, i-1,
     $                  one, a( k+i, 1 ),
     $                  lda, a( k+i, i ), 1, one, t( 1, nb ), 1 )
*
*           w := T**H * w
*
            CALL ztrmv( 'Upper', 'Conjugate transpose', 'NON-UNIT',
     $                  i-1, t, ldt,
     $                  t( 1, nb ), 1 )
*
*           b2 := b2 - V2*w
*
            CALL zgemv( 'NO TRANSPOSE', n-k-i+1, i-1, -one,
     $                  a( k+i, 1 ),
     $                  lda, t( 1, nb ), 1, one, a( k+i, i ), 1 )
*
*           b1 := b1 - V1*w
*
            CALL ztrmv( 'Lower', 'NO TRANSPOSE',
     $                  'UNIT', i-1,
     $                  a( k+1, 1 ), lda, t( 1, nb ), 1 )
            CALL zaxpy( i-1, -one, t( 1, nb ), 1, a( k+1, i ), 1 )
*
            a( k+i-1, i-1 ) = ei
         END IF
*
*        Generate the elementary reflector H(I) to annihilate
*        A(K+I+1:N,I)
*
         CALL zlarfg( n-k-i+1, a( k+i, i ), a( min( k+i+1, n ), i ), 1,
     $                tau( i ) )
         ei = a( k+i, i )
         a( k+i, i ) = one
*
*        Compute  Y(K+1:N,I)
*
         CALL zgemv( 'NO TRANSPOSE', n-k, n-k-i+1,
     $               one, a( k+1, i+1 ),
     $               lda, a( k+i, i ), 1, zero, y( k+1, i ), 1 )
         CALL zgemv( 'Conjugate transpose', n-k-i+1, i-1,
     $               one, a( k+i, 1 ), lda,
     $               a( k+i, i ), 1, zero, t( 1, i ), 1 )
         CALL zgemv( 'NO TRANSPOSE', n-k, i-1, -one,
     $               y( k+1, 1 ), ldy,
     $               t( 1, i ), 1, one, y( k+1, i ), 1 )
         CALL zscal( n-k, tau( i ), y( k+1, i ), 1 )
*
*        Compute T(1:I,I)
*
         CALL zscal( i-1, -tau( i ), t( 1, i ), 1 )
         CALL ztrmv( 'Upper', 'No Transpose', 'NON-UNIT',
     $               i-1, t, ldt,
     $               t( 1, i ), 1 )
         t( i, i ) = tau( i )
*
   10 CONTINUE
      a( k+nb, nb ) = ei
*
*     Compute Y(1:K,1:NB)
*
      CALL zlacpy( 'ALL', k, nb, a( 1, 2 ), lda, y, ldy )
      CALL ztrmm( 'RIGHT', 'Lower', 'NO TRANSPOSE',
     $            'UNIT', k, nb,
     $            one, a( k+1, 1 ), lda, y, ldy )
      IF( n.GT.k+nb )
     $   CALL zgemm( 'NO TRANSPOSE', 'NO TRANSPOSE', k,
     $               nb, n-k-nb, one,
     $               a( 1, 2+nb ), lda, a( k+1+nb, 1 ), lda, one, y,
     $               ldy )
      CALL ztrmm( 'RIGHT', 'Upper', 'NO TRANSPOSE',
     $            'NON-UNIT', k, nb,
     $            one, t, ldt, y, ldy )
*
      RETURN
*
*     End of ZLAHR2
*

Here is the call graph for this function:

Here is the caller graph for this function: