slqt03()

subroutine slqt03	(	integer	M,
		integer	N,
		integer	K,
		real, dimension( lda, * )	AF,
		real, dimension( lda, * )	C,
		real, dimension( lda, * )	CC,
		real, dimension( lda, * )	Q,
		integer	LDA,
		real, dimension( * )	TAU,
		real, dimension( lwork )	WORK,
		integer	LWORK,
		real, dimension( * )	RWORK,
		real, dimension( * )	RESULT
	)

SLQT03

Purpose:

 SLQT03 tests SORMLQ, which computes Q*C, Q'*C, C*Q or C*Q'.

 SLQT03 compares the results of a call to SORMLQ with the results of
 forming Q explicitly by a call to SORGLQ and then performing matrix
 multiplication by a call to SGEMM.

Parameters

[in]	M	M is INTEGER The number of rows or columns of the matrix C; C is n-by-m if Q is applied from the left, or m-by-n if Q is applied from the right. M >= 0.
[in]	N	N is INTEGER The order of the orthogonal matrix Q. N >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the orthogonal matrix Q. N >= K >= 0.
[in]	AF	AF is REAL array, dimension (LDA,N) Details of the LQ factorization of an m-by-n matrix, as returned by SGELQF. See SGELQF for further details.
[out]	C	C is REAL array, dimension (LDA,N)
[out]	CC	CC is REAL array, dimension (LDA,N)
[out]	Q	Q is REAL array, dimension (LDA,N)
[in]	LDA	LDA is INTEGER The leading dimension of the arrays AF, C, CC, and Q.
[in]	TAU	TAU is REAL array, dimension (min(M,N)) The scalar factors of the elementary reflectors corresponding to the LQ factorization in AF.
[out]	WORK	WORK is REAL array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The length of WORK. LWORK must be at least M, and should be M*NB, where NB is the blocksize for this environment.
[out]	RWORK	RWORK is REAL array, dimension (M)
[out]	RESULT	RESULT is REAL array, dimension (4) The test ratios compare two techniques for multiplying a random matrix C by an n-by-n orthogonal matrix Q. RESULT(1) = norm( Q*C - Q*C ) / ( N * norm(C) * EPS ) RESULT(2) = norm( C*Q - C*Q ) / ( N * norm(C) * EPS ) RESULT(3) = norm( Q'*C - Q'*C )/ ( N * norm(C) * EPS ) RESULT(4) = norm( C*Q' - C*Q' )/ ( N * norm(C) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 138 of file slqt03.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      REAL               AF( LDA, * ), C( LDA, * ), CC( LDA, * ),
     $                   Q( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE
      parameter( one = 1.0e0 )
      REAL               ROGUE
      parameter( rogue = -1.0e+10 )
*     ..
*     .. Local Scalars ..
      CHARACTER          SIDE, TRANS
      INTEGER            INFO, ISIDE, ITRANS, J, MC, NC
      REAL               CNORM, EPS, RESID
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH, SLANGE
      EXTERNAL           lsame, slamch, slange
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slacpy, slarnv, slaset, sorglq, sormlq
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, real
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Data statements ..
      DATA               iseed / 1988, 1989, 1990, 1991 /
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'Epsilon' )
*
*     Copy the first k rows of the factorization to the array Q
*
      CALL slaset( 'Full', n, n, rogue, rogue, q, lda )
      CALL slacpy( 'Upper', k, n-1, af( 1, 2 ), lda, q( 1, 2 ), lda )
*
*     Generate the n-by-n matrix Q
*
      srnamt = 'SORGLQ'
      CALL sorglq( n, n, k, q, lda, tau, work, lwork, info )
*
      DO 30 iside = 1, 2
         IF( iside.EQ.1 ) THEN
            side = 'L'
            mc = n
            nc = m
         ELSE
            side = 'R'
            mc = m
            nc = n
         END IF
*
*        Generate MC by NC matrix C
*
         DO 10 j = 1, nc
            CALL slarnv( 2, iseed, mc, c( 1, j ) )
   10    CONTINUE
         cnorm = slange( '1', mc, nc, c, lda, rwork )
         IF( cnorm.EQ.0.0 )
     $      cnorm = one
*
         DO 20 itrans = 1, 2
            IF( itrans.EQ.1 ) THEN
               trans = 'N'
            ELSE
               trans = 'T'
            END IF
*
*           Copy C
*
            CALL slacpy( 'Full', mc, nc, c, lda, cc, lda )
*
*           Apply Q or Q' to C
*
            srnamt = 'SORMLQ'
            CALL sormlq( side, trans, mc, nc, k, af, lda, tau, cc, lda,
     $                   work, lwork, info )
*
*           Form explicit product and subtract
*
            IF( lsame( side, 'L' ) ) THEN
               CALL sgemm( trans, 'No transpose', mc, nc, mc, -one, q,
     $                     lda, c, lda, one, cc, lda )
            ELSE
               CALL sgemm( 'No transpose', trans, mc, nc, nc, -one, c,
     $                     lda, q, lda, one, cc, lda )
            END IF
*
*           Compute error in the difference
*
            resid = slange( '1', mc, nc, cc, lda, rwork )
            result( ( iside-1 )*2+itrans ) = resid /
     $         ( real( max( 1, n ) )*cnorm*eps )
*
   20    CONTINUE
   30 CONTINUE
*
      RETURN
*
*     End of SLQT03
*

Here is the call graph for this function:

Here is the caller graph for this function: