cget22()

subroutine cget22	(	character	TRANSA,
		character	TRANSE,
		character	TRANSW,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		complex, dimension( lde, * )	E,
		integer	LDE,
		complex, dimension( * )	W,
		complex, dimension( * )	WORK,
		real, dimension( * )	RWORK,
		real, dimension( 2 )	RESULT
	)

CGET22

Purpose:

 CGET22 does an eigenvector check.

 The basic test is:

    RESULT(1) = | A E  -  E W | / ( |A| |E| ulp )

 using the 1-norm.  It also tests the normalization of E:

    RESULT(2) = max | m-norm(E(j)) - 1 | / ( n ulp )
                 j

 where E(j) is the j-th eigenvector, and m-norm is the max-norm of a
 vector.  The max-norm of a complex n-vector x in this case is the
 maximum of |re(x(i)| + |im(x(i)| over i = 1, ..., n.

Parameters

[in]	TRANSA	TRANSA is CHARACTER*1 Specifies whether or not A is transposed. = 'N': No transpose = 'T': Transpose = 'C': Conjugate transpose
[in]	TRANSE	TRANSE is CHARACTER*1 Specifies whether or not E is transposed. = 'N': No transpose, eigenvectors are in columns of E = 'T': Transpose, eigenvectors are in rows of E = 'C': Conjugate transpose, eigenvectors are in rows of E
[in]	TRANSW	TRANSW is CHARACTER*1 Specifies whether or not W is transposed. = 'N': No transpose = 'T': Transpose, same as TRANSW = 'N' = 'C': Conjugate transpose, use -WI(j) instead of WI(j)
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	A	A is COMPLEX array, dimension (LDA,N) The matrix whose eigenvectors are in E.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	E	E is COMPLEX array, dimension (LDE,N) The matrix of eigenvectors. If TRANSE = 'N', the eigenvectors are stored in the columns of E, if TRANSE = 'T' or 'C', the eigenvectors are stored in the rows of E.
[in]	LDE	LDE is INTEGER The leading dimension of the array E. LDE >= max(1,N).
[in]	W	W is COMPLEX array, dimension (N) The eigenvalues of A.
[out]	WORK	WORK is COMPLEX array, dimension (N*N)
[out]	RWORK	RWORK is REAL array, dimension (N)
[out]	RESULT	RESULT is REAL array, dimension (2) RESULT(1) = | A E - E W | / ( |A| |E| ulp ) RESULT(2) = max | m-norm(E(j)) - 1 | / ( n ulp )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 145 of file cget22.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          TRANSA, TRANSE, TRANSW
      INTEGER            LDA, LDE, N
*     ..
*     .. Array Arguments ..
      REAL               RESULT( 2 ), RWORK( * )
      COMPLEX            A( LDA, * ), E( LDE, * ), W( * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER          NORMA, NORME
      INTEGER            ITRNSE, ITRNSW, J, JCOL, JOFF, JROW, JVEC
      REAL               ANORM, ENORM, ENRMAX, ENRMIN, ERRNRM, TEMP1,
     $                   ULP, UNFL
      COMPLEX            WTEMP
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               CLANGE, SLAMCH
      EXTERNAL           lsame, clange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, claset
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, conjg, max, min, real
*     ..
*     .. Executable Statements ..
*
*     Initialize RESULT (in case N=0)
*
      result( 1 ) = zero
      result( 2 ) = zero
      IF( n.LE.0 )
     $   RETURN
*
      unfl = slamch( 'Safe minimum' )
      ulp = slamch( 'Precision' )
*
      itrnse = 0
      itrnsw = 0
      norma = 'O'
      norme = 'O'
*
      IF( lsame( transa, 'T' ) .OR. lsame( transa, 'C' ) ) THEN
         norma = 'I'
      END IF
*
      IF( lsame( transe, 'T' ) ) THEN
         itrnse = 1
         norme = 'I'
      ELSE IF( lsame( transe, 'C' ) ) THEN
         itrnse = 2
         norme = 'I'
      END IF
*
      IF( lsame( transw, 'C' ) ) THEN
         itrnsw = 1
      END IF
*
*     Normalization of E:
*
      enrmin = one / ulp
      enrmax = zero
      IF( itrnse.EQ.0 ) THEN
         DO 20 jvec = 1, n
            temp1 = zero
            DO 10 j = 1, n
               temp1 = max( temp1, abs( real( e( j, jvec ) ) )+
     $                 abs( aimag( e( j, jvec ) ) ) )
   10       CONTINUE
            enrmin = min( enrmin, temp1 )
            enrmax = max( enrmax, temp1 )
   20    CONTINUE
      ELSE
         DO 30 jvec = 1, n
            rwork( jvec ) = zero
   30    CONTINUE
*
         DO 50 j = 1, n
            DO 40 jvec = 1, n
               rwork( jvec ) = max( rwork( jvec ),
     $                         abs( real( e( jvec, j ) ) )+
     $                         abs( aimag( e( jvec, j ) ) ) )
   40       CONTINUE
   50    CONTINUE
*
         DO 60 jvec = 1, n
            enrmin = min( enrmin, rwork( jvec ) )
            enrmax = max( enrmax, rwork( jvec ) )
   60    CONTINUE
      END IF
*
*     Norm of A:
*
      anorm = max( clange( norma, n, n, a, lda, rwork ), unfl )
*
*     Norm of E:
*
      enorm = max( clange( norme, n, n, e, lde, rwork ), ulp )
*
*     Norm of error:
*
*     Error =  AE - EW
*
      CALL claset( 'Full', n, n, czero, czero, work, n )
*
      joff = 0
      DO 100 jcol = 1, n
         IF( itrnsw.EQ.0 ) THEN
            wtemp = w( jcol )
         ELSE
            wtemp = conjg( w( jcol ) )
         END IF
*
         IF( itrnse.EQ.0 ) THEN
            DO 70 jrow = 1, n
               work( joff+jrow ) = e( jrow, jcol )*wtemp
   70       CONTINUE
         ELSE IF( itrnse.EQ.1 ) THEN
            DO 80 jrow = 1, n
               work( joff+jrow ) = e( jcol, jrow )*wtemp
   80       CONTINUE
         ELSE
            DO 90 jrow = 1, n
               work( joff+jrow ) = conjg( e( jcol, jrow ) )*wtemp
   90       CONTINUE
         END IF
         joff = joff + n
  100 CONTINUE
*
      CALL cgemm( transa, transe, n, n, n, cone, a, lda, e, lde, -cone,
     $            work, n )
*
      errnrm = clange( 'One', n, n, work, n, rwork ) / enorm
*
*     Compute RESULT(1) (avoiding under/overflow)
*
      IF( anorm.GT.errnrm ) THEN
         result( 1 ) = ( errnrm / anorm ) / ulp
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( errnrm, anorm ) / anorm ) / ulp
         ELSE
            result( 1 ) = min( errnrm / anorm, one ) / ulp
         END IF
      END IF
*
*     Compute RESULT(2) : the normalization error in E.
*
      result( 2 ) = max( abs( enrmax-one ), abs( enrmin-one ) ) /
     $              ( real( n )*ulp )
*
      RETURN
*
*     End of CGET22
*

Here is the call graph for this function:

Here is the caller graph for this function: