sppt01()

subroutine sppt01	(	character	UPLO,
		integer	N,
		real, dimension( * )	A,
		real, dimension( * )	AFAC,
		real, dimension( * )	RWORK,
		real	RESID
	)

SPPT01

Purpose:

 SPPT01 reconstructs a symmetric positive definite packed matrix A
 from its L*L' or U'*U factorization and computes the residual
    norm( L*L' - A ) / ( N * norm(A) * EPS ) or
    norm( U'*U - A ) / ( N * norm(A) * EPS ),
 where EPS is the machine epsilon.

Parameters

[in]	UPLO	UPLO is CHARACTER*1 Specifies whether the upper or lower triangular part of the symmetric matrix A is stored: = 'U': Upper triangular = 'L': Lower triangular
[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is REAL array, dimension (N*(N+1)/2) The original symmetric matrix A, stored as a packed triangular matrix.
[in,out]	AFAC	AFAC is REAL array, dimension (N*(N+1)/2) On entry, the factor L or U from the L*L' or U'*U factorization of A, stored as a packed triangular matrix. Overwritten with the reconstructed matrix, and then with the difference L*L' - A (or U'*U - A).
[out]	RWORK	RWORK is REAL array, dimension (N)
[out]	RESID	RESID is REAL If UPLO = 'L', norm(L*L' - A) / ( N * norm(A) * EPS ) If UPLO = 'U', norm(U'*U - A) / ( N * norm(A) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 95 of file sppt01.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            N
      REAL               RESID
*     ..
*     .. Array Arguments ..
      REAL               A( * ), AFAC( * ), RWORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE
      parameter( zero = 0.0e+0, one = 1.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, K, KC, NPP
      REAL               ANORM, EPS, T
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SDOT, SLAMCH, SLANSP
      EXTERNAL           lsame, sdot, slamch, slansp
*     ..
*     .. External Subroutines ..
      EXTERNAL           sscal, sspr, stpmv
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          real
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0
*
      IF( n.LE.0 ) THEN
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0.
*
      eps = slamch( 'Epsilon' )
      anorm = slansp( '1', uplo, n, a, rwork )
      IF( anorm.LE.zero ) THEN
         resid = one / eps
         RETURN
      END IF
*
*     Compute the product U'*U, overwriting U.
*
      IF( lsame( uplo, 'U' ) ) THEN
         kc = ( n*( n-1 ) ) / 2 + 1
         DO 10 k = n, 1, -1
*
*           Compute the (K,K) element of the result.
*
            t = sdot( k, afac( kc ), 1, afac( kc ), 1 )
            afac( kc+k-1 ) = t
*
*           Compute the rest of column K.
*
            IF( k.GT.1 ) THEN
               CALL stpmv( 'Upper', 'Transpose', 'Non-unit', k-1, afac,
     $                     afac( kc ), 1 )
               kc = kc - ( k-1 )
            END IF
   10    CONTINUE
*
*     Compute the product L*L', overwriting L.
*
      ELSE
         kc = ( n*( n+1 ) ) / 2
         DO 20 k = n, 1, -1
*
*           Add a multiple of column K of the factor L to each of
*           columns K+1 through N.
*
            IF( k.LT.n )
     $         CALL sspr( 'Lower', n-k, one, afac( kc+1 ), 1,
     $                    afac( kc+n-k+1 ) )
*
*           Scale column K by the diagonal element.
*
            t = afac( kc )
            CALL sscal( n-k+1, t, afac( kc ), 1 )
*
            kc = kc - ( n-k+2 )
   20    CONTINUE
      END IF
*
*     Compute the difference  L*L' - A (or U'*U - A).
*
      npp = n*( n+1 ) / 2
      DO 30 i = 1, npp
         afac( i ) = afac( i ) - a( i )
   30 CONTINUE
*
*     Compute norm( L*U - A ) / ( N * norm(A) * EPS )
*
      resid = slansp( '1', uplo, n, afac, rwork )
*
      resid = ( ( resid / real( n ) ) / anorm ) / eps
*
      RETURN
*
*     End of SPPT01
*

Here is the call graph for this function:

Here is the caller graph for this function: