zpttrf()

subroutine zpttrf	(	integer	N,
		double precision, dimension( * )	D,
		complex*16, dimension( * )	E,
		integer	INFO
	)

ZPTTRF

Download ZPTTRF + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZPTTRF computes the L*D*L**H factorization of a complex Hermitian
 positive definite tridiagonal matrix A.  The factorization may also
 be regarded as having the form A = U**H *D*U.

Parameters

[in]	N	N is INTEGER The order of the matrix A. N >= 0.
[in,out]	D	D is DOUBLE PRECISION array, dimension (N) On entry, the n diagonal elements of the tridiagonal matrix A. On exit, the n diagonal elements of the diagonal matrix D from the L*D*L**H factorization of A.
[in,out]	E	E is COMPLEX*16 array, dimension (N-1) On entry, the (n-1) subdiagonal elements of the tridiagonal matrix A. On exit, the (n-1) subdiagonal elements of the unit bidiagonal factor L from the L*D*L**H factorization of A. E can also be regarded as the superdiagonal of the unit bidiagonal factor U from the U**H *D*U factorization of A.
[out]	INFO	INFO is INTEGER = 0: successful exit < 0: if INFO = -k, the k-th argument had an illegal value > 0: if INFO = k, the leading minor of order k is not positive definite; if k < N, the factorization could not be completed, while if k = N, the factorization was completed, but D(N) <= 0.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 94 of file zpttrf.f.

*
*  -- LAPACK computational routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            INFO, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * )
      COMPLEX*16         E( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO
      parameter( zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, I4
      DOUBLE PRECISION   EII, EIR, F, G
*     ..
*     .. External Subroutines ..
      EXTERNAL           xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, dcmplx, dimag, mod
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -1
         CALL xerbla( 'ZPTTRF', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
*     Compute the L*D*L**H (or U**H *D*U) factorization of A.
*
      i4 = mod( n-1, 4 )
      DO 10 i = 1, i4
         IF( d( i ).LE.zero ) THEN
            info = i
            GO TO 30
         END IF
         eir = dble( e( i ) )
         eii = dimag( e( i ) )
         f = eir / d( i )
         g = eii / d( i )
         e( i ) = dcmplx( f, g )
         d( i+1 ) = d( i+1 ) - f*eir - g*eii
   10 CONTINUE
*
      DO 20 i = i4 + 1, n - 4, 4
*
*        Drop out of the loop if d(i) <= 0: the matrix is not positive
*        definite.
*
         IF( d( i ).LE.zero ) THEN
            info = i
            GO TO 30
         END IF
*
*        Solve for e(i) and d(i+1).
*
         eir = dble( e( i ) )
         eii = dimag( e( i ) )
         f = eir / d( i )
         g = eii / d( i )
         e( i ) = dcmplx( f, g )
         d( i+1 ) = d( i+1 ) - f*eir - g*eii
*
         IF( d( i+1 ).LE.zero ) THEN
            info = i + 1
            GO TO 30
         END IF
*
*        Solve for e(i+1) and d(i+2).
*
         eir = dble( e( i+1 ) )
         eii = dimag( e( i+1 ) )
         f = eir / d( i+1 )
         g = eii / d( i+1 )
         e( i+1 ) = dcmplx( f, g )
         d( i+2 ) = d( i+2 ) - f*eir - g*eii
*
         IF( d( i+2 ).LE.zero ) THEN
            info = i + 2
            GO TO 30
         END IF
*
*        Solve for e(i+2) and d(i+3).
*
         eir = dble( e( i+2 ) )
         eii = dimag( e( i+2 ) )
         f = eir / d( i+2 )
         g = eii / d( i+2 )
         e( i+2 ) = dcmplx( f, g )
         d( i+3 ) = d( i+3 ) - f*eir - g*eii
*
         IF( d( i+3 ).LE.zero ) THEN
            info = i + 3
            GO TO 30
         END IF
*
*        Solve for e(i+3) and d(i+4).
*
         eir = dble( e( i+3 ) )
         eii = dimag( e( i+3 ) )
         f = eir / d( i+3 )
         g = eii / d( i+3 )
         e( i+3 ) = dcmplx( f, g )
         d( i+4 ) = d( i+4 ) - f*eir - g*eii
   20 CONTINUE
*
*     Check d(n) for positive definiteness.
*
      IF( d( n ).LE.zero )
     $   info = n
*
   30 CONTINUE
      RETURN
*
*     End of ZPTTRF
*

Here is the call graph for this function:

Here is the caller graph for this function: