slas2()

subroutine slas2	(	real	F,
		real	G,
		real	H,
		real	SSMIN,
		real	SSMAX
	)

SLAS2 computes singular values of a 2-by-2 triangular matrix.

Download SLAS2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SLAS2  computes the singular values of the 2-by-2 matrix
    [  F   G  ]
    [  0   H  ].
 On return, SSMIN is the smaller singular value and SSMAX is the
 larger singular value.

Parameters

[in]	F	F is REAL The (1,1) element of the 2-by-2 matrix.
[in]	G	G is REAL The (1,2) element of the 2-by-2 matrix.
[in]	H	H is REAL The (2,2) element of the 2-by-2 matrix.
[out]	SSMIN	SSMIN is REAL The smaller singular value.
[out]	SSMAX	SSMAX is REAL The larger singular value.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Further Details:

  Barring over/underflow, all output quantities are correct to within
  a few units in the last place (ulps), even in the absence of a guard
  digit in addition/subtraction.

  In IEEE arithmetic, the code works correctly if one matrix element is
  infinite.

  Overflow will not occur unless the largest singular value itself
  overflows, or is within a few ulps of overflow. (On machines with
  partial overflow, like the Cray, overflow may occur if the largest
  singular value is within a factor of 2 of overflow.)

  Underflow is harmless if underflow is gradual. Otherwise, results
  may correspond to a matrix modified by perturbations of size near
  the underflow threshold.

Definition at line 109 of file slas2.f.

*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      REAL               F, G, H, SSMAX, SSMIN
*     ..
*
*  ====================================================================
*
*     .. Parameters ..
      REAL               ZERO
      parameter( zero = 0.0e0 )
      REAL               ONE
      parameter( one = 1.0e0 )
      REAL               TWO
      parameter( two = 2.0e0 )
*     ..
*     .. Local Scalars ..
      REAL               AS, AT, AU, C, FA, FHMN, FHMX, GA, HA
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sqrt
*     ..
*     .. Executable Statements ..
*
      fa = abs( f )
      ga = abs( g )
      ha = abs( h )
      fhmn = min( fa, ha )
      fhmx = max( fa, ha )
      IF( fhmn.EQ.zero ) THEN
         ssmin = zero
         IF( fhmx.EQ.zero ) THEN
            ssmax = ga
         ELSE
            ssmax = max( fhmx, ga )*sqrt( one+
     $              ( min( fhmx, ga ) / max( fhmx, ga ) )**2 )
         END IF
      ELSE
         IF( ga.LT.fhmx ) THEN
            as = one + fhmn / fhmx
            at = ( fhmx-fhmn ) / fhmx
            au = ( ga / fhmx )**2
            c = two / ( sqrt( as*as+au )+sqrt( at*at+au ) )
            ssmin = fhmn*c
            ssmax = fhmx / c
         ELSE
            au = fhmx / ga
            IF( au.EQ.zero ) THEN
*
*              Avoid possible harmful underflow if exponent range
*              asymmetric (true SSMIN may not underflow even if
*              AU underflows)
*
               ssmin = ( fhmn*fhmx ) / ga
               ssmax = ga
            ELSE
               as = one + fhmn / fhmx
               at = ( fhmx-fhmn ) / fhmx
               c = one / ( sqrt( one+( as*au )**2 )+
     $             sqrt( one+( at*au )**2 ) )
               ssmin = ( fhmn*c )*au
               ssmin = ssmin + ssmin
               ssmax = ga / ( c+c )
            END IF
         END IF
      END IF
      RETURN
*
*     End of SLAS2
*

Here is the caller graph for this function: