sorg2l()

subroutine sorg2l	(	integer	M,
		integer	N,
		integer	K,
		real, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( * )	TAU,
		real, dimension( * )	WORK,
		integer	INFO
	)

SORG2L generates all or part of the orthogonal matrix Q from a QL factorization determined by sgeqlf (unblocked algorithm).

Download SORG2L + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SORG2L generates an m by n real matrix Q with orthonormal columns,
 which is defined as the last n columns of a product of k elementary
 reflectors of order m

       Q  =  H(k) . . . H(2) H(1)

 as returned by SGEQLF.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix Q. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix Q. M >= N >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. N >= K >= 0.
[in,out]	A	A is REAL array, dimension (LDA,N) On entry, the (n-k+i)-th column must contain the vector which defines the elementary reflector H(i), for i = 1,2,...,k, as returned by SGEQLF in the last k columns of its array argument A. On exit, the m by n matrix Q.
[in]	LDA	LDA is INTEGER The first dimension of the array A. LDA >= max(1,M).
[in]	TAU	TAU is REAL array, dimension (K) TAU(i) must contain the scalar factor of the elementary reflector H(i), as returned by SGEQLF.
[out]	WORK	WORK is REAL array, dimension (N)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument has an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 116 of file sorg2l.f.

*
*  -- LAPACK computational routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDA, M, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), TAU( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, II, J, L
*     ..
*     .. External Subroutines ..
      EXTERNAL           slarf, sscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 .OR. n.GT.m ) THEN
         info = -2
      ELSE IF( k.LT.0 .OR. k.GT.n ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SORG2L', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.LE.0 )
     $   RETURN
*
*     Initialise columns 1:n-k to columns of the unit matrix
*
      DO 20 j = 1, n - k
         DO 10 l = 1, m
            a( l, j ) = zero
   10    CONTINUE
         a( m-n+j, j ) = one
   20 CONTINUE
*
      DO 40 i = 1, k
         ii = n - k + i
*
*        Apply H(i) to A(1:m-k+i,1:n-k+i) from the left
*
         a( m-n+ii, ii ) = one
         CALL slarf( 'Left', m-n+ii, ii-1, a( 1, ii ), 1, tau( i ), a,
     $               lda, work )
         CALL sscal( m-n+ii-1, -tau( i ), a( 1, ii ), 1 )
         a( m-n+ii, ii ) = one - tau( i )
*
*        Set A(m-k+i+1:m,n-k+i) to zero
*
         DO 30 l = m - n + ii + 1, m
            a( l, ii ) = zero
   30    CONTINUE
   40 CONTINUE
      RETURN
*
*     End of SORG2L
*

Here is the call graph for this function:

Here is the caller graph for this function: