cgecon()

subroutine cgecon	(	character	NORM,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		real	ANORM,
		real	RCOND,
		complex, dimension( * )	WORK,
		real, dimension( * )	RWORK,
		integer	INFO
	)

CGECON

Download CGECON + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CGECON estimates the reciprocal of the condition number of a general
 complex matrix A, in either the 1-norm or the infinity-norm, using
 the LU factorization computed by CGETRF.

 An estimate is obtained for norm(inv(A)), and the reciprocal of the
 condition number is computed as
    RCOND = 1 / ( norm(A) * norm(inv(A)) ).

Parameters

[in]	NORM	NORM is CHARACTER*1 Specifies whether the 1-norm condition number or the infinity-norm condition number is required: = '1' or 'O': 1-norm; = 'I': Infinity-norm.
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The factors L and U from the factorization A = P*L*U as computed by CGETRF.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	ANORM	ANORM is REAL If NORM = '1' or 'O', the 1-norm of the original matrix A. If NORM = 'I', the infinity-norm of the original matrix A.
[out]	RCOND	RCOND is REAL The reciprocal of the condition number of the matrix A, computed as RCOND = 1/(norm(A) * norm(inv(A))).
[out]	WORK	WORK is COMPLEX array, dimension (2*N)
[out]	RWORK	RWORK is REAL array, dimension (2*N)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 126 of file cgecon.f.

*
*  -- LAPACK computational routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          NORM
      INTEGER            INFO, LDA, N
      REAL               ANORM, RCOND
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * )
      COMPLEX            A( LDA, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            ONENRM
      CHARACTER          NORMIN
      INTEGER            IX, KASE, KASE1
      REAL               AINVNM, SCALE, SL, SMLNUM, SU
      COMPLEX            ZDUM
*     ..
*     .. Local Arrays ..
      INTEGER            ISAVE( 3 )
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      INTEGER            ICAMAX
      REAL               SLAMCH
      EXTERNAL           lsame, icamax, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           clacn2, clatrs, csrscl, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, real
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( zdum ) = abs( real( zdum ) ) + abs( aimag( zdum ) )
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      onenrm = norm.EQ.'1' .OR. lsame( norm, 'O' )
      IF( .NOT.onenrm .AND. .NOT.lsame( norm, 'I' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      ELSE IF( anorm.LT.zero ) THEN
         info = -5
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CGECON', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      rcond = zero
      IF( n.EQ.0 ) THEN
         rcond = one
         RETURN
      ELSE IF( anorm.EQ.zero ) THEN
         RETURN
      END IF
*
      smlnum = slamch( 'Safe minimum' )
*
*     Estimate the norm of inv(A).
*
      ainvnm = zero
      normin = 'N'
      IF( onenrm ) THEN
         kase1 = 1
      ELSE
         kase1 = 2
      END IF
      kase = 0
   10 CONTINUE
      CALL clacn2( n, work( n+1 ), work, ainvnm, kase, isave )
      IF( kase.NE.0 ) THEN
         IF( kase.EQ.kase1 ) THEN
*
*           Multiply by inv(L).
*
            CALL clatrs( 'Lower', 'No transpose', 'Unit', normin, n, a,
     $                   lda, work, sl, rwork, info )
*
*           Multiply by inv(U).
*
            CALL clatrs( 'Upper', 'No transpose', 'Non-unit', normin, n,
     $                   a, lda, work, su, rwork( n+1 ), info )
         ELSE
*
*           Multiply by inv(U**H).
*
            CALL clatrs( 'Upper', 'Conjugate transpose', 'Non-unit',
     $                   normin, n, a, lda, work, su, rwork( n+1 ),
     $                   info )
*
*           Multiply by inv(L**H).
*
            CALL clatrs( 'Lower', 'Conjugate transpose', 'Unit', normin,
     $                   n, a, lda, work, sl, rwork, info )
         END IF
*
*        Divide X by 1/(SL*SU) if doing so will not cause overflow.
*
         scale = sl*su
         normin = 'Y'
         IF( scale.NE.one ) THEN
            ix = icamax( n, work, 1 )
            IF( scale.LT.cabs1( work( ix ) )*smlnum .OR. scale.EQ.zero )
     $         GO TO 20
            CALL csrscl( n, scale, work, 1 )
         END IF
         GO TO 10
      END IF
*
*     Compute the estimate of the reciprocal condition number.
*
      IF( ainvnm.NE.zero )
     $   rcond = ( one / ainvnm ) / anorm
*
   20 CONTINUE
      RETURN
*
*     End of CGECON
*

Here is the call graph for this function:

Here is the caller graph for this function: