dlaord()

subroutine dlaord	(	character	JOB,
		integer	N,
		double precision, dimension( * )	X,
		integer	INCX
	)

DLAORD

Purpose:

 DLAORD sorts the elements of a vector x in increasing or decreasing
 order.

Parameters

[in]	JOB	JOB is CHARACTER = 'I': Sort in increasing order = 'D': Sort in decreasing order
[in]	N	N is INTEGER The length of the vector X.
[in,out]	X	X is DOUBLE PRECISION array, dimension (1+(N-1)*INCX) On entry, the vector of length n to be sorted. On exit, the vector x is sorted in the prescribed order.
[in]	INCX	INCX is INTEGER The spacing between successive elements of X. INCX >= 0.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 75 of file dlaord.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          JOB
      INTEGER            INCX, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   X( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            I, INC, IX, IXNEXT
      DOUBLE PRECISION   TEMP
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs
*     ..
*     .. Executable Statements ..
*
      inc = abs( incx )
      IF( lsame( job, 'I' ) ) THEN
*
*        Sort in increasing order
*
         DO 20 i = 2, n
            ix = 1 + ( i-1 )*inc
   10       CONTINUE
            IF( ix.EQ.1 )
     $         GO TO 20
            ixnext = ix - inc
            IF( x( ix ).GT.x( ixnext ) ) THEN
               GO TO 20
            ELSE
               temp = x( ix )
               x( ix ) = x( ixnext )
               x( ixnext ) = temp
            END IF
            ix = ixnext
            GO TO 10
   20    CONTINUE
*
      ELSE IF( lsame( job, 'D' ) ) THEN
*
*        Sort in decreasing order
*
         DO 40 i = 2, n
            ix = 1 + ( i-1 )*inc
   30       CONTINUE
            IF( ix.EQ.1 )
     $         GO TO 40
            ixnext = ix - inc
            IF( x( ix ).LT.x( ixnext ) ) THEN
               GO TO 40
            ELSE
               temp = x( ix )
               x( ix ) = x( ixnext )
               x( ixnext ) = temp
            END IF
            ix = ixnext
            GO TO 30
   40    CONTINUE
      END IF
      RETURN
*
*     End of DLAORD
*

Here is the caller graph for this function: