clacrm()

subroutine clacrm	(	integer	M,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		real, dimension( ldb, * )	B,
		integer	LDB,
		complex, dimension( ldc, * )	C,
		integer	LDC,
		real, dimension( * )	RWORK
	)

CLACRM multiplies a complex matrix by a square real matrix.

Download CLACRM + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CLACRM performs a very simple matrix-matrix multiplication:
          C := A * B,
 where A is M by N and complex; B is N by N and real;
 C is M by N and complex.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A and of the matrix C. M >= 0.
[in]	N	N is INTEGER The number of columns and rows of the matrix B and the number of columns of the matrix C. N >= 0.
[in]	A	A is COMPLEX array, dimension (LDA, N) On entry, A contains the M by N matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >=max(1,M).
[in]	B	B is REAL array, dimension (LDB, N) On entry, B contains the N by N matrix B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >=max(1,N).
[out]	C	C is COMPLEX array, dimension (LDC, N) On exit, C contains the M by N matrix C.
[in]	LDC	LDC is INTEGER The leading dimension of the array C. LDC >=max(1,N).
[out]	RWORK	RWORK is REAL array, dimension (2*M*N)

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 116 of file clacrm.f.

*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDB, LDC, M, N
*     ..
*     .. Array Arguments ..
      REAL               B( LDB, * ), RWORK( * )
      COMPLEX            A( LDA, * ), C( LDC, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, ZERO
      parameter( one = 1.0e0, zero = 0.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, L
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          aimag, cmplx, real
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible.
*
      IF( ( m.EQ.0 ) .OR. ( n.EQ.0 ) )
     $   RETURN
*
      DO 20 j = 1, n
         DO 10 i = 1, m
            rwork( ( j-1 )*m+i ) = real( a( i, j ) )
   10    CONTINUE
   20 CONTINUE
*
      l = m*n + 1
      CALL sgemm( 'N', 'N', m, n, n, one, rwork, m, b, ldb, zero,
     $            rwork( l ), m )
      DO 40 j = 1, n
         DO 30 i = 1, m
            c( i, j ) = rwork( l+( j-1 )*m+i-1 )
   30    CONTINUE
   40 CONTINUE
*
      DO 60 j = 1, n
         DO 50 i = 1, m
            rwork( ( j-1 )*m+i ) = aimag( a( i, j ) )
   50    CONTINUE
   60 CONTINUE
      CALL sgemm( 'N', 'N', m, n, n, one, rwork, m, b, ldb, zero,
     $            rwork( l ), m )
      DO 80 j = 1, n
         DO 70 i = 1, m
            c( i, j ) = cmplx( real( c( i, j ) ),
     $                  rwork( l+( j-1 )*m+i-1 ) )
   70    CONTINUE
   80 CONTINUE
*
      RETURN
*
*     End of CLACRM
*

Here is the call graph for this function:

Here is the caller graph for this function: