zget01()

subroutine zget01	(	integer	M,
		integer	N,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		complex*16, dimension( ldafac, * )	AFAC,
		integer	LDAFAC,
		integer, dimension( * )	IPIV,
		double precision, dimension( * )	RWORK,
		double precision	RESID
	)

ZGET01

Purpose:

 ZGET01 reconstructs a matrix A from its L*U factorization and
 computes the residual
    norm(L*U - A) / ( N * norm(A) * EPS ),
 where EPS is the machine epsilon.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix A. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix A. N >= 0.
[in]	A	A is COMPLEX*16 array, dimension (LDA,N) The original M x N matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[in,out]	AFAC	AFAC is COMPLEX*16 array, dimension (LDAFAC,N) The factored form of the matrix A. AFAC contains the factors L and U from the L*U factorization as computed by ZGETRF. Overwritten with the reconstructed matrix, and then with the difference L*U - A.
[in]	LDAFAC	LDAFAC is INTEGER The leading dimension of the array AFAC. LDAFAC >= max(1,M).
[in]	IPIV	IPIV is INTEGER array, dimension (N) The pivot indices from ZGETRF.
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (M)
[out]	RESID	RESID is DOUBLE PRECISION norm(L*U - A) / ( N * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 110 of file zget01.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDAFAC, M, N
      DOUBLE PRECISION   RESID
*     ..
*     .. Array Arguments ..
      INTEGER            IPIV( * )
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         A( LDA, * ), AFAC( LDAFAC, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      COMPLEX*16         CONE
      parameter( cone = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            I, J, K
      DOUBLE PRECISION   ANORM, EPS
      COMPLEX*16         T
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANGE
      COMPLEX*16         ZDOTU
      EXTERNAL           dlamch, zlange, zdotu
*     ..
*     .. External Subroutines ..
      EXTERNAL           zgemv, zlaswp, zscal, ztrmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, min
*     ..
*     .. Executable Statements ..
*
*     Quick exit if M = 0 or N = 0.
*
      IF( m.LE.0 .OR. n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Determine EPS and the norm of A.
*
      eps = dlamch( 'Epsilon' )
      anorm = zlange( '1', m, n, a, lda, rwork )
*
*     Compute the product L*U and overwrite AFAC with the result.
*     A column at a time of the product is obtained, starting with
*     column N.
*
      DO 10 k = n, 1, -1
         IF( k.GT.m ) THEN
            CALL ztrmv( 'Lower', 'No transpose', 'Unit', m, afac,
     $                  ldafac, afac( 1, k ), 1 )
         ELSE
*
*           Compute elements (K+1:M,K)
*
            t = afac( k, k )
            IF( k+1.LE.m ) THEN
               CALL zscal( m-k, t, afac( k+1, k ), 1 )
               CALL zgemv( 'No transpose', m-k, k-1, cone,
     $                     afac( k+1, 1 ), ldafac, afac( 1, k ), 1,
     $                     cone, afac( k+1, k ), 1 )
            END IF
*
*           Compute the (K,K) element
*
            afac( k, k ) = t + zdotu( k-1, afac( k, 1 ), ldafac,
     $                     afac( 1, k ), 1 )
*
*           Compute elements (1:K-1,K)
*
            CALL ztrmv( 'Lower', 'No transpose', 'Unit', k-1, afac,
     $                  ldafac, afac( 1, k ), 1 )
         END IF
   10 CONTINUE
      CALL zlaswp( n, afac, ldafac, 1, min( m, n ), ipiv, -1 )
*
*     Compute the difference  L*U - A  and store in AFAC.
*
      DO 30 j = 1, n
         DO 20 i = 1, m
            afac( i, j ) = afac( i, j ) - a( i, j )
   20    CONTINUE
   30 CONTINUE
*
*     Compute norm( L*U - A ) / ( N * norm(A) * EPS )
*
      resid = zlange( '1', m, n, afac, ldafac, rwork )
*
      IF( anorm.LE.zero ) THEN
         IF( resid.NE.zero )
     $      resid = one / eps
      ELSE
         resid = ( ( resid / dble( n ) ) / anorm ) / eps
      END IF
*
      RETURN
*
*     End of ZGET01
*

Here is the call graph for this function:

Here is the caller graph for this function: