clauu2()

subroutine clauu2	(	character	UPLO,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		integer	INFO
	)

CLAUU2 computes the product UUH or LHL, where U and L are upper or lower triangular matrices (unblocked algorithm).

Download CLAUU2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CLAUU2 computes the product U * U**H or L**H * L, where the triangular
 factor U or L is stored in the upper or lower triangular part of
 the array A.

 If UPLO = 'U' or 'u' then the upper triangle of the result is stored,
 overwriting the factor U in A.
 If UPLO = 'L' or 'l' then the lower triangle of the result is stored,
 overwriting the factor L in A.

 This is the unblocked form of the algorithm, calling Level 2 BLAS.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the triangular factor stored in the array A is upper or lower triangular: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The order of the triangular factor U or L. N >= 0.
[in,out]	A	A is COMPLEX array, dimension (LDA,N) On entry, the triangular factor U or L. On exit, if UPLO = 'U', the upper triangle of A is overwritten with the upper triangle of the product U * U**H; if UPLO = 'L', the lower triangle of A is overwritten with the lower triangle of the product L**H * L.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -k, the k-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 104 of file clauu2.f.

*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            INFO, LDA, N
*     ..
*     .. Array Arguments ..
      COMPLEX            A( LDA, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX            ONE
      parameter( one = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            UPPER
      INTEGER            I
      REAL               AII
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      COMPLEX            CDOTC
      EXTERNAL           lsame, cdotc
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemv, clacgv, csscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          cmplx, max, real
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      upper = lsame( uplo, 'U' )
      IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( lda.LT.max( 1, n ) ) THEN
         info = -4
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CLAUU2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      IF( upper ) THEN
*
*        Compute the product U * U**H.
*
         DO 10 i = 1, n
            aii = a( i, i )
            IF( i.LT.n ) THEN
               a( i, i ) = aii*aii + real( cdotc( n-i, a( i, i+1 ), lda,
     $                     a( i, i+1 ), lda ) )
               CALL clacgv( n-i, a( i, i+1 ), lda )
               CALL cgemv( 'No transpose', i-1, n-i, one, a( 1, i+1 ),
     $                     lda, a( i, i+1 ), lda, cmplx( aii ),
     $                     a( 1, i ), 1 )
               CALL clacgv( n-i, a( i, i+1 ), lda )
            ELSE
               CALL csscal( i, aii, a( 1, i ), 1 )
            END IF
   10    CONTINUE
*
      ELSE
*
*        Compute the product L**H * L.
*
         DO 20 i = 1, n
            aii = a( i, i )
            IF( i.LT.n ) THEN
               a( i, i ) = aii*aii + real( cdotc( n-i, a( i+1, i ), 1,
     $                     a( i+1, i ), 1 ) )
               CALL clacgv( i-1, a( i, 1 ), lda )
               CALL cgemv( 'Conjugate transpose', n-i, i-1, one,
     $                     a( i+1, 1 ), lda, a( i+1, i ), 1,
     $                     cmplx( aii ), a( i, 1 ), lda )
               CALL clacgv( i-1, a( i, 1 ), lda )
            ELSE
               CALL csscal( i, aii, a( i, 1 ), lda )
            END IF
   20    CONTINUE
      END IF
*
      RETURN
*
*     End of CLAUU2
*

Here is the call graph for this function:

Here is the caller graph for this function: