ssyt21.f

Go to the documentation of this file.

*> \brief \b SSYT21
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE SSYT21( ITYPE, UPLO, N, KBAND, A, LDA, D, E, U, LDU, V,
*                          LDV, TAU, WORK, RESULT )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            ITYPE, KBAND, LDA, LDU, LDV, N
*       ..
*       .. Array Arguments ..
*       REAL               A( LDA, * ), D( * ), E( * ), RESULT( 2 ),
*      $                   TAU( * ), U( LDU, * ), V( LDV, * ), WORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SSYT21 generally checks a decomposition of the form
*>
*>    A = U S U**T
*>
*> where **T means transpose, A is symmetric, U is orthogonal, and S is
*> diagonal (if KBAND=0) or symmetric tridiagonal (if KBAND=1).
*>
*> If ITYPE=1, then U is represented as a dense matrix; otherwise U is
*> expressed as a product of Householder transformations, whose vectors
*> are stored in the array "V" and whose scaling constants are in "TAU".
*> We shall use the letter "V" to refer to the product of Householder
*> transformations (which should be equal to U).
*>
*> Specifically, if ITYPE=1, then:
*>
*>    RESULT(1) = | A - U S U**T | / ( |A| n ulp ) and
*>    RESULT(2) = | I - U U**T | / ( n ulp )
*>
*> If ITYPE=2, then:
*>
*>    RESULT(1) = | A - V S V**T | / ( |A| n ulp )
*>
*> If ITYPE=3, then:
*>
*>    RESULT(1) = | I - V U**T | / ( n ulp )
*>
*> For ITYPE > 1, the transformation U is expressed as a product
*> V = H(1)...H(n-2),  where H(j) = I  -  tau(j) v(j) v(j)**T and each
*> vector v(j) has its first j elements 0 and the remaining n-j elements
*> stored in V(j+1:n,j).
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] ITYPE
*> \verbatim
*>          ITYPE is INTEGER
*>          Specifies the type of tests to be performed.
*>          1: U expressed as a dense orthogonal matrix:
*>             RESULT(1) = | A - U S U**T | / ( |A| n ulp ) and
*>             RESULT(2) = | I - U U**T | / ( n ulp )
*>
*>          2: U expressed as a product V of Housholder transformations:
*>             RESULT(1) = | A - V S V**T | / ( |A| n ulp )
*>
*>          3: U expressed both as a dense orthogonal matrix and
*>             as a product of Housholder transformations:
*>             RESULT(1) = | I - V U**T | / ( n ulp )
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER
*>          If UPLO='U', the upper triangle of A and V will be used and
*>          the (strictly) lower triangle will not be referenced.
*>          If UPLO='L', the lower triangle of A and V will be used and
*>          the (strictly) upper triangle will not be referenced.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The size of the matrix.  If it is zero, SSYT21 does nothing.
*>          It must be at least zero.
*> \endverbatim
*>
*> \param[in] KBAND
*> \verbatim
*>          KBAND is INTEGER
*>          The bandwidth of the matrix.  It may only be zero or one.
*>          If zero, then S is diagonal, and E is not referenced.  If
*>          one, then S is symmetric tri-diagonal.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is REAL array, dimension (LDA, N)
*>          The original (unfactored) matrix.  It is assumed to be
*>          symmetric, and only the upper (UPLO='U') or only the lower
*>          (UPLO='L') will be referenced.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>          The leading dimension of A.  It must be at least 1
*>          and at least N.
*> \endverbatim
*>
*> \param[in] D
*> \verbatim
*>          D is REAL array, dimension (N)
*>          The diagonal of the (symmetric tri-) diagonal matrix.
*> \endverbatim
*>
*> \param[in] E
*> \verbatim
*>          E is REAL array, dimension (N-1)
*>          The off-diagonal of the (symmetric tri-) diagonal matrix.
*>          E(1) is the (1,2) and (2,1) element, E(2) is the (2,3) and
*>          (3,2) element, etc.
*>          Not referenced if KBAND=0.
*> \endverbatim
*>
*> \param[in] U
*> \verbatim
*>          U is REAL array, dimension (LDU, N)
*>          If ITYPE=1 or 3, this contains the orthogonal matrix in
*>          the decomposition, expressed as a dense matrix.  If ITYPE=2,
*>          then it is not referenced.
*> \endverbatim
*>
*> \param[in] LDU
*> \verbatim
*>          LDU is INTEGER
*>          The leading dimension of U.  LDU must be at least N and
*>          at least 1.
*> \endverbatim
*>
*> \param[in] V
*> \verbatim
*>          V is REAL array, dimension (LDV, N)
*>          If ITYPE=2 or 3, the columns of this array contain the
*>          Householder vectors used to describe the orthogonal matrix
*>          in the decomposition.  If UPLO='L', then the vectors are in
*>          the lower triangle, if UPLO='U', then in the upper
*>          triangle.
*>          *NOTE* If ITYPE=2 or 3, V is modified and restored.  The
*>          subdiagonal (if UPLO='L') or the superdiagonal (if UPLO='U')
*>          is set to one, and later reset to its original value, during
*>          the course of the calculation.
*>          If ITYPE=1, then it is neither referenced nor modified.
*> \endverbatim
*>
*> \param[in] LDV
*> \verbatim
*>          LDV is INTEGER
*>          The leading dimension of V.  LDV must be at least N and
*>          at least 1.
*> \endverbatim
*>
*> \param[in] TAU
*> \verbatim
*>          TAU is REAL array, dimension (N)
*>          If ITYPE >= 2, then TAU(j) is the scalar factor of
*>          v(j) v(j)**T in the Householder transformation H(j) of
*>          the product  U = H(1)...H(n-2)
*>          If ITYPE < 2, then TAU is not referenced.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (2*N**2)
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (2)
*>          The values computed by the two tests described above.  The
*>          values are currently limited to 1/ulp, to avoid overflow.
*>          RESULT(1) is always modified.  RESULT(2) is modified only
*>          if ITYPE=1.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date December 2016
*
*> \ingroup single_eig
*
*  =====================================================================
      SUBROUTINE ssyt21( ITYPE, UPLO, N, KBAND, A, LDA, D, E, U, LDU, V,
     $                   LDV, TAU, WORK, RESULT )
*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          UPLO
      INTEGER            ITYPE, KBAND, LDA, LDU, LDV, N
*     ..
*     .. Array Arguments ..
      REAL               A( LDA, * ), D( * ), E( * ), RESULT( 2 ),
     $                   tau( * ), u( ldu, * ), v( ldv, * ), work( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TEN
      parameter( zero = 0.0e0, one = 1.0e0, ten = 10.0e0 )
*     ..
*     .. Local Scalars ..
      LOGICAL            LOWER
      CHARACTER          CUPLO
      INTEGER            IINFO, J, JCOL, JR, JROW
      REAL               ANORM, ULP, UNFL, VSAVE, WNORM
*     ..
*     .. External Functions ..
      LOGICAL            LSAME
      REAL               SLAMCH, SLANGE, SLANSY
      EXTERNAL           lsame, slamch, slange, slansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           sgemm, slacpy, slarfy, slaset, sorm2l, sorm2r,
     $                   ssyr, ssyr2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Executable Statements ..
*
      result( 1 ) = zero
      IF( itype.EQ.1 )
     $   result( 2 ) = zero
      IF( n.LE.0 )
     $   RETURN
*
      IF( lsame( uplo, 'U' ) ) THEN
         lower = .false.
         cuplo = 'U'
      ELSE
         lower = .true.
         cuplo = 'L'
      END IF
*
      unfl = slamch( 'Safe minimum' )
      ulp = slamch( 'Epsilon' )*slamch( 'Base' )
*
*     Some Error Checks
*
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         result( 1 ) = ten / ulp
         RETURN
      END IF
*
*     Do Test 1
*
*     Norm of A:
*
      IF( itype.EQ.3 ) THEN
         anorm = one
      ELSE
         anorm = max( slansy( '1', cuplo, n, a, lda, work ), unfl )
      END IF
*
*     Compute error matrix:
*
      IF( itype.EQ.1 ) THEN
*
*        ITYPE=1: error = A - U S U**T
*
         CALL slaset( 'Full', n, n, zero, zero, work, n )
         CALL slacpy( cuplo, n, n, a, lda, work, n )
*
         DO 10 j = 1, n
            CALL ssyr( cuplo, n, -d( j ), u( 1, j ), 1, work, n )
   10    CONTINUE
*
         IF( n.GT.1 .AND. kband.EQ.1 ) THEN
            DO 20 j = 1, n - 1
               CALL ssyr2( cuplo, n, -e( j ), u( 1, j ), 1, u( 1, j+1 ),
     $                     1, work, n )
   20       CONTINUE
         END IF
         wnorm = slansy( '1', cuplo, n, work, n, work( n**2+1 ) )
*
      ELSE IF( itype.EQ.2 ) THEN
*
*        ITYPE=2: error = V S V**T - A
*
         CALL slaset( 'Full', n, n, zero, zero, work, n )
*
         IF( lower ) THEN
            work( n**2 ) = d( n )
            DO 40 j = n - 1, 1, -1
               IF( kband.EQ.1 ) THEN
                  work( ( n+1 )*( j-1 )+2 ) = ( one-tau( j ) )*e( j )
                  DO 30 jr = j + 2, n
                     work( ( j-1 )*n+jr ) = -tau( j )*e( j )*v( jr, j )
   30             CONTINUE
               END IF
*
               vsave = v( j+1, j )
               v( j+1, j ) = one
               CALL slarfy( 'L', n-j, v( j+1, j ), 1, tau( j ),
     $                      work( ( n+1 )*j+1 ), n, work( n**2+1 ) )
               v( j+1, j ) = vsave
               work( ( n+1 )*( j-1 )+1 ) = d( j )
   40       CONTINUE
         ELSE
            work( 1 ) = d( 1 )
            DO 60 j = 1, n - 1
               IF( kband.EQ.1 ) THEN
                  work( ( n+1 )*j ) = ( one-tau( j ) )*e( j )
                  DO 50 jr = 1, j - 1
                     work( j*n+jr ) = -tau( j )*e( j )*v( jr, j+1 )
   50             CONTINUE
               END IF
*
               vsave = v( j, j+1 )
               v( j, j+1 ) = one
               CALL slarfy( 'U', j, v( 1, j+1 ), 1, tau( j ), work, n,
     $                      work( n**2+1 ) )
               v( j, j+1 ) = vsave
               work( ( n+1 )*j+1 ) = d( j+1 )
   60       CONTINUE
         END IF
*
         DO 90 jcol = 1, n
            IF( lower ) THEN
               DO 70 jrow = jcol, n
                  work( jrow+n*( jcol-1 ) ) = work( jrow+n*( jcol-1 ) )
     $                - a( jrow, jcol )
   70          CONTINUE
            ELSE
               DO 80 jrow = 1, jcol
                  work( jrow+n*( jcol-1 ) ) = work( jrow+n*( jcol-1 ) )
     $                - a( jrow, jcol )
   80          CONTINUE
            END IF
   90    CONTINUE
         wnorm = slansy( '1', cuplo, n, work, n, work( n**2+1 ) )
*
      ELSE IF( itype.EQ.3 ) THEN
*
*        ITYPE=3: error = U V**T - I
*
         IF( n.LT.2 )
     $      RETURN
         CALL slacpy( ' ', n, n, u, ldu, work, n )
         IF( lower ) THEN
            CALL sorm2r( 'R', 'T', n, n-1, n-1, v( 2, 1 ), ldv, tau,
     $                   work( n+1 ), n, work( n**2+1 ), iinfo )
         ELSE
            CALL sorm2l( 'R', 'T', n, n-1, n-1, v( 1, 2 ), ldv, tau,
     $                   work, n, work( n**2+1 ), iinfo )
         END IF
         IF( iinfo.NE.0 ) THEN
            result( 1 ) = ten / ulp
            RETURN
         END IF
*
         DO 100 j = 1, n
            work( ( n+1 )*( j-1 )+1 ) = work( ( n+1 )*( j-1 )+1 ) - one
  100    CONTINUE
*
         wnorm = slange( '1', n, n, work, n, work( n**2+1 ) )
      END IF
*
      IF( anorm.GT.wnorm ) THEN
         result( 1 ) = ( wnorm / anorm ) / ( n*ulp )
      ELSE
         IF( anorm.LT.one ) THEN
            result( 1 ) = ( min( wnorm, n*anorm ) / anorm ) / ( n*ulp )
         ELSE
            result( 1 ) = min( wnorm / anorm, real( n ) ) / ( n*ulp )
         END IF
      END IF
*
*     Do Test 2
*
*     Compute  U U**T - I
*
      IF( itype.EQ.1 ) THEN
         CALL sgemm( 'N', 'C', n, n, n, one, u, ldu, u, ldu, zero, work,
     $               n )
*
         DO 110 j = 1, n
            work( ( n+1 )*( j-1 )+1 ) = work( ( n+1 )*( j-1 )+1 ) - one
  110    CONTINUE
*
         result( 2 ) = min( slange( '1', n, n, work, n,
     $                 work( n**2+1 ) ), real( n ) ) / ( n*ulp )
      END IF
*
      RETURN
*
*     End of SSYT21
*
      END