zlanht()

double precision function zlanht	(	character	NORM,
		integer	N,
		double precision, dimension( * )	D,
		complex*16, dimension( * )	E
	)

ZLANHT returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian tridiagonal matrix.

Download ZLANHT + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 ZLANHT  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 complex Hermitian tridiagonal matrix A.

Returns

ZLANHT

    ZLANHT = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.

Parameters

[in]	NORM	NORM is CHARACTER*1 Specifies the value to be returned in ZLANHT as described above.
[in]	N	N is INTEGER The order of the matrix A. N >= 0. When N = 0, ZLANHT is set to zero.
[in]	D	D is DOUBLE PRECISION array, dimension (N) The diagonal elements of A.
[in]	E	E is COMPLEX*16 array, dimension (N-1) The (n-1) sub-diagonal or super-diagonal elements of A.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 103 of file zlanht.f.

*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          NORM
      INTEGER            N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   D( * )
      COMPLEX*16         E( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ONE, ZERO
      parameter( one = 1.0d+0, zero = 0.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I
      DOUBLE PRECISION   ANORM, SCALE, SUM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME, DISNAN
      EXTERNAL           lsame, disnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           dlassq, zlassq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( n.LE.0 ) THEN
         anorm = zero
      ELSE IF( lsame( norm, 'M' ) ) THEN
*
*        Find max(abs(A(i,j))).
*
         anorm = abs( d( n ) )
         DO 10 i = 1, n - 1
            sum =  abs( d( i ) )
            IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
            sum = abs( e( i ) )
            IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
   10    CONTINUE
      ELSE IF( lsame( norm, 'O' ) .OR. norm.EQ.'1' .OR.
     $         lsame( norm, 'I' ) ) THEN
*
*        Find norm1(A).
*
         IF( n.EQ.1 ) THEN
            anorm = abs( d( 1 ) )
         ELSE
            anorm = abs( d( 1 ) )+abs( e( 1 ) )
            sum = abs( e( n-1 ) )+abs( d( n ) )
            IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
            DO 20 i = 2, n - 1
               sum = abs( d( i ) )+abs( e( i ) )+abs( e( i-1 ) )
               IF( anorm .LT. sum .OR. disnan( sum ) ) anorm = sum
   20       CONTINUE
         END IF
      ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
*
*        Find normF(A).
*
         scale = zero
         sum = one
         IF( n.GT.1 ) THEN
            CALL zlassq( n-1, e, 1, scale, sum )
            sum = 2*sum
         END IF
         CALL dlassq( n, d, 1, scale, sum )
         anorm = scale*sqrt( sum )
      END IF
*
      zlanht = anorm
      RETURN
*
*     End of ZLANHT
*

Here is the call graph for this function: