◆ ssysv_aa()

subroutine ssysv_aa	(	character	UPLO,
		integer	N,
		integer	NRHS,
		real, dimension( lda, * )	A,
		integer	LDA,
		integer, dimension( * )	IPIV,
		real, dimension( ldb, * )	B,
		integer	LDB,
		real, dimension( * )	WORK,
		integer	LWORK,
		integer	INFO
	)

SSYSV_AA computes the solution to system of linear equations A * X = B for SY matrices

Download SSYSV_AA + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SSYSV computes the solution to a real system of linear equations
    A * X = B,
 where A is an N-by-N symmetric matrix and X and B are N-by-NRHS
 matrices.

 Aasen's algorithm is used to factor A as
    A = U**T * T * U,  if UPLO = 'U', or
    A = L * T * L**T,  if UPLO = 'L',
 where U (or L) is a product of permutation and unit upper (lower)
 triangular matrices, and T is symmetric tridiagonal. The factored
 form of A is then used to solve the system of equations A * X = B.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 = 'U': Upper triangle of A is stored; = 'L': Lower triangle of A is stored.
[in]	N	N is INTEGER The number of linear equations, i.e., the order of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrix B. NRHS >= 0.
[in,out]	A	A is REAL array, dimension (LDA,N) On entry, the symmetric matrix A. If UPLO = 'U', the leading N-by-N upper triangular part of A contains the upper triangular part of the matrix A, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading N-by-N lower triangular part of A contains the lower triangular part of the matrix A, and the strictly upper triangular part of A is not referenced. On exit, if INFO = 0, the tridiagonal matrix T and the multipliers used to obtain the factor U or L from the factorization A = U*TTU or A = LTL*T as computed by SSYTRF.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	IPIV	IPIV is INTEGER array, dimension (N) On exit, it contains the details of the interchanges, i.e., the row and column k of A were interchanged with the row and column IPIV(k).
[in,out]	B	B is REAL array, dimension (LDB,NRHS) On entry, the N-by-NRHS right hand side matrix B. On exit, if INFO = 0, the N-by-NRHS solution matrix X.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	WORK	WORK is REAL array, dimension (MAX(1,LWORK)) On exit, if INFO = 0, WORK(1) returns the optimal LWORK.
[in]	LWORK	LWORK is INTEGER The length of WORK. LWORK >= MAX(1,2N,3N-2), and for the best performance, LWORK >= MAX(1,N*NB), where NB is the optimal blocksize for SSYTRF_AA. If LWORK = -1, then a workspace query is assumed; the routine only calculates the optimal size of the WORK array, returns this value as the first entry of the WORK array, and no error message related to LWORK is issued by XERBLA.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value > 0: if INFO = i, D(i,i) is exactly zero. The factorization has been completed, but the block diagonal matrix D is exactly singular, so the solution could not be computed.

Author: Univ. of Tennessee; Univ. of California Berkeley; Univ. of Colorado Denver; NAG Ltd.

Date: November 2017

Definition at line 164 of file ssysv_aa.f.

 *
 *  -- LAPACK driver routine (version 3.8.0) --
 *  -- LAPACK is a software package provided by Univ. of Tennessee,    --
 *  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
 *     November 2017
 *
 *     .. Scalar Arguments ..
       CHARACTER          UPLO
       INTEGER            INFO, LDA, LDB, LWORK, N, NRHS
 *     ..
 *     .. Array Arguments ..
       INTEGER            IPIV( * )
       REAL               A( LDA, * ), B( LDB, * ), WORK( * )
 *     ..
 *
 *  =====================================================================
 *
 *     .. Local Scalars ..
       LOGICAL            LQUERY
       INTEGER            LWKOPT, LWKOPT_SYTRF, LWKOPT_SYTRS
 *     ..
 *     .. External Functions ..
       LOGICAL            LSAME
       EXTERNAL           lsame
 *     ..
 *     .. External Subroutines ..
       EXTERNAL           xerbla, ssytrs_aa, ssytrf_aa
 *     ..
 *     .. Intrinsic Functions ..
       INTRINSIC          max
 *     ..
 *     .. Executable Statements ..
 *
 *     Test the input parameters.
 *
       info = 0
       lquery = ( lwork.EQ.-1 )
       IF( .NOT.lsame( uplo, 'U' ) .AND. .NOT.lsame( uplo, 'L' ) ) THEN
          info = -1
       ELSE IF( n.LT.0 ) THEN
          info = -2
       ELSE IF( nrhs.LT.0 ) THEN
          info = -3
       ELSE IF( lda.LT.max( 1, n ) ) THEN
          info = -5
       ELSE IF( ldb.LT.max( 1, n ) ) THEN
          info = -8
       ELSE IF( lwork.LT.max(2*n, 3*n-2) .AND. .NOT.lquery ) THEN
          info = -10
       END IF
 *
       IF( info.EQ.0 ) THEN
          CALL ssytrf_aa( uplo, n, a, lda, ipiv, work, -1, info )
          lwkopt_sytrf = int( work(1) )
          CALL ssytrs_aa( uplo, n, nrhs, a, lda, ipiv, b, ldb, work,
      $                   -1, info )
          lwkopt_sytrs = int( work(1) )
          lwkopt = max( lwkopt_sytrf, lwkopt_sytrs )
          work( 1 ) = lwkopt
       END IF
 *
       IF( info.NE.0 ) THEN
          CALL xerbla( 'SSYSV_AA', -info )
          RETURN
       ELSE IF( lquery ) THEN
          RETURN
       END IF
 *
 *     Compute the factorization A = U**T*T*U or A = L*T*L**T.
 *
       CALL ssytrf_aa( uplo, n, a, lda, ipiv, work, lwork, info )
       IF( info.EQ.0 ) THEN
 *
 *        Solve the system A*X = B, overwriting B with X.
 *
          CALL ssytrs_aa( uplo, n, nrhs, a, lda, ipiv, b, ldb, work,
      $                      lwork, info )
 *
       END IF
 *
       work( 1 ) = lwkopt
 *
       RETURN
 *
 *     End of SSYSV_AA
 *

Here is the call graph for this function:

Here is the caller graph for this function: