cbdt05()

subroutine cbdt05	(	integer	M,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( * )	S,
		integer	NS,
		complex, dimension( * )	U,
		integer	LDU,
		complex, dimension( ldvt, * )	VT,
		integer	LDVT,
		complex, dimension( * )	WORK,
		real	RESID
	)

CBDT05

Purpose:

 CBDT05 reconstructs a bidiagonal matrix B from its (partial) SVD:
    S = U' * B * V
 where U and V are orthogonal matrices and S is diagonal.

 The test ratio to test the singular value decomposition is
    RESID = norm( S - U' * B * V ) / ( n * norm(B) * EPS )
 where VT = V' and EPS is the machine precision.

Parameters

[in]	M	M is INTEGER The number of rows of the matrices A and U.
[in]	N	N is INTEGER The number of columns of the matrices A and VT.
[in]	A	A is COMPLEX array, dimension (LDA,N) The m by n matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[in]	S	S is REAL array, dimension (NS) The singular values from the (partial) SVD of B, sorted in decreasing order.
[in]	NS	NS is INTEGER The number of singular values/vectors from the (partial) SVD of B.
[in]	U	U is COMPLEX array, dimension (LDU,NS) The n by ns orthogonal matrix U in S = U' * B * V.
[in]	LDU	LDU is INTEGER The leading dimension of the array U. LDU >= max(1,N)
[in]	VT	VT is COMPLEX array, dimension (LDVT,N) The n by ns orthogonal matrix V in S = U' * B * V.
[in]	LDVT	LDVT is INTEGER The leading dimension of the array VT.
[out]	WORK	WORK is COMPLEX array, dimension (M,N)
[out]	RESID	RESID is REAL The test ratio: norm(S - U' * A * V) / ( n * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 127 of file cbdt05.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDU, LDVT, M, N, NS
      REAL               RESID
*     ..
*     .. Array Arguments ..
      REAL               S( * )
      COMPLEX            A( LDA, * ), U( * ), VT( LDVT, * ), WORK( * )
*     ..
*
* ======================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      REAL               ANORM, EPS
*     ..
*     .. Local Arrays ..
      REAL               DUM( 1 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ISAMAX
      REAL               SASUM, SLAMCH, CLANGE
      EXTERNAL           lsame, isamax, sasum, slamch, clange
      REAL               SCASUM
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, real, max, min
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible.
*
      resid = zero
      IF( min( m, n ).LE.0 .OR. ns.LE.0 )
     $   RETURN
*
      eps = slamch( 'Precision' )
      anorm = clange( 'M', m, n, a, lda, dum )
*
*     Compute U' * A * V.
*
      CALL cgemm( 'N', 'C', m, ns, n, cone, a, lda, vt,
     $            ldvt, czero, work( 1+ns*ns ), m )
      CALL cgemm( 'C', 'N', ns, ns, m, -cone, u, ldu, work( 1+ns*ns ),
     $            m, czero, work, ns )
*
*     norm(S - U' * B * V)
*
      j = 0
      DO 10 i = 1, ns
         work( j+i ) =  work( j+i ) + cmplx( s( i ), zero )
         resid = max( resid, scasum( ns, work( j+1 ), 1 ) )
         j = j + ns
   10 CONTINUE
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         IF( anorm.GE.resid ) THEN
            resid = ( resid / anorm ) / ( real( n )*eps )
         ELSE
            IF( anorm.LT.one ) THEN
               resid = ( min( resid, real( n )*anorm ) / anorm ) /
     $                 ( real( n )*eps )
            ELSE
               resid = min( resid / anorm, real( n ) ) /
     $                 ( real( n )*eps )
            END IF
         END IF
      END IF
*
      RETURN
*
*     End of CBDT05
*

Here is the call graph for this function:

Here is the caller graph for this function: