ztpt06()

subroutine ztpt06	(	double precision	RCOND,
		double precision	RCONDC,
		character	UPLO,
		character	DIAG,
		integer	N,
		complex*16, dimension( * )	AP,
		double precision, dimension( * )	RWORK,
		double precision	RAT
	)

ZTPT06

Purpose:

 ZTPT06 computes a test ratio comparing RCOND (the reciprocal
 condition number of the triangular matrix A) and RCONDC, the estimate
 computed by ZTPCON.  Information about the triangular matrix is used
 if one estimate is zero and the other is non-zero to decide if
 underflow in the estimate is justified.

Parameters

[in]	RCOND	RCOND is DOUBLE PRECISION The estimate of the reciprocal condition number obtained by forming the explicit inverse of the matrix A and computing RCOND = 1/( norm(A) * norm(inv(A)) ).
[in]	RCONDC	RCONDC is DOUBLE PRECISION The estimate of the reciprocal condition number computed by ZTPCON.
[in]	UPLO	UPLO is CHARACTER Specifies whether the matrix A is upper or lower triangular. = 'U': Upper triangular = 'L': Lower triangular
[in]	DIAG	DIAG is CHARACTER Specifies whether or not the matrix A is unit triangular. = 'N': Non-unit triangular = 'U': Unit triangular
[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in]	AP	AP is COMPLEX*16 array, dimension (N*(N+1)/2) The upper or lower triangular matrix A, packed columnwise in a linear array. The j-th column of A is stored in the array AP as follows: if UPLO = 'U', AP((j-1)*j/2 + i) = A(i,j) for 1<=i<=j; if UPLO = 'L', AP((j-1)*(n-j) + j*(j+1)/2 + i-j) = A(i,j) for j<=i<=n.
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (N)
[out]	RAT	RAT is DOUBLE PRECISION The test ratio. If both RCOND and RCONDC are nonzero, RAT = MAX( RCOND, RCONDC )/MIN( RCOND, RCONDC ) - 1. If RAT = 0, the two estimates are exactly the same.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 114 of file ztpt06.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          DIAG, UPLO
      INTEGER            N
      DOUBLE PRECISION   RAT, RCOND, RCONDC
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   RWORK( * )
      COMPLEX*16         AP( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      DOUBLE PRECISION   ANORM, BIGNUM, EPS, RMAX, RMIN
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, ZLANTP
      EXTERNAL           dlamch, zlantp
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
      eps = dlamch( 'Epsilon' )
      rmax = max( rcond, rcondc )
      rmin = min( rcond, rcondc )
*
*     Do the easy cases first.
*
      IF( rmin.LT.zero ) THEN
*
*        Invalid value for RCOND or RCONDC, return 1/EPS.
*
         rat = one / eps
*
      ELSE IF( rmin.GT.zero ) THEN
*
*        Both estimates are positive, return RMAX/RMIN - 1.
*
         rat = rmax / rmin - one
*
      ELSE IF( rmax.EQ.zero ) THEN
*
*        Both estimates zero.
*
         rat = zero
*
      ELSE
*
*        One estimate is zero, the other is non-zero.  If the matrix is
*        ill-conditioned, return the nonzero estimate multiplied by
*        1/EPS; if the matrix is badly scaled, return the nonzero
*        estimate multiplied by BIGNUM/TMAX, where TMAX is the maximum
*        element in absolute value in A.
*
         bignum = one / dlamch( 'Safe minimum' )
         anorm = zlantp( 'M', uplo, diag, n, ap, rwork )
*
         rat = rmax*( min( bignum / max( one, anorm ), one / eps ) )
      END IF
*
      RETURN
*
*     End of ZTPT06
*

Here is the caller graph for this function: