cgesc2()

subroutine cgesc2	(	integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		complex, dimension( * )	RHS,
		integer, dimension( * )	IPIV,
		integer, dimension( * )	JPIV,
		real	SCALE
	)

CGESC2 solves a system of linear equations using the LU factorization with complete pivoting computed by sgetc2.

Download CGESC2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CGESC2 solves a system of linear equations

           A * X = scale* RHS

 with a general N-by-N matrix A using the LU factorization with
 complete pivoting computed by CGETC2.

Parameters

[in]	N	N is INTEGER The number of columns of the matrix A.
[in]	A	A is COMPLEX array, dimension (LDA, N) On entry, the LU part of the factorization of the n-by-n matrix A computed by CGETC2: A = P * L * U * Q
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1, N).
[in,out]	RHS	RHS is COMPLEX array, dimension N. On entry, the right hand side vector b. On exit, the solution vector X.
[in]	IPIV	IPIV is INTEGER array, dimension (N). The pivot indices; for 1 <= i <= N, row i of the matrix has been interchanged with row IPIV(i).
[in]	JPIV	JPIV is INTEGER array, dimension (N). The pivot indices; for 1 <= j <= N, column j of the matrix has been interchanged with column JPIV(j).
[out]	SCALE	SCALE is REAL On exit, SCALE contains the scale factor. SCALE is chosen 0 <= SCALE <= 1 to prevent overflow in the solution.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Contributors:

Bo Kagstrom and Peter Poromaa, Department of Computing Science, Umea University, S-901 87 Umea, Sweden.

Definition at line 117 of file cgesc2.f.

*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            LDA, N
      REAL               SCALE
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * ), JPIV( * )
      COMPLEX            A( LDA, * ), RHS( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TWO
      parameter( zero = 0.0e+0, one = 1.0e+0, two = 2.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
      REAL               BIGNUM, EPS, SMLNUM
      COMPLEX            TEMP
*     ..
*     .. External Subroutines ..
      EXTERNAL           claswp, cscal, slabad
*     ..
*     .. External Functions ..
      INTEGER            ICAMAX
      REAL               SLAMCH
      EXTERNAL           icamax, slamch
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, cmplx, real
*     ..
*     .. Executable Statements ..
*
*     Set constant to control overflow
*
      eps = slamch( 'P' )
      smlnum = slamch( 'S' ) / eps
      bignum = one / smlnum
      CALL slabad( smlnum, bignum )
*
*     Apply permutations IPIV to RHS
*
      CALL claswp( 1, rhs, lda, 1, n-1, ipiv, 1 )
*
*     Solve for L part
*
      DO 20 i = 1, n - 1
         DO 10 j = i + 1, n
            rhs( j ) = rhs( j ) - a( j, i )*rhs( i )
   10    CONTINUE
   20 CONTINUE
*
*     Solve for U part
*
      scale = one
*
*     Check for scaling
*
      i = icamax( n, rhs, 1 )
      IF( two*smlnum*abs( rhs( i ) ).GT.abs( a( n, n ) ) ) THEN
         temp = cmplx( one / two, zero ) / abs( rhs( i ) )
         CALL cscal( n, temp, rhs( 1 ), 1 )
         scale = scale*real( temp )
      END IF
      DO 40 i = n, 1, -1
         temp = cmplx( one, zero ) / a( i, i )
         rhs( i ) = rhs( i )*temp
         DO 30 j = i + 1, n
            rhs( i ) = rhs( i ) - rhs( j )*( a( i, j )*temp )
   30    CONTINUE
   40 CONTINUE
*
*     Apply permutations JPIV to the solution (RHS)
*
      CALL claswp( 1, rhs, lda, 1, n-1, jpiv, -1 )
      RETURN
*
*     End of CGESC2
*

Here is the call graph for this function:

Here is the caller graph for this function: