dtrt06()

subroutine dtrt06	(	double precision	RCOND,
		double precision	RCONDC,
		character	UPLO,
		character	DIAG,
		integer	N,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( * )	WORK,
		double precision	RAT
	)

DTRT06

Purpose:

 DTRT06 computes a test ratio comparing RCOND (the reciprocal
 condition number of a triangular matrix A) and RCONDC, the estimate
 computed by DTRCON.  Information about the triangular matrix A is
 used if one estimate is zero and the other is non-zero to decide if
 underflow in the estimate is justified.

Parameters

[in]	RCOND	RCOND is DOUBLE PRECISION The estimate of the reciprocal condition number obtained by forming the explicit inverse of the matrix A and computing RCOND = 1/( norm(A) * norm(inv(A)) ).
[in]	RCONDC	RCONDC is DOUBLE PRECISION The estimate of the reciprocal condition number computed by DTRCON.
[in]	UPLO	UPLO is CHARACTER Specifies whether the matrix A is upper or lower triangular. = 'U': Upper triangular = 'L': Lower triangular
[in]	DIAG	DIAG is CHARACTER Specifies whether or not the matrix A is unit triangular. = 'N': Non-unit triangular = 'U': Unit triangular
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) The triangular matrix A. If UPLO = 'U', the leading n by n upper triangular part of the array A contains the upper triangular matrix, and the strictly lower triangular part of A is not referenced. If UPLO = 'L', the leading n by n lower triangular part of the array A contains the lower triangular matrix, and the strictly upper triangular part of A is not referenced. If DIAG = 'U', the diagonal elements of A are also not referenced and are assumed to be 1.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (N)
[out]	RAT	RAT is DOUBLE PRECISION The test ratio. If both RCOND and RCONDC are nonzero, RAT = MAX( RCOND, RCONDC )/MIN( RCOND, RCONDC ) - 1. If RAT = 0, the two estimates are exactly the same.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 123 of file dtrt06.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, UPLO
      INTEGER            LDA, N
      DOUBLE PRECISION   RAT, RCOND, RCONDC
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   ANORM, BIGNUM, EPS, RMAX, RMIN, SMLNUM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANTR
      EXTERNAL           dlamch, dlantr
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlabad
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
      rmax = max( rcond, rcondc )
      rmin = min( rcond, rcondc )
*
*     Do the easy cases first.
*
      IF( rmin.LT.zero ) THEN
*
*        Invalid value for RCOND or RCONDC, return 1/EPS.
*
         rat = one / eps
*
      ELSE IF( rmin.GT.zero ) THEN
*
*        Both estimates are positive, return RMAX/RMIN - 1.
*
         rat = rmax / rmin - one
*
      ELSE IF( rmax.EQ.zero ) THEN
*
*        Both estimates zero.
*
         rat = zero
*
      ELSE
*
*        One estimate is zero, the other is non-zero.  If the matrix is
*        ill-conditioned, return the nonzero estimate multiplied by
*        1/EPS; if the matrix is badly scaled, return the nonzero
*        estimate multiplied by BIGNUM/TMAX, where TMAX is the maximum
*        element in absolute value in A.
*
         smlnum = dlamch( 'Safe minimum' )
         bignum = one / smlnum
         CALL dlabad( smlnum, bignum )
         anorm = dlantr( 'M', uplo, diag, n, n, a, lda, work )
*
         rat = rmax*( min( bignum / max( one, anorm ), one / eps ) )
      END IF
*
      RETURN
*
*     End of DTRT06
*

Here is the call graph for this function:

Here is the caller graph for this function: