clqt01()

subroutine clqt01	(	integer	M,
		integer	N,
		complex, dimension( lda, * )	A,
		complex, dimension( lda, * )	AF,
		complex, dimension( lda, * )	Q,
		complex, dimension( lda, * )	L,
		integer	LDA,
		complex, dimension( * )	TAU,
		complex, dimension( lwork )	WORK,
		integer	LWORK,
		real, dimension( * )	RWORK,
		real, dimension( * )	RESULT
	)

CLQT01

Purpose:

 CLQT01 tests CGELQF, which computes the LQ factorization of an m-by-n
 matrix A, and partially tests CUNGLQ which forms the n-by-n
 orthogonal matrix Q.

 CLQT01 compares L with A*Q', and checks that Q is orthogonal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The m-by-n matrix A.
[out]	AF	AF is COMPLEX array, dimension (LDA,N) Details of the LQ factorization of A, as returned by CGELQF. See CGELQF for further details.
[out]	Q	Q is COMPLEX array, dimension (LDA,N) The n-by-n orthogonal matrix Q.
[out]	L	L is COMPLEX array, dimension (LDA,max(M,N))
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and L. LDA >= max(M,N).
[out]	TAU	TAU is COMPLEX array, dimension (min(M,N)) The scalar factors of the elementary reflectors, as returned by CGELQF.
[out]	WORK	WORK is COMPLEX array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is REAL array, dimension (max(M,N))
[out]	RESULT	RESULT is REAL array, dimension (2) The test ratios: RESULT(1) = norm( L - A*Q' ) / ( N * norm(A) * EPS ) RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 128 of file clqt01.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               RESULT( * ), RWORK( * )
      COMPLEX            A( LDA, * ), AF( LDA, * ), L( LDA, * ),
     $                   Q( LDA, * ), TAU( * ), WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            ROGUE
      parameter( rogue = ( -1.0e+10, -1.0e+10 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO, MINMN
      REAL               ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      REAL               CLANGE, CLANSY, SLAMCH
      EXTERNAL           clange, clansy, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgelqf, cgemm, cherk, clacpy, claset, cunglq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, min, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
      minmn = min( m, n )
      eps = slamch( 'Epsilon' )
*
*     Copy the matrix A to the array AF.
*
      CALL clacpy( 'Full', m, n, a, lda, af, lda )
*
*     Factorize the matrix A in the array AF.
*
      srnamt = 'CGELQF'
      CALL cgelqf( m, n, af, lda, tau, work, lwork, info )
*
*     Copy details of Q
*
      CALL claset( 'Full', n, n, rogue, rogue, q, lda )
      IF( n.GT.1 )
     $   CALL clacpy( 'Upper', m, n-1, af( 1, 2 ), lda, q( 1, 2 ), lda )
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'CUNGLQ'
      CALL cunglq( n, n, minmn, q, lda, tau, work, lwork, info )
*
*     Copy L
*
      CALL claset( 'Full', m, n, cmplx( zero ), cmplx( zero ), l, lda )
      CALL clacpy( 'Lower', m, n, af, lda, l, lda )
*
*     Compute L - A*Q'
*
      CALL cgemm( 'No transpose', 'Conjugate transpose', m, n, n,
     $            cmplx( -one ), a, lda, q, lda, cmplx( one ), l, lda )
*
*     Compute norm( L - Q'*A ) / ( N * norm(A) * EPS ) .
*
      anorm = clange( '1', m, n, a, lda, rwork )
      resid = clange( '1', m, n, l, lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / real( max( 1, n ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL claset( 'Full', n, n, cmplx( zero ), cmplx( one ), l, lda )
      CALL cherk( 'Upper', 'No transpose', n, n, -one, q, lda, one, l,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = clansy( '1', 'Upper', n, l, lda, rwork )
*
      result( 2 ) = ( resid / real( max( 1, n ) ) ) / eps
*
      RETURN
*
*     End of CLQT01
*

Here is the call graph for this function:

Here is the caller graph for this function: