isamax()

integer function isamax	(	integer	N,
		real, dimension(*)	SX,
		integer	INCX
	)

ISAMAX

Purpose:

    ISAMAX finds the index of the first element having maximum absolute value.

Parameters

[in]	N	N is INTEGER number of elements in input vector(s)
[in]	SX	SX is REAL array, dimension ( 1 + ( N - 1 )*abs( INCX ) )
[in]	INCX	INCX is INTEGER storage spacing between elements of SX

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2017

Further Details:

     jack dongarra, linpack, 3/11/78.
     modified 3/93 to return if incx .le. 0.
     modified 12/3/93, array(1) declarations changed to array(*)

Definition at line 73 of file isamax.f.

*
*  -- Reference BLAS level1 routine (version 3.8.0) --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2017
*
*     .. Scalar Arguments ..
      INTEGER INCX,N
*     ..
*     .. Array Arguments ..
      REAL SX(*)
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      REAL SMAX
      INTEGER I,IX
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC abs
*     ..
      isamax = 0
      IF (n.LT.1 .OR. incx.LE.0) RETURN
      isamax = 1
      IF (n.EQ.1) RETURN
      IF (incx.EQ.1) THEN
*
*        code for increment equal to 1
*
         smax = abs(sx(1))
         DO i = 2,n
            IF (abs(sx(i)).GT.smax) THEN
               isamax = i
               smax = abs(sx(i))
            END IF
         END DO
      ELSE
*
*        code for increment not equal to 1
*
         ix = 1
         smax = abs(sx(1))
         ix = ix + incx
         DO i = 2,n
            IF (abs(sx(ix)).GT.smax) THEN
               isamax = i
               smax = abs(sx(ix))
            END IF
            ix = ix + incx
         END DO
      END IF
      RETURN

Here is the caller graph for this function: