spttrf()

subroutine spttrf	(	integer	N,
		real, dimension( * )	D,
		real, dimension( * )	E,
		integer	INFO
	)

SPTTRF

Download SPTTRF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SPTTRF computes the L*D*L**T factorization of a real symmetric
 positive definite tridiagonal matrix A.  The factorization may also
 be regarded as having the form A = U**T*D*U.

Parameters

[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	D	D is REAL array, dimension (N) On entry, the n diagonal elements of the tridiagonal matrix A. On exit, the n diagonal elements of the diagonal matrix D from the L*D*L**T factorization of A.
[in,out]	E	E is REAL array, dimension (N-1) On entry, the (n-1) subdiagonal elements of the tridiagonal matrix A. On exit, the (n-1) subdiagonal elements of the unit bidiagonal factor L from the L*D*L**T factorization of A. E can also be regarded as the superdiagonal of the unit bidiagonal factor U from the U**T*D*U factorization of A.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -k, the k-th argument had an illegal value > 0: if INFO = k, the leading minor of order k is not positive definite; if k < N, the factorization could not be completed, while if k = N, the factorization was completed, but D(N) <= 0.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 93 of file spttrf.f.

*
*  -- LAPACK computational routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            INFO, N
*     ..
*     .. Array Arguments ..
      REAL               D( * ), E( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO
      parameter( zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, I4
      REAL               EI
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          mod
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
         CALL xerbla( 'SPTTRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Compute the L*D*L**T (or U**T*D*U) factorization of A.
*
      i4 = mod( n-1, 4 )
      DO 10 i = 1, i4
         IF( d( i ).LE.zero ) THEN
            info = i
            GO TO 30
         END IF
         ei = e( i )
         e( i ) = ei / d( i )
         d( i+1 ) = d( i+1 ) - e( i )*ei
   10 CONTINUE
*
      DO 20 i = i4 + 1, n - 4, 4
*
*        Drop out of the loop if d(i) <= 0: the matrix is not positive
*        definite.
*
         IF( d( i ).LE.zero ) THEN
            info = i
            GO TO 30
         END IF
*
*        Solve for e(i) and d(i+1).
*
         ei = e( i )
         e( i ) = ei / d( i )
         d( i+1 ) = d( i+1 ) - e( i )*ei
*
         IF( d( i+1 ).LE.zero ) THEN
            info = i + 1
            GO TO 30
         END IF
*
*        Solve for e(i+1) and d(i+2).
*
         ei = e( i+1 )
         e( i+1 ) = ei / d( i+1 )
         d( i+2 ) = d( i+2 ) - e( i+1 )*ei
*
         IF( d( i+2 ).LE.zero ) THEN
            info = i + 2
            GO TO 30
         END IF
*
*        Solve for e(i+2) and d(i+3).
*
         ei = e( i+2 )
         e( i+2 ) = ei / d( i+2 )
         d( i+3 ) = d( i+3 ) - e( i+2 )*ei
*
         IF( d( i+3 ).LE.zero ) THEN
            info = i + 3
            GO TO 30
         END IF
*
*        Solve for e(i+3) and d(i+4).
*
         ei = e( i+3 )
         e( i+3 ) = ei / d( i+3 )
         d( i+4 ) = d( i+4 ) - e( i+3 )*ei
   20 CONTINUE
*
*     Check d(n) for positive definiteness.
*
      IF( d( n ).LE.zero )
     $   info = n
*
   30 CONTINUE
      RETURN
*
*     End of SPTTRF
*

Here is the call graph for this function:

Here is the caller graph for this function: