LAPACK  3.9.0
LAPACK: Linear Algebra PACKage

◆ zhegs2()

subroutine zhegs2 ( integer  ITYPE,
character  UPLO,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( ldb, * )  B,
integer  LDB,
integer  INFO 
)

ZHEGS2 reduces a Hermitian definite generalized eigenproblem to standard form, using the factorization results obtained from cpotrf (unblocked algorithm).

Download ZHEGS2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZHEGS2 reduces a complex Hermitian-definite generalized
 eigenproblem to standard form.

 If ITYPE = 1, the problem is A*x = lambda*B*x,
 and A is overwritten by inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H)

 If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
 B*A*x = lambda*x, and A is overwritten by U*A*U**H or L**H *A*L.

 B must have been previously factorized as U**H *U or L*L**H by ZPOTRF.
Parameters
[in]ITYPE
          ITYPE is INTEGER
          = 1: compute inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H);
          = 2 or 3: compute U*A*U**H or L**H *A*L.
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          Hermitian matrix A is stored, and how B has been factorized.
          = 'U':  Upper triangular
          = 'L':  Lower triangular
[in]N
          N is INTEGER
          The order of the matrices A and B.  N >= 0.
[in,out]A
          A is COMPLEX*16 array, dimension (LDA,N)
          On entry, the Hermitian matrix A.  If UPLO = 'U', the leading
          n by n upper triangular part of A contains the upper
          triangular part of the matrix A, and the strictly lower
          triangular part of A is not referenced.  If UPLO = 'L', the
          leading n by n lower triangular part of A contains the lower
          triangular part of the matrix A, and the strictly upper
          triangular part of A is not referenced.

          On exit, if INFO = 0, the transformed matrix, stored in the
          same format as A.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in,out]B
          B is COMPLEX*16 array, dimension (LDB,N)
          The triangular factor from the Cholesky factorization of B,
          as returned by ZPOTRF.
          B is modified by the routine but restored on exit.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]INFO
          INFO is INTEGER
          = 0:  successful exit.
          < 0:  if INFO = -i, the i-th argument had an illegal value.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 130 of file zhegs2.f.

130 *
131 * -- LAPACK computational routine (version 3.7.0) --
132 * -- LAPACK is a software package provided by Univ. of Tennessee, --
133 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
134 * December 2016
135 *
136 * .. Scalar Arguments ..
137  CHARACTER UPLO
138  INTEGER INFO, ITYPE, LDA, LDB, N
139 * ..
140 * .. Array Arguments ..
141  COMPLEX*16 A( LDA, * ), B( LDB, * )
142 * ..
143 *
144 * =====================================================================
145 *
146 * .. Parameters ..
147  DOUBLE PRECISION ONE, HALF
148  parameter( one = 1.0d+0, half = 0.5d+0 )
149  COMPLEX*16 CONE
150  parameter( cone = ( 1.0d+0, 0.0d+0 ) )
151 * ..
152 * .. Local Scalars ..
153  LOGICAL UPPER
154  INTEGER K
155  DOUBLE PRECISION AKK, BKK
156  COMPLEX*16 CT
157 * ..
158 * .. External Subroutines ..
159  EXTERNAL xerbla, zaxpy, zdscal, zher2, zlacgv, ztrmv,
160  $ ztrsv
161 * ..
162 * .. Intrinsic Functions ..
163  INTRINSIC max
164 * ..
165 * .. External Functions ..
166  LOGICAL LSAME
167  EXTERNAL lsame
168 * ..
169 * .. Executable Statements ..
170 *
171 * Test the input parameters.
172 *
173  info = 0
174  upper = lsame( uplo, 'U' )
175  IF( itype.LT.1 .OR. itype.GT.3 ) THEN
176  info = -1
177  ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
178  info = -2
179  ELSE IF( n.LT.0 ) THEN
180  info = -3
181  ELSE IF( lda.LT.max( 1, n ) ) THEN
182  info = -5
183  ELSE IF( ldb.LT.max( 1, n ) ) THEN
184  info = -7
185  END IF
186  IF( info.NE.0 ) THEN
187  CALL xerbla( 'ZHEGS2', -info )
188  RETURN
189  END IF
190 *
191  IF( itype.EQ.1 ) THEN
192  IF( upper ) THEN
193 *
194 * Compute inv(U**H)*A*inv(U)
195 *
196  DO 10 k = 1, n
197 *
198 * Update the upper triangle of A(k:n,k:n)
199 *
200  akk = a( k, k )
201  bkk = b( k, k )
202  akk = akk / bkk**2
203  a( k, k ) = akk
204  IF( k.LT.n ) THEN
205  CALL zdscal( n-k, one / bkk, a( k, k+1 ), lda )
206  ct = -half*akk
207  CALL zlacgv( n-k, a( k, k+1 ), lda )
208  CALL zlacgv( n-k, b( k, k+1 ), ldb )
209  CALL zaxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
210  $ lda )
211  CALL zher2( uplo, n-k, -cone, a( k, k+1 ), lda,
212  $ b( k, k+1 ), ldb, a( k+1, k+1 ), lda )
213  CALL zaxpy( n-k, ct, b( k, k+1 ), ldb, a( k, k+1 ),
214  $ lda )
215  CALL zlacgv( n-k, b( k, k+1 ), ldb )
216  CALL ztrsv( uplo, 'Conjugate transpose', 'Non-unit',
217  $ n-k, b( k+1, k+1 ), ldb, a( k, k+1 ),
218  $ lda )
219  CALL zlacgv( n-k, a( k, k+1 ), lda )
220  END IF
221  10 CONTINUE
222  ELSE
223 *
224 * Compute inv(L)*A*inv(L**H)
225 *
226  DO 20 k = 1, n
227 *
228 * Update the lower triangle of A(k:n,k:n)
229 *
230  akk = a( k, k )
231  bkk = b( k, k )
232  akk = akk / bkk**2
233  a( k, k ) = akk
234  IF( k.LT.n ) THEN
235  CALL zdscal( n-k, one / bkk, a( k+1, k ), 1 )
236  ct = -half*akk
237  CALL zaxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
238  CALL zher2( uplo, n-k, -cone, a( k+1, k ), 1,
239  $ b( k+1, k ), 1, a( k+1, k+1 ), lda )
240  CALL zaxpy( n-k, ct, b( k+1, k ), 1, a( k+1, k ), 1 )
241  CALL ztrsv( uplo, 'No transpose', 'Non-unit', n-k,
242  $ b( k+1, k+1 ), ldb, a( k+1, k ), 1 )
243  END IF
244  20 CONTINUE
245  END IF
246  ELSE
247  IF( upper ) THEN
248 *
249 * Compute U*A*U**H
250 *
251  DO 30 k = 1, n
252 *
253 * Update the upper triangle of A(1:k,1:k)
254 *
255  akk = a( k, k )
256  bkk = b( k, k )
257  CALL ztrmv( uplo, 'No transpose', 'Non-unit', k-1, b,
258  $ ldb, a( 1, k ), 1 )
259  ct = half*akk
260  CALL zaxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
261  CALL zher2( uplo, k-1, cone, a( 1, k ), 1, b( 1, k ), 1,
262  $ a, lda )
263  CALL zaxpy( k-1, ct, b( 1, k ), 1, a( 1, k ), 1 )
264  CALL zdscal( k-1, bkk, a( 1, k ), 1 )
265  a( k, k ) = akk*bkk**2
266  30 CONTINUE
267  ELSE
268 *
269 * Compute L**H *A*L
270 *
271  DO 40 k = 1, n
272 *
273 * Update the lower triangle of A(1:k,1:k)
274 *
275  akk = a( k, k )
276  bkk = b( k, k )
277  CALL zlacgv( k-1, a( k, 1 ), lda )
278  CALL ztrmv( uplo, 'Conjugate transpose', 'Non-unit', k-1,
279  $ b, ldb, a( k, 1 ), lda )
280  ct = half*akk
281  CALL zlacgv( k-1, b( k, 1 ), ldb )
282  CALL zaxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
283  CALL zher2( uplo, k-1, cone, a( k, 1 ), lda, b( k, 1 ),
284  $ ldb, a, lda )
285  CALL zaxpy( k-1, ct, b( k, 1 ), ldb, a( k, 1 ), lda )
286  CALL zlacgv( k-1, b( k, 1 ), ldb )
287  CALL zdscal( k-1, bkk, a( k, 1 ), lda )
288  CALL zlacgv( k-1, a( k, 1 ), lda )
289  a( k, k ) = akk*bkk**2
290  40 CONTINUE
291  END IF
292  END IF
293  RETURN
294 *
295 * End of ZHEGS2
296 *
Here is the call graph for this function:
Here is the caller graph for this function:
zlacgv
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:76
zaxpy
subroutine zaxpy(N, ZA, ZX, INCX, ZY, INCY)
ZAXPY
Definition: zaxpy.f:90
ztrsv
subroutine ztrsv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
ZTRSV
Definition: ztrsv.f:151
zdscal
subroutine zdscal(N, DA, ZX, INCX)
ZDSCAL
Definition: zdscal.f:80
zher2
subroutine zher2(UPLO, N, ALPHA, X, INCX, Y, INCY, A, LDA)
ZHER2
Definition: zher2.f:152
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
lsame
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
ztrmv
subroutine ztrmv(UPLO, TRANS, DIAG, N, A, LDA, X, INCX)
ZTRMV
Definition: ztrmv.f:149