ztplqt2()

subroutine ztplqt2	(	integer	M,
		integer	N,
		integer	L,
		complex*16, dimension( lda, * )	A,
		integer	LDA,
		complex*16, dimension( ldb, * )	B,
		integer	LDB,
		complex*16, dimension( ldt, * )	T,
		integer	LDT,
		integer	INFO
	)

ZTPLQT2 computes a LQ factorization of a real or complex "triangular-pentagonal" matrix, which is composed of a triangular block and a pentagonal block, using the compact WY representation for Q.

Download ZTPLQT2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZTPLQT2 computes a LQ a factorization of a complex "triangular-pentagonal"
 matrix C, which is composed of a triangular block A and pentagonal block B,
 using the compact WY representation for Q.

Parameters

[in]	M	M is INTEGER The total number of rows of the matrix B. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix B, and the order of the triangular matrix A. N >= 0.
[in]	L	L is INTEGER The number of rows of the lower trapezoidal part of B. MIN(M,N) >= L >= 0. See Further Details.
[in,out]	A	A is COMPLEX*16 array, dimension (LDA,M) On entry, the lower triangular M-by-M matrix A. On exit, the elements on and below the diagonal of the array contain the lower triangular matrix L.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,M).
[in,out]	B	B is COMPLEX*16 array, dimension (LDB,N) On entry, the pentagonal M-by-N matrix B. The first N-L columns are rectangular, and the last L columns are lower trapezoidal. On exit, B contains the pentagonal matrix V. See Further Details.
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,M).
[out]	T	T is COMPLEX*16 array, dimension (LDT,M) The N-by-N upper triangular factor T of the block reflector. See Further Details.
[in]	LDT	LDT is INTEGER The leading dimension of the array T. LDT >= max(1,M)
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

June 2017

Further Details:

  The input matrix C is a M-by-(M+N) matrix

               C = [ A ][ B ]


  where A is an lower triangular M-by-M matrix, and B is M-by-N pentagonal
  matrix consisting of a M-by-(N-L) rectangular matrix B1 left of a M-by-L
  upper trapezoidal matrix B2:

               B = [ B1 ][ B2 ]
                   [ B1 ]  <-     M-by-(N-L) rectangular
                   [ B2 ]  <-     M-by-L lower trapezoidal.

  The lower trapezoidal matrix B2 consists of the first L columns of a
  N-by-N lower triangular matrix, where 0 <= L <= MIN(M,N).  If L=0,
  B is rectangular M-by-N; if M=L=N, B is lower triangular.

  The matrix W stores the elementary reflectors H(i) in the i-th row
  above the diagonal (of A) in the M-by-(M+N) input matrix C

               C = [ A ][ B ]
                   [ A ]  <- lower triangular M-by-M
                   [ B ]  <- M-by-N pentagonal

  so that W can be represented as

               W = [ I ][ V ]
                   [ I ]  <- identity, M-by-M
                   [ V ]  <- M-by-N, same form as B.

  Thus, all of information needed for W is contained on exit in B, which
  we call V above.  Note that V has the same form as B; that is,

               W = [ V1 ][ V2 ]
                   [ V1 ] <-     M-by-(N-L) rectangular
                   [ V2 ] <-     M-by-L lower trapezoidal.

  The rows of V represent the vectors which define the H(i)'s.
  The (M+N)-by-(M+N) block reflector H is then given by

               H = I - W**T * T * W

  where W^H is the conjugate transpose of W and T is the upper triangular
  factor of the block reflector.

Definition at line 179 of file ztplqt2.f.

*
*  -- LAPACK computational routine (version 3.7.1) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     June 2017
*
*     .. Scalar Arguments ..
      INTEGER        INFO, LDA, LDB, LDT, N, M, L
*     ..
*     .. Array Arguments ..
      COMPLEX*16     A( LDA, * ), B( LDB, * ), T( LDT, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      COMPLEX*16  ONE, ZERO
      parameter( zero = ( 0.0d+0, 0.0d+0 ),one  = ( 1.0d+0, 0.0d+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER   I, J, P, MP, NP
      COMPLEX*16   ALPHA
*     ..
*     .. External Subroutines ..
      EXTERNAL  zlarfg, zgemv, zgerc, ztrmv, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC max, min
*     ..
*     .. Executable Statements ..
*
*     Test the input arguments
*
      info = 0
      IF( m.LT.0 ) THEN
         info = -1
      ELSE IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( l.LT.0 .OR. l.GT.min(m,n) ) THEN
         info = -3
      ELSE IF( lda.LT.max( 1, m ) ) THEN
         info = -5
      ELSE IF( ldb.LT.max( 1, m ) ) THEN
         info = -7
      ELSE IF( ldt.LT.max( 1, m ) ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'ZTPLQT2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 .OR. m.EQ.0 ) RETURN
*
      DO i = 1, m
*
*        Generate elementary reflector H(I) to annihilate B(I,:)
*
         p = n-l+min( l, i )
         CALL zlarfg( p+1, a( i, i ), b( i, 1 ), ldb, t( 1, i ) )
         t(1,i)=conjg(t(1,i))
         IF( i.LT.m ) THEN
            DO j = 1, p
               b( i, j ) = conjg(b(i,j))
            END DO
*
*           W(M-I:1) := C(I+1:M,I:N) * C(I,I:N) [use W = T(M,:)]
*
            DO j = 1, m-i
               t( m, j ) = (a( i+j, i ))
            END DO
            CALL zgemv( 'N', m-i, p, one, b( i+1, 1 ), ldb,
     $                  b( i, 1 ), ldb, one, t( m, 1 ), ldt )
*
*           C(I+1:M,I:N) = C(I+1:M,I:N) + alpha * C(I,I:N)*W(M-1:1)^H
*
            alpha = -(t( 1, i ))
            DO j = 1, m-i
               a( i+j, i ) = a( i+j, i ) + alpha*(t( m, j ))
            END DO
            CALL zgerc( m-i, p, (alpha),  t( m, 1 ), ldt,
     $          b( i, 1 ), ldb, b( i+1, 1 ), ldb )
            DO j = 1, p
               b( i, j ) = conjg(b(i,j))
            END DO
         END IF
      END DO
*
      DO i = 2, m
*
*        T(I,1:I-1) := C(I:I-1,1:N)**H * (alpha * C(I,I:N))
*
         alpha = -(t( 1, i ))
         DO j = 1, i-1
            t( i, j ) = zero
         END DO
         p = min( i-1, l )
         np = min( n-l+1, n )
         mp = min( p+1, m )
         DO j = 1, n-l+p
           b(i,j)=conjg(b(i,j))
         END DO
*
*        Triangular part of B2
*
         DO j = 1, p
            t( i, j ) = (alpha*b( i, n-l+j ))
         END DO
         CALL ztrmv( 'L', 'N', 'N', p, b( 1, np ), ldb,
     $               t( i, 1 ), ldt )
*
*        Rectangular part of B2
*
         CALL zgemv( 'N', i-1-p, l,  alpha, b( mp, np ), ldb,
     $               b( i, np ), ldb, zero, t( i,mp ), ldt )
*
*        B1
 
*
         CALL zgemv( 'N', i-1, n-l, alpha, b, ldb, b( i, 1 ), ldb,
     $               one, t( i, 1 ), ldt )
*
 
*
*        T(1:I-1,I) := T(1:I-1,1:I-1) * T(I,1:I-1)
*
         DO j = 1, i-1
            t(i,j)=conjg(t(i,j))
         END DO
         CALL ztrmv( 'L', 'C', 'N', i-1, t, ldt, t( i, 1 ), ldt )
         DO j = 1, i-1
            t(i,j)=conjg(t(i,j))
         END DO
         DO j = 1, n-l+p
            b(i,j)=conjg(b(i,j))
         END DO
*
*        T(I,I) = tau(I)
*
         t( i, i ) = t( 1, i )
         t( 1, i ) = zero
      END DO
      DO i=1,m
         DO j= i+1,m
            t(i,j)=(t(j,i))
            t(j,i)=zero
         END DO
      END DO
 
*
*     End of ZTPLQT2
*

Here is the call graph for this function:

Here is the caller graph for this function: