dtbt06()

subroutine dtbt06	(	double precision	RCOND,
		double precision	RCONDC,
		character	UPLO,
		character	DIAG,
		integer	N,
		integer	KD,
		double precision, dimension( ldab, * )	AB,
		integer	LDAB,
		double precision, dimension( * )	WORK,
		double precision	RAT
	)

DTBT06

Purpose:

 DTBT06 computes a test ratio comparing RCOND (the reciprocal
 condition number of a triangular matrix A) and RCONDC, the estimate
 computed by DTBCON.  Information about the triangular matrix A is
 used if one estimate is zero and the other is non-zero to decide if
 underflow in the estimate is justified.

Parameters

[in]	RCOND	RCOND is DOUBLE PRECISION The estimate of the reciprocal condition number obtained by forming the explicit inverse of the matrix A and computing RCOND = 1/( norm(A) * norm(inv(A)) ).
[in]	RCONDC	RCONDC is DOUBLE PRECISION The estimate of the reciprocal condition number computed by DTBCON.
[in]	UPLO	UPLO is CHARACTER Specifies whether the matrix A is upper or lower triangular. = 'U': Upper triangular = 'L': Lower triangular
[in]	DIAG	DIAG is CHARACTER Specifies whether or not the matrix A is unit triangular. = 'N': Non-unit triangular = 'U': Unit triangular
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	KD	KD is INTEGER The number of superdiagonals or subdiagonals of the triangular band matrix A. KD >= 0.
[in]	AB	AB is DOUBLE PRECISION array, dimension (LDAB,N) The upper or lower triangular band matrix A, stored in the first kd+1 rows of the array. The j-th column of A is stored in the j-th column of the array AB as follows: if UPLO = 'U', AB(kd+1+i-j,j) = A(i,j) for max(1,j-kd)<=i<=j; if UPLO = 'L', AB(1+i-j,j) = A(i,j) for j<=i<=min(n,j+kd).
[in]	LDAB	LDAB is INTEGER The leading dimension of the array AB. LDAB >= KD+1.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (N)
[out]	RAT	RAT is DOUBLE PRECISION The test ratio. If both RCOND and RCONDC are nonzero, RAT = MAX( RCOND, RCONDC )/MIN( RCOND, RCONDC ) - 1. If RAT = 0, the two estimates are exactly the same.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 127 of file dtbt06.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, UPLO
      INTEGER            KD, LDAB, N
      DOUBLE PRECISION   RAT, RCOND, RCONDC
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   AB( LDAB, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   ANORM, BIGNUM, EPS, RMAX, RMIN, SMLNUM
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANTB
      EXTERNAL           dlamch, dlantb
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlabad
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
      rmax = max( rcond, rcondc )
      rmin = min( rcond, rcondc )
*
*     Do the easy cases first.
*
      IF( rmin.LT.zero ) THEN
*
*        Invalid value for RCOND or RCONDC, return 1/EPS.
*
         rat = one / eps
*
      ELSE IF( rmin.GT.zero ) THEN
*
*        Both estimates are positive, return RMAX/RMIN - 1.
*
         rat = rmax / rmin - one
*
      ELSE IF( rmax.EQ.zero ) THEN
*
*        Both estimates zero.
*
         rat = zero
*
      ELSE
*
*        One estimate is zero, the other is non-zero.  If the matrix is
*        ill-conditioned, return the nonzero estimate multiplied by
*        1/EPS; if the matrix is badly scaled, return the nonzero
*        estimate multiplied by BIGNUM/TMAX, where TMAX is the maximum
*        element in absolute value in A.
*
         smlnum = dlamch( 'Safe minimum' )
         bignum = one / smlnum
         CALL dlabad( smlnum, bignum )
         anorm = dlantb( 'M', uplo, diag, n, kd, ab, ldab, work )
*
         rat = rmax*( min( bignum / max( one, anorm ), one / eps ) )
      END IF
*
      RETURN
*
*     End of DTBT06
*

Here is the call graph for this function:

Here is the caller graph for this function: