dgebak()

subroutine dgebak	(	character	JOB,
		character	SIDE,
		integer	N,
		integer	ILO,
		integer	IHI,
		double precision, dimension( * )	SCALE,
		integer	M,
		double precision, dimension( ldv, * )	V,
		integer	LDV,
		integer	INFO
	)

DGEBAK

Download DGEBAK + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DGEBAK forms the right or left eigenvectors of a real general matrix
 by backward transformation on the computed eigenvectors of the
 balanced matrix output by DGEBAL.

Parameters

[in]	JOB	JOB is CHARACTER*1 Specifies the type of backward transformation required: = 'N': do nothing, return immediately; = 'P': do backward transformation for permutation only; = 'S': do backward transformation for scaling only; = 'B': do backward transformations for both permutation and scaling. JOB must be the same as the argument JOB supplied to DGEBAL.
[in]	SIDE	SIDE is CHARACTER*1 = 'R': V contains right eigenvectors; = 'L': V contains left eigenvectors.
[in]	N	N is INTEGER The number of rows of the matrix V. N >= 0.
[in]	ILO	ILO is INTEGER
[in]	IHI	IHI is INTEGER The integers ILO and IHI determined by DGEBAL. 1 <= ILO <= IHI <= N, if N > 0; ILO=1 and IHI=0, if N=0.
[in]	SCALE	SCALE is DOUBLE PRECISION array, dimension (N) Details of the permutation and scaling factors, as returned by DGEBAL.
[in]	M	M is INTEGER The number of columns of the matrix V. M >= 0.
[in,out]	V	V is DOUBLE PRECISION array, dimension (LDV,M) On entry, the matrix of right or left eigenvectors to be transformed, as returned by DHSEIN or DTREVC. On exit, V is overwritten by the transformed eigenvectors.
[in]	LDV	LDV is INTEGER The leading dimension of the array V. LDV >= max(1,N).
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -i, the i-th argument had an illegal value.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 132 of file dgebak.f.

*
*  -- LAPACK computational routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          JOB, SIDE
      INTEGER            IHI, ILO, INFO, LDV, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   SCALE( * ), V( LDV, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LEFTV, RIGHTV
      INTEGER            I, II, K
      DOUBLE PRECISION   S
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           dscal, dswap, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min
*     ..
*     .. Executable Statements ..
*
*     Decode and Test the input parameters
*
      rightv = lsame( side, 'R' )
      leftv = lsame( side, 'L' )
*
      info = 0
      IF( .NOT.lsame( job, 'N' ) .AND. .NOT.lsame( job, 'P' ) .AND.
     $    .NOT.lsame( job, 'S' ) .AND. .NOT.lsame( job, 'B' ) ) THEN
         info = -1
      ELSE IF( .NOT.rightv .AND. .NOT.leftv ) THEN
         info = -2
      ELSE IF( n.LT.0 ) THEN
         info = -3
      ELSE IF( ilo.LT.1 .OR. ilo.GT.max( 1, n ) ) THEN
         info = -4
      ELSE IF( ihi.LT.min( ilo, n ) .OR. ihi.GT.n ) THEN
         info = -5
      ELSE IF( m.LT.0 ) THEN
         info = -7
      ELSE IF( ldv.LT.max( 1, n ) ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DGEBAK', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
      IF( m.EQ.0 )
     $   RETURN
      IF( lsame( job, 'N' ) )
     $   RETURN
*
      IF( ilo.EQ.ihi )
     $   GO TO 30
*
*     Backward balance
*
      IF( lsame( job, 'S' ) .OR. lsame( job, 'B' ) ) THEN
*
         IF( rightv ) THEN
            DO 10 i = ilo, ihi
               s = scale( i )
               CALL dscal( m, s, v( i, 1 ), ldv )
   10       CONTINUE
         END IF
*
         IF( leftv ) THEN
            DO 20 i = ilo, ihi
               s = one / scale( i )
               CALL dscal( m, s, v( i, 1 ), ldv )
   20       CONTINUE
         END IF
*
      END IF
*
*     Backward permutation
*
*     For  I = ILO-1 step -1 until 1,
*              IHI+1 step 1 until N do --
*
   30 CONTINUE
      IF( lsame( job, 'P' ) .OR. lsame( job, 'B' ) ) THEN
         IF( rightv ) THEN
            DO 40 ii = 1, n
               i = ii
               IF( i.GE.ilo .AND. i.LE.ihi )
     $            GO TO 40
               IF( i.LT.ilo )
     $            i = ilo - ii
               k = scale( i )
               IF( k.EQ.i )
     $            GO TO 40
               CALL dswap( m, v( i, 1 ), ldv, v( k, 1 ), ldv )
   40       CONTINUE
         END IF
*
         IF( leftv ) THEN
            DO 50 ii = 1, n
               i = ii
               IF( i.GE.ilo .AND. i.LE.ihi )
     $            GO TO 50
               IF( i.LT.ilo )
     $            i = ilo - ii
               k = scale( i )
               IF( k.EQ.i )
     $            GO TO 50
               CALL dswap( m, v( i, 1 ), ldv, v( k, 1 ), ldv )
   50       CONTINUE
         END IF
      END IF
*
      RETURN
*
*     End of DGEBAK
*

Here is the call graph for this function:

Here is the caller graph for this function: