dlaptm()

subroutine dlaptm	(	integer	N,
		integer	NRHS,
		double precision	ALPHA,
		double precision, dimension( * )	D,
		double precision, dimension( * )	E,
		double precision, dimension( ldx, * )	X,
		integer	LDX,
		double precision	BETA,
		double precision, dimension( ldb, * )	B,
		integer	LDB
	)

DLAPTM

Purpose:

 DLAPTM multiplies an N by NRHS matrix X by a symmetric tridiagonal
 matrix A and stores the result in a matrix B.  The operation has the
 form

    B := alpha * A * X + beta * B

 where alpha may be either 1. or -1. and beta may be 0., 1., or -1.

Parameters

[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	NRHS	NRHS is INTEGER The number of right hand sides, i.e., the number of columns of the matrices X and B.
[in]	ALPHA	ALPHA is DOUBLE PRECISION The scalar alpha. ALPHA must be 1. or -1.; otherwise, it is assumed to be 0.
[in]	D	D is DOUBLE PRECISION array, dimension (N) The n diagonal elements of the tridiagonal matrix A.
[in]	E	E is DOUBLE PRECISION array, dimension (N-1) The (n-1) subdiagonal or superdiagonal elements of A.
[in]	X	X is DOUBLE PRECISION array, dimension (LDX,NRHS) The N by NRHS matrix X.
[in]	LDX	LDX is INTEGER The leading dimension of the array X. LDX >= max(N,1).
[in]	BETA	BETA is DOUBLE PRECISION The scalar beta. BETA must be 0., 1., or -1.; otherwise, it is assumed to be 1.
[in,out]	B	B is DOUBLE PRECISION array, dimension (LDB,NRHS) On entry, the N by NRHS matrix B. On exit, B is overwritten by the matrix expression B := alpha * A * X + beta * B.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(N,1).

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 118 of file dlaptm.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            LDB, LDX, N, NRHS
      DOUBLE PRECISION   ALPHA, BETA
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   B( LDB, * ), D( * ), E( * ), X( LDX, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J
*     ..
*     .. Executable Statements ..
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Multiply B by BETA if BETA.NE.1.
*
      IF( beta.EQ.zero ) THEN
         DO 20 j = 1, nrhs
            DO 10 i = 1, n
               b( i, j ) = zero
   10       CONTINUE
   20    CONTINUE
      ELSE IF( beta.EQ.-one ) THEN
         DO 40 j = 1, nrhs
            DO 30 i = 1, n
               b( i, j ) = -b( i, j )
   30       CONTINUE
   40    CONTINUE
      END IF
*
      IF( alpha.EQ.one ) THEN
*
*        Compute B := B + A*X
*
         DO 60 j = 1, nrhs
            IF( n.EQ.1 ) THEN
               b( 1, j ) = b( 1, j ) + d( 1 )*x( 1, j )
            ELSE
               b( 1, j ) = b( 1, j ) + d( 1 )*x( 1, j ) +
     $                     e( 1 )*x( 2, j )
               b( n, j ) = b( n, j ) + e( n-1 )*x( n-1, j ) +
     $                     d( n )*x( n, j )
               DO 50 i = 2, n - 1
                  b( i, j ) = b( i, j ) + e( i-1 )*x( i-1, j ) +
     $                        d( i )*x( i, j ) + e( i )*x( i+1, j )
   50          CONTINUE
            END IF
   60    CONTINUE
      ELSE IF( alpha.EQ.-one ) THEN
*
*        Compute B := B - A*X
*
         DO 80 j = 1, nrhs
            IF( n.EQ.1 ) THEN
               b( 1, j ) = b( 1, j ) - d( 1 )*x( 1, j )
            ELSE
               b( 1, j ) = b( 1, j ) - d( 1 )*x( 1, j ) -
     $                     e( 1 )*x( 2, j )
               b( n, j ) = b( n, j ) - e( n-1 )*x( n-1, j ) -
     $                     d( n )*x( n, j )
               DO 70 i = 2, n - 1
                  b( i, j ) = b( i, j ) - e( i-1 )*x( i-1, j ) -
     $                        d( i )*x( i, j ) - e( i )*x( i+1, j )
   70          CONTINUE
            END IF
   80    CONTINUE
      END IF
      RETURN
*
*     End of DLAPTM
*

Here is the caller graph for this function: