dlasd8()

subroutine dlasd8	(	integer	ICOMPQ,
		integer	K,
		double precision, dimension( * )	D,
		double precision, dimension( * )	Z,
		double precision, dimension( * )	VF,
		double precision, dimension( * )	VL,
		double precision, dimension( * )	DIFL,
		double precision, dimension( lddifr, * )	DIFR,
		integer	LDDIFR,
		double precision, dimension( * )	DSIGMA,
		double precision, dimension( * )	WORK,
		integer	INFO
	)

DLASD8 finds the square roots of the roots of the secular equation, and stores, for each element in D, the distance to its two nearest poles. Used by sbdsdc.

Download DLASD8 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 DLASD8 finds the square roots of the roots of the secular equation,
 as defined by the values in DSIGMA and Z. It makes the appropriate
 calls to DLASD4, and stores, for each  element in D, the distance
 to its two nearest poles (elements in DSIGMA). It also updates
 the arrays VF and VL, the first and last components of all the
 right singular vectors of the original bidiagonal matrix.

 DLASD8 is called from DLASD6.

Parameters

[in]	ICOMPQ	ICOMPQ is INTEGER Specifies whether singular vectors are to be computed in factored form in the calling routine: = 0: Compute singular values only. = 1: Compute singular vectors in factored form as well.
[in]	K	K is INTEGER The number of terms in the rational function to be solved by DLASD4. K >= 1.
[out]	D	D is DOUBLE PRECISION array, dimension ( K ) On output, D contains the updated singular values.
[in,out]	Z	Z is DOUBLE PRECISION array, dimension ( K ) On entry, the first K elements of this array contain the components of the deflation-adjusted updating row vector. On exit, Z is updated.
[in,out]	VF	VF is DOUBLE PRECISION array, dimension ( K ) On entry, VF contains information passed through DBEDE8. On exit, VF contains the first K components of the first components of all right singular vectors of the bidiagonal matrix.
[in,out]	VL	VL is DOUBLE PRECISION array, dimension ( K ) On entry, VL contains information passed through DBEDE8. On exit, VL contains the first K components of the last components of all right singular vectors of the bidiagonal matrix.
[out]	DIFL	DIFL is DOUBLE PRECISION array, dimension ( K ) On exit, DIFL(I) = D(I) - DSIGMA(I).
[out]	DIFR	DIFR is DOUBLE PRECISION array, dimension ( LDDIFR, 2 ) if ICOMPQ = 1 and dimension ( K ) if ICOMPQ = 0. On exit, DIFR(I,1) = D(I) - DSIGMA(I+1), DIFR(K,1) is not defined and will not be referenced. If ICOMPQ = 1, DIFR(1:K,2) is an array containing the normalizing factors for the right singular vector matrix.
[in]	LDDIFR	LDDIFR is INTEGER The leading dimension of DIFR, must be at least K.
[in,out]	DSIGMA	DSIGMA is DOUBLE PRECISION array, dimension ( K ) On entry, the first K elements of this array contain the old roots of the deflated updating problem. These are the poles of the secular equation. On exit, the elements of DSIGMA may be very slightly altered in value.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (3*K)
[out]	INFO	INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value. > 0: if INFO = 1, a singular value did not converge

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

June 2017

Contributors:

Ming Gu and Huan Ren, Computer Science Division, University of California at Berkeley, USA

Definition at line 168 of file dlasd8.f.

*
*  -- LAPACK auxiliary routine (version 3.7.1) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     June 2017
*
*     .. Scalar Arguments ..
      INTEGER            ICOMPQ, INFO, K, LDDIFR
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * ), DIFL( * ), DIFR( LDDIFR, * ),
     $                   DSIGMA( * ), VF( * ), VL( * ), WORK( * ),
     $                   Z( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE
      parameter( one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IWK1, IWK2, IWK2I, IWK3, IWK3I, J
      DOUBLE PRECISION   DIFLJ, DIFRJ, DJ, DSIGJ, DSIGJP, RHO, TEMP
*     ..
*     .. External Subroutines ..
      EXTERNAL           dcopy, dlascl, dlasd4, dlaset, xerbla
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DDOT, DLAMC3, DNRM2
      EXTERNAL           ddot, dlamc3, dnrm2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, sign, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
      IF( ( icompq.LT.0 ) .OR. ( icompq.GT.1 ) ) THEN
         info = -1
      ELSE IF( k.LT.1 ) THEN
         info = -2
      ELSE IF( lddifr.LT.k ) THEN
         info = -9
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'DLASD8', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( k.EQ.1 ) THEN
         d( 1 ) = abs( z( 1 ) )
         difl( 1 ) = d( 1 )
         IF( icompq.EQ.1 ) THEN
            difl( 2 ) = one
            difr( 1, 2 ) = one
         END IF
         RETURN
      END IF
*
*     Modify values DSIGMA(i) to make sure all DSIGMA(i)-DSIGMA(j) can
*     be computed with high relative accuracy (barring over/underflow).
*     This is a problem on machines without a guard digit in
*     add/subtract (Cray XMP, Cray YMP, Cray C 90 and Cray 2).
*     The following code replaces DSIGMA(I) by 2*DSIGMA(I)-DSIGMA(I),
*     which on any of these machines zeros out the bottommost
*     bit of DSIGMA(I) if it is 1; this makes the subsequent
*     subtractions DSIGMA(I)-DSIGMA(J) unproblematic when cancellation
*     occurs. On binary machines with a guard digit (almost all
*     machines) it does not change DSIGMA(I) at all. On hexadecimal
*     and decimal machines with a guard digit, it slightly
*     changes the bottommost bits of DSIGMA(I). It does not account
*     for hexadecimal or decimal machines without guard digits
*     (we know of none). We use a subroutine call to compute
*     2*DLAMBDA(I) to prevent optimizing compilers from eliminating
*     this code.
*
      DO 10 i = 1, k
         dsigma( i ) = dlamc3( dsigma( i ), dsigma( i ) ) - dsigma( i )
   10 CONTINUE
*
*     Book keeping.
*
      iwk1 = 1
      iwk2 = iwk1 + k
      iwk3 = iwk2 + k
      iwk2i = iwk2 - 1
      iwk3i = iwk3 - 1
*
*     Normalize Z.
*
      rho = dnrm2( k, z, 1 )
      CALL dlascl( 'G', 0, 0, rho, one, k, 1, z, k, info )
      rho = rho*rho
*
*     Initialize WORK(IWK3).
*
      CALL dlaset( 'A', k, 1, one, one, work( iwk3 ), k )
*
*     Compute the updated singular values, the arrays DIFL, DIFR,
*     and the updated Z.
*
      DO 40 j = 1, k
         CALL dlasd4( k, j, dsigma, z, work( iwk1 ), rho, d( j ),
     $                work( iwk2 ), info )
*
*        If the root finder fails, report the convergence failure.
*
         IF( info.NE.0 ) THEN
            RETURN
         END IF
         work( iwk3i+j ) = work( iwk3i+j )*work( j )*work( iwk2i+j )
         difl( j ) = -work( j )
         difr( j, 1 ) = -work( j+1 )
         DO 20 i = 1, j - 1
            work( iwk3i+i ) = work( iwk3i+i )*work( i )*
     $                        work( iwk2i+i ) / ( dsigma( i )-
     $                        dsigma( j ) ) / ( dsigma( i )+
     $                        dsigma( j ) )
   20    CONTINUE
         DO 30 i = j + 1, k
            work( iwk3i+i ) = work( iwk3i+i )*work( i )*
     $                        work( iwk2i+i ) / ( dsigma( i )-
     $                        dsigma( j ) ) / ( dsigma( i )+
     $                        dsigma( j ) )
   30    CONTINUE
   40 CONTINUE
*
*     Compute updated Z.
*
      DO 50 i = 1, k
         z( i ) = sign( sqrt( abs( work( iwk3i+i ) ) ), z( i ) )
   50 CONTINUE
*
*     Update VF and VL.
*
      DO 80 j = 1, k
         diflj = difl( j )
         dj = d( j )
         dsigj = -dsigma( j )
         IF( j.LT.k ) THEN
            difrj = -difr( j, 1 )
            dsigjp = -dsigma( j+1 )
         END IF
         work( j ) = -z( j ) / diflj / ( dsigma( j )+dj )
         DO 60 i = 1, j - 1
            work( i ) = z( i ) / ( dlamc3( dsigma( i ), dsigj )-diflj )
     $                   / ( dsigma( i )+dj )
   60    CONTINUE
         DO 70 i = j + 1, k
            work( i ) = z( i ) / ( dlamc3( dsigma( i ), dsigjp )+difrj )
     $                   / ( dsigma( i )+dj )
   70    CONTINUE
         temp = dnrm2( k, work, 1 )
         work( iwk2i+j ) = ddot( k, work, 1, vf, 1 ) / temp
         work( iwk3i+j ) = ddot( k, work, 1, vl, 1 ) / temp
         IF( icompq.EQ.1 ) THEN
            difr( j, 2 ) = temp
         END IF
   80 CONTINUE
*
      CALL dcopy( k, work( iwk2 ), 1, vf, 1 )
      CALL dcopy( k, work( iwk3 ), 1, vl, 1 )
*
      RETURN
*
*     End of DLASD8
*

Here is the call graph for this function:

Here is the caller graph for this function: