slaed2()

subroutine slaed2	(	integer	K,
		integer	N,
		integer	N1,
		real, dimension( * )	D,
		real, dimension( ldq, * )	Q,
		integer	LDQ,
		integer, dimension( * )	INDXQ,
		real	RHO,
		real, dimension( * )	Z,
		real, dimension( * )	DLAMDA,
		real, dimension( * )	W,
		real, dimension( * )	Q2,
		integer, dimension( * )	INDX,
		integer, dimension( * )	INDXC,
		integer, dimension( * )	INDXP,
		integer, dimension( * )	COLTYP,
		integer	INFO
	)

SLAED2 used by sstedc. Merges eigenvalues and deflates secular equation. Used when the original matrix is tridiagonal.

Download SLAED2 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 SLAED2 merges the two sets of eigenvalues together into a single
 sorted set.  Then it tries to deflate the size of the problem.
 There are two ways in which deflation can occur:  when two or more
 eigenvalues are close together or if there is a tiny entry in the
 Z vector.  For each such occurrence the order of the related secular
 equation problem is reduced by one.

Parameters

[out]	K	K is INTEGER The number of non-deflated eigenvalues, and the order of the related secular equation. 0 <= K <=N.
[in]	N	N is INTEGER The dimension of the symmetric tridiagonal matrix. N >= 0.
[in]	N1	N1 is INTEGER The location of the last eigenvalue in the leading sub-matrix. min(1,N) <= N1 <= N/2.
[in,out]	D	D is REAL array, dimension (N) On entry, D contains the eigenvalues of the two submatrices to be combined. On exit, D contains the trailing (N-K) updated eigenvalues (those which were deflated) sorted into increasing order.
[in,out]	Q	Q is REAL array, dimension (LDQ, N) On entry, Q contains the eigenvectors of two submatrices in the two square blocks with corners at (1,1), (N1,N1) and (N1+1, N1+1), (N,N). On exit, Q contains the trailing (N-K) updated eigenvectors (those which were deflated) in its last N-K columns.
[in]	LDQ	LDQ is INTEGER The leading dimension of the array Q. LDQ >= max(1,N).
[in,out]	INDXQ	INDXQ is INTEGER array, dimension (N) The permutation which separately sorts the two sub-problems in D into ascending order. Note that elements in the second half of this permutation must first have N1 added to their values. Destroyed on exit.
[in,out]	RHO	RHO is REAL On entry, the off-diagonal element associated with the rank-1 cut which originally split the two submatrices which are now being recombined. On exit, RHO has been modified to the value required by SLAED3.
[in]	Z	Z is REAL array, dimension (N) On entry, Z contains the updating vector (the last row of the first sub-eigenvector matrix and the first row of the second sub-eigenvector matrix). On exit, the contents of Z have been destroyed by the updating process.
[out]	DLAMDA	DLAMDA is REAL array, dimension (N) A copy of the first K eigenvalues which will be used by SLAED3 to form the secular equation.
[out]	W	W is REAL array, dimension (N) The first k values of the final deflation-altered z-vector which will be passed to SLAED3.
[out]	Q2	Q2 is REAL array, dimension (N1**2+(N-N1)**2) A copy of the first K eigenvectors which will be used by SLAED3 in a matrix multiply (SGEMM) to solve for the new eigenvectors.
[out]	INDX	INDX is INTEGER array, dimension (N) The permutation used to sort the contents of DLAMDA into ascending order.
[out]	INDXC	INDXC is INTEGER array, dimension (N) The permutation used to arrange the columns of the deflated Q matrix into three groups: the first group contains non-zero elements only at and above N1, the second contains non-zero elements only below N1, and the third is dense.
[out]	INDXP	INDXP is INTEGER array, dimension (N) The permutation used to place deflated values of D at the end of the array. INDXP(1:K) points to the nondeflated D-values and INDXP(K+1:N) points to the deflated eigenvalues.
[out]	COLTYP	COLTYP is INTEGER array, dimension (N) During execution, a label which will indicate which of the following types a column in the Q2 matrix is: 1 : non-zero in the upper half only; 2 : dense; 3 : non-zero in the lower half only; 4 : deflated. On exit, COLTYP(i) is the number of columns of type i, for i=1 to 4 only.
[out]	INFO	INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Contributors:

Jeff Rutter, Computer Science Division, University of California at Berkeley, USA
Modified by Francoise Tisseur, University of Tennessee

Definition at line 214 of file slaed2.f.

*
*  -- LAPACK computational routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            INFO, K, LDQ, N, N1
      REAL               RHO
*     ..
*     .. Array Arguments ..
      INTEGER            COLTYP( * ), INDX( * ), INDXC( * ), INDXP( * ),
     $                   INDXQ( * )
      REAL               D( * ), DLAMDA( * ), Q( LDQ, * ), Q2( * ),
     $                   W( * ), Z( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               MONE, ZERO, ONE, TWO, EIGHT
      parameter( mone = -1.0e0, zero = 0.0e0, one = 1.0e0,
     $                   two = 2.0e0, eight = 8.0e0 )
*     ..
*     .. Local Arrays ..
      INTEGER            CTOT( 4 ), PSM( 4 )
*     ..
*     .. Local Scalars ..
      INTEGER            CT, I, IMAX, IQ1, IQ2, J, JMAX, JS, K2, N1P1,
     $                   N2, NJ, PJ
      REAL               C, EPS, S, T, TAU, TOL
*     ..
*     .. External Functions ..
      INTEGER            ISAMAX
      REAL               SLAMCH, SLAPY2
      EXTERNAL           isamax, slamch, slapy2
*     ..
*     .. External Subroutines ..
      EXTERNAL           scopy, slacpy, slamrg, srot, sscal, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
      IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( ldq.LT.max( 1, n ) ) THEN
         info = -6
      ELSE IF( min( 1, ( n / 2 ) ).GT.n1 .OR. ( n / 2 ).LT.n1 ) THEN
         info = -3
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SLAED2', -info )
         RETURN
      END IF
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      n2 = n - n1
      n1p1 = n1 + 1
*
      IF( rho.LT.zero ) THEN
         CALL sscal( n2, mone, z( n1p1 ), 1 )
      END IF
*
*     Normalize z so that norm(z) = 1.  Since z is the concatenation of
*     two normalized vectors, norm2(z) = sqrt(2).
*
      t = one / sqrt( two )
      CALL sscal( n, t, z, 1 )
*
*     RHO = ABS( norm(z)**2 * RHO )
*
      rho = abs( two*rho )
*
*     Sort the eigenvalues into increasing order
*
      DO 10 i = n1p1, n
         indxq( i ) = indxq( i ) + n1
   10 CONTINUE
*
*     re-integrate the deflated parts from the last pass
*
      DO 20 i = 1, n
         dlamda( i ) = d( indxq( i ) )
   20 CONTINUE
      CALL slamrg( n1, n2, dlamda, 1, 1, indxc )
      DO 30 i = 1, n
         indx( i ) = indxq( indxc( i ) )
   30 CONTINUE
*
*     Calculate the allowable deflation tolerance
*
      imax = isamax( n, z, 1 )
      jmax = isamax( n, d, 1 )
      eps = slamch( 'Epsilon' )
      tol = eight*eps*max( abs( d( jmax ) ), abs( z( imax ) ) )
*
*     If the rank-1 modifier is small enough, no more needs to be done
*     except to reorganize Q so that its columns correspond with the
*     elements in D.
*
      IF( rho*abs( z( imax ) ).LE.tol ) THEN
         k = 0
         iq2 = 1
         DO 40 j = 1, n
            i = indx( j )
            CALL scopy( n, q( 1, i ), 1, q2( iq2 ), 1 )
            dlamda( j ) = d( i )
            iq2 = iq2 + n
   40    CONTINUE
         CALL slacpy( 'A', n, n, q2, n, q, ldq )
         CALL scopy( n, dlamda, 1, d, 1 )
         GO TO 190
      END IF
*
*     If there are multiple eigenvalues then the problem deflates.  Here
*     the number of equal eigenvalues are found.  As each equal
*     eigenvalue is found, an elementary reflector is computed to rotate
*     the corresponding eigensubspace so that the corresponding
*     components of Z are zero in this new basis.
*
      DO 50 i = 1, n1
         coltyp( i ) = 1
   50 CONTINUE
      DO 60 i = n1p1, n
         coltyp( i ) = 3
   60 CONTINUE
*
*
      k = 0
      k2 = n + 1
      DO 70 j = 1, n
         nj = indx( j )
         IF( rho*abs( z( nj ) ).LE.tol ) THEN
*
*           Deflate due to small z component.
*
            k2 = k2 - 1
            coltyp( nj ) = 4
            indxp( k2 ) = nj
            IF( j.EQ.n )
     $         GO TO 100
         ELSE
            pj = nj
            GO TO 80
         END IF
   70 CONTINUE
   80 CONTINUE
      j = j + 1
      nj = indx( j )
      IF( j.GT.n )
     $   GO TO 100
      IF( rho*abs( z( nj ) ).LE.tol ) THEN
*
*        Deflate due to small z component.
*
         k2 = k2 - 1
         coltyp( nj ) = 4
         indxp( k2 ) = nj
      ELSE
*
*        Check if eigenvalues are close enough to allow deflation.
*
         s = z( pj )
         c = z( nj )
*
*        Find sqrt(a**2+b**2) without overflow or
*        destructive underflow.
*
         tau = slapy2( c, s )
         t = d( nj ) - d( pj )
         c = c / tau
         s = -s / tau
         IF( abs( t*c*s ).LE.tol ) THEN
*
*           Deflation is possible.
*
            z( nj ) = tau
            z( pj ) = zero
            IF( coltyp( nj ).NE.coltyp( pj ) )
     $         coltyp( nj ) = 2
            coltyp( pj ) = 4
            CALL srot( n, q( 1, pj ), 1, q( 1, nj ), 1, c, s )
            t = d( pj )*c**2 + d( nj )*s**2
            d( nj ) = d( pj )*s**2 + d( nj )*c**2
            d( pj ) = t
            k2 = k2 - 1
            i = 1
   90       CONTINUE
            IF( k2+i.LE.n ) THEN
               IF( d( pj ).LT.d( indxp( k2+i ) ) ) THEN
                  indxp( k2+i-1 ) = indxp( k2+i )
                  indxp( k2+i ) = pj
                  i = i + 1
                  GO TO 90
               ELSE
                  indxp( k2+i-1 ) = pj
               END IF
            ELSE
               indxp( k2+i-1 ) = pj
            END IF
            pj = nj
         ELSE
            k = k + 1
            dlamda( k ) = d( pj )
            w( k ) = z( pj )
            indxp( k ) = pj
            pj = nj
         END IF
      END IF
      GO TO 80
  100 CONTINUE
*
*     Record the last eigenvalue.
*
      k = k + 1
      dlamda( k ) = d( pj )
      w( k ) = z( pj )
      indxp( k ) = pj
*
*     Count up the total number of the various types of columns, then
*     form a permutation which positions the four column types into
*     four uniform groups (although one or more of these groups may be
*     empty).
*
      DO 110 j = 1, 4
         ctot( j ) = 0
  110 CONTINUE
      DO 120 j = 1, n
         ct = coltyp( j )
         ctot( ct ) = ctot( ct ) + 1
  120 CONTINUE
*
*     PSM(*) = Position in SubMatrix (of types 1 through 4)
*
      psm( 1 ) = 1
      psm( 2 ) = 1 + ctot( 1 )
      psm( 3 ) = psm( 2 ) + ctot( 2 )
      psm( 4 ) = psm( 3 ) + ctot( 3 )
      k = n - ctot( 4 )
*
*     Fill out the INDXC array so that the permutation which it induces
*     will place all type-1 columns first, all type-2 columns next,
*     then all type-3's, and finally all type-4's.
*
      DO 130 j = 1, n
         js = indxp( j )
         ct = coltyp( js )
         indx( psm( ct ) ) = js
         indxc( psm( ct ) ) = j
         psm( ct ) = psm( ct ) + 1
  130 CONTINUE
*
*     Sort the eigenvalues and corresponding eigenvectors into DLAMDA
*     and Q2 respectively.  The eigenvalues/vectors which were not
*     deflated go into the first K slots of DLAMDA and Q2 respectively,
*     while those which were deflated go into the last N - K slots.
*
      i = 1
      iq1 = 1
      iq2 = 1 + ( ctot( 1 )+ctot( 2 ) )*n1
      DO 140 j = 1, ctot( 1 )
         js = indx( i )
         CALL scopy( n1, q( 1, js ), 1, q2( iq1 ), 1 )
         z( i ) = d( js )
         i = i + 1
         iq1 = iq1 + n1
  140 CONTINUE
*
      DO 150 j = 1, ctot( 2 )
         js = indx( i )
         CALL scopy( n1, q( 1, js ), 1, q2( iq1 ), 1 )
         CALL scopy( n2, q( n1+1, js ), 1, q2( iq2 ), 1 )
         z( i ) = d( js )
         i = i + 1
         iq1 = iq1 + n1
         iq2 = iq2 + n2
  150 CONTINUE
*
      DO 160 j = 1, ctot( 3 )
         js = indx( i )
         CALL scopy( n2, q( n1+1, js ), 1, q2( iq2 ), 1 )
         z( i ) = d( js )
         i = i + 1
         iq2 = iq2 + n2
  160 CONTINUE
*
      iq1 = iq2
      DO 170 j = 1, ctot( 4 )
         js = indx( i )
         CALL scopy( n, q( 1, js ), 1, q2( iq2 ), 1 )
         iq2 = iq2 + n
         z( i ) = d( js )
         i = i + 1
  170 CONTINUE
*
*     The deflated eigenvalues and their corresponding vectors go back
*     into the last N - K slots of D and Q respectively.
*
      IF( k.LT.n ) THEN
         CALL slacpy( 'A', n, ctot( 4 ), q2( iq1 ), n,
     $                q( 1, k+1 ), ldq )
         CALL scopy( n-k, z( k+1 ), 1, d( k+1 ), 1 )
      END IF
*
*     Copy CTOT into COLTYP for referencing in SLAED3.
*
      DO 180 j = 1, 4
         coltyp( j ) = ctot( j )
  180 CONTINUE
*
  190 CONTINUE
      RETURN
*
*     End of SLAED2
*

Here is the call graph for this function:

Here is the caller graph for this function: