slaed5()

subroutine slaed5	(	integer	I,
		real, dimension( 2 )	D,
		real, dimension( 2 )	Z,
		real, dimension( 2 )	DELTA,
		real	RHO,
		real	DLAM
	)

SLAED5 used by sstedc. Solves the 2-by-2 secular equation.

Download SLAED5 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 This subroutine computes the I-th eigenvalue of a symmetric rank-one
 modification of a 2-by-2 diagonal matrix

            diag( D )  +  RHO * Z * transpose(Z) .

 The diagonal elements in the array D are assumed to satisfy

            D(i) < D(j)  for  i < j .

 We also assume RHO > 0 and that the Euclidean norm of the vector
 Z is one.

Parameters

[in]	I	I is INTEGER The index of the eigenvalue to be computed. I = 1 or I = 2.
[in]	D	D is REAL array, dimension (2) The original eigenvalues. We assume D(1) < D(2).
[in]	Z	Z is REAL array, dimension (2) The components of the updating vector.
[out]	DELTA	DELTA is REAL array, dimension (2) The vector DELTA contains the information necessary to construct the eigenvectors.
[in]	RHO	RHO is REAL The scalar in the symmetric updating formula.
[out]	DLAM	DLAM is REAL The computed lambda_I, the I-th updated eigenvalue.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Contributors:

Ren-Cang Li, Computer Science Division, University of California at Berkeley, USA

Definition at line 110 of file slaed5.f.

*
*  -- LAPACK computational routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            I
      REAL               DLAM, RHO
*     ..
*     .. Array Arguments ..
      REAL               D( 2 ), DELTA( 2 ), Z( 2 )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TWO, FOUR
      parameter( zero = 0.0e0, one = 1.0e0, two = 2.0e0,
     $                   four = 4.0e0 )
*     ..
*     .. Local Scalars ..
      REAL               B, C, DEL, TAU, TEMP, W
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sqrt
*     ..
*     .. Executable Statements ..
*
      del = d( 2 ) - d( 1 )
      IF( i.EQ.1 ) THEN
         w = one + two*rho*( z( 2 )*z( 2 )-z( 1 )*z( 1 ) ) / del
         IF( w.GT.zero ) THEN
            b = del + rho*( z( 1 )*z( 1 )+z( 2 )*z( 2 ) )
            c = rho*z( 1 )*z( 1 )*del
*
*           B > ZERO, always
*
            tau = two*c / ( b+sqrt( abs( b*b-four*c ) ) )
            dlam = d( 1 ) + tau
            delta( 1 ) = -z( 1 ) / tau
            delta( 2 ) = z( 2 ) / ( del-tau )
         ELSE
            b = -del + rho*( z( 1 )*z( 1 )+z( 2 )*z( 2 ) )
            c = rho*z( 2 )*z( 2 )*del
            IF( b.GT.zero ) THEN
               tau = -two*c / ( b+sqrt( b*b+four*c ) )
            ELSE
               tau = ( b-sqrt( b*b+four*c ) ) / two
            END IF
            dlam = d( 2 ) + tau
            delta( 1 ) = -z( 1 ) / ( del+tau )
            delta( 2 ) = -z( 2 ) / tau
         END IF
         temp = sqrt( delta( 1 )*delta( 1 )+delta( 2 )*delta( 2 ) )
         delta( 1 ) = delta( 1 ) / temp
         delta( 2 ) = delta( 2 ) / temp
      ELSE
*
*     Now I=2
*
         b = -del + rho*( z( 1 )*z( 1 )+z( 2 )*z( 2 ) )
         c = rho*z( 2 )*z( 2 )*del
         IF( b.GT.zero ) THEN
            tau = ( b+sqrt( b*b+four*c ) ) / two
         ELSE
            tau = two*c / ( -b+sqrt( b*b+four*c ) )
         END IF
         dlam = d( 2 ) + tau
         delta( 1 ) = -z( 1 ) / ( del+tau )
         delta( 2 ) = -z( 2 ) / tau
         temp = sqrt( delta( 1 )*delta( 1 )+delta( 2 )*delta( 2 ) )
         delta( 1 ) = delta( 1 ) / temp
         delta( 2 ) = delta( 2 ) / temp
      END IF
      RETURN
*
*     End OF SLAED5
*

Here is the caller graph for this function: