zlat2c()

subroutine zlat2c	(	character	UPLO,
		integer	N,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		complex, dimension( ldsa, * )	SA,
		integer	LDSA,
		integer	INFO
	)

ZLAT2C converts a double complex triangular matrix to a complex triangular matrix.

Download ZLAT2C + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLAT2C converts a COMPLEX*16 triangular matrix, SA, to a COMPLEX
 triangular matrix, A.

 RMAX is the overflow for the SINGLE PRECISION arithmetic
 ZLAT2C checks that all the entries of A are between -RMAX and
 RMAX. If not the conversion is aborted and a flag is raised.

 This is an auxiliary routine so there is no argument checking.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': A is upper triangular; = 'L': A is lower triangular.
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) On entry, the N-by-N triangular coefficient matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	SA	SA is COMPLEX array, dimension (LDSA,N) Only the UPLO part of SA is referenced. On exit, if INFO=0, the N-by-N coefficient matrix SA; if INFO>0, the content of the UPLO part of SA is unspecified.
[in]	LDSA	LDSA is INTEGER The leading dimension of the array SA. LDSA >= max(1,M).
[out]	INFO	INFO is INTEGER = 0: successful exit. = 1: an entry of the matrix A is greater than the SINGLE PRECISION overflow threshold, in this case, the content of the UPLO part of SA in exit is unspecified.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 113 of file zlat2c.f.

*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, LDSA, N
*     ..
*     .. Array Arguments ..
      COMPLEX            SA( LDSA, * )
      COMPLEX*16         A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, J
      DOUBLE PRECISION   RMAX
      LOGICAL            UPPER
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dimag
*     ..
*     .. External Functions ..
      REAL               SLAMCH
      LOGICAL            LSAME
      EXTERNAL           slamch, lsame
*     ..
*     .. Executable Statements ..
*
      rmax = slamch( 'O' )
      upper = lsame( uplo, 'U' )
      IF( upper ) THEN
         DO 20 j = 1, n
            DO 10 i = 1, j
               IF( ( dble( a( i, j ) ).LT.-rmax ) .OR.
     $             ( dble( a( i, j ) ).GT.rmax ) .OR.
     $             ( dimag( a( i, j ) ).LT.-rmax ) .OR.
     $             ( dimag( a( i, j ) ).GT.rmax ) ) THEN
                  info = 1
                  GO TO 50
               END IF
               sa( i, j ) = a( i, j )
   10       CONTINUE
   20    CONTINUE
      ELSE
         DO 40 j = 1, n
            DO 30 i = j, n
               IF( ( dble( a( i, j ) ).LT.-rmax ) .OR.
     $             ( dble( a( i, j ) ).GT.rmax ) .OR.
     $             ( dimag( a( i, j ) ).LT.-rmax ) .OR.
     $             ( dimag( a( i, j ) ).GT.rmax ) ) THEN
                  info = 1
                  GO TO 50
               END IF
               sa( i, j ) = a( i, j )
   30       CONTINUE
   40    CONTINUE
      END IF
   50 CONTINUE
*
      RETURN
*
*     End of ZLAT2C
*

Here is the caller graph for this function: