slanv2.f

Go to the documentation of this file.

*> \brief \b SLANV2 computes the Schur factorization of a real 2-by-2 nonsymmetric matrix in standard form.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download SLANV2 + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/slanv2.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/slanv2.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/slanv2.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       SUBROUTINE SLANV2( A, B, C, D, RT1R, RT1I, RT2R, RT2I, CS, SN )
*
*       .. Scalar Arguments ..
*       REAL               A, B, C, CS, D, RT1I, RT1R, RT2I, RT2R, SN
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> SLANV2 computes the Schur factorization of a real 2-by-2 nonsymmetric
*> matrix in standard form:
*>
*>      [ A  B ] = [ CS -SN ] [ AA  BB ] [ CS  SN ]
*>      [ C  D ]   [ SN  CS ] [ CC  DD ] [-SN  CS ]
*>
*> where either
*> 1) CC = 0 so that AA and DD are real eigenvalues of the matrix, or
*> 2) AA = DD and BB*CC < 0, so that AA + or - sqrt(BB*CC) are complex
*> conjugate eigenvalues.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in,out] A
*> \verbatim
*>          A is REAL
*> \endverbatim
*>
*> \param[in,out] B
*> \verbatim
*>          B is REAL
*> \endverbatim
*>
*> \param[in,out] C
*> \verbatim
*>          C is REAL
*> \endverbatim
*>
*> \param[in,out] D
*> \verbatim
*>          D is REAL
*>          On entry, the elements of the input matrix.
*>          On exit, they are overwritten by the elements of the
*>          standardised Schur form.
*> \endverbatim
*>
*> \param[out] RT1R
*> \verbatim
*>          RT1R is REAL
*> \endverbatim
*>
*> \param[out] RT1I
*> \verbatim
*>          RT1I is REAL
*> \endverbatim
*>
*> \param[out] RT2R
*> \verbatim
*>          RT2R is REAL
*> \endverbatim
*>
*> \param[out] RT2I
*> \verbatim
*>          RT2I is REAL
*>          The real and imaginary parts of the eigenvalues. If the
*>          eigenvalues are a complex conjugate pair, RT1I > 0.
*> \endverbatim
*>
*> \param[out] CS
*> \verbatim
*>          CS is REAL
*> \endverbatim
*>
*> \param[out] SN
*> \verbatim
*>          SN is REAL
*>          Parameters of the rotation matrix.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date December 2016
*
*> \ingroup realOTHERauxiliary
*
*> \par Further Details:
*  =====================
*>
*> \verbatim
*>
*>  Modified by V. Sima, Research Institute for Informatics, Bucharest,
*>  Romania, to reduce the risk of cancellation errors,
*>  when computing real eigenvalues, and to ensure, if possible, that
*>  abs(RT1R) >= abs(RT2R).
*> \endverbatim
*>
*  =====================================================================
      SUBROUTINE slanv2( A, B, C, D, RT1R, RT1I, RT2R, RT2I, CS, SN )
*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      REAL               A, B, C, CS, D, RT1I, RT1R, RT2I, RT2R, SN
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, HALF, ONE
      parameter( zero = 0.0e+0, half = 0.5e+0, one = 1.0e+0 )
      REAL               MULTPL
      parameter( multpl = 4.0e+0 )
*     ..
*     .. Local Scalars ..
      REAL               AA, BB, BCMAX, BCMIS, CC, CS1, DD, EPS, P, SAB,
     $                   SAC, SCALE, SIGMA, SN1, TAU, TEMP, Z
*     ..
*     .. External Functions ..
      REAL               SLAMCH, SLAPY2
      EXTERNAL           slamch, slapy2
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sign, sqrt
*     ..
*     .. Executable Statements ..
*
      eps = slamch( 'P' )
      IF( c.EQ.zero ) THEN
         cs = one
         sn = zero
*
      ELSE IF( b.EQ.zero ) THEN
*
*        Swap rows and columns
*
         cs = zero
         sn = one
         temp = d
         d = a
         a = temp
         b = -c
         c = zero
*
      ELSE IF( (a-d).EQ.zero .AND. sign( one, b ).NE.
     $   sign( one, c ) ) THEN
         cs = one
         sn = zero
*
      ELSE
*
         temp = a - d
         p = half*temp
         bcmax = max( abs( b ), abs( c ) )
         bcmis = min( abs( b ), abs( c ) )*sign( one, b )*sign( one, c )
         scale = max( abs( p ), bcmax )
         z = ( p / scale )*p + ( bcmax / scale )*bcmis
*
*        If Z is of the order of the machine accuracy, postpone the
*        decision on the nature of eigenvalues
*
         IF( z.GE.multpl*eps ) THEN
*
*           Real eigenvalues. Compute A and D.
*
            z = p + sign( sqrt( scale )*sqrt( z ), p )
            a = d + z
            d = d - ( bcmax / z )*bcmis
*
*           Compute B and the rotation matrix
*
            tau = slapy2( c, z )
            cs = z / tau
            sn = c / tau
            b = b - c
            c = zero
*
         ELSE
*
*           Complex eigenvalues, or real (almost) equal eigenvalues.
*           Make diagonal elements equal.
*
            sigma = b + c
            tau = slapy2( sigma, temp )
            cs = sqrt( half*( one+abs( sigma ) / tau ) )
            sn = -( p / ( tau*cs ) )*sign( one, sigma )
*
*           Compute [ AA  BB ] = [ A  B ] [ CS -SN ]
*                   [ CC  DD ]   [ C  D ] [ SN  CS ]
*
            aa = a*cs + b*sn
            bb = -a*sn + b*cs
            cc = c*cs + d*sn
            dd = -c*sn + d*cs
*
*           Compute [ A  B ] = [ CS  SN ] [ AA  BB ]
*                   [ C  D ]   [-SN  CS ] [ CC  DD ]
*
            a = aa*cs + cc*sn
            b = bb*cs + dd*sn
            c = -aa*sn + cc*cs
            d = -bb*sn + dd*cs
*
            temp = half*( a+d )
            a = temp
            d = temp
*
            IF( c.NE.zero ) THEN
               IF( b.NE.zero ) THEN
                  IF( sign( one, b ).EQ.sign( one, c ) ) THEN
*
*                    Real eigenvalues: reduce to upper triangular form
*
                     sab = sqrt( abs( b ) )
                     sac = sqrt( abs( c ) )
                     p = sign( sab*sac, c )
                     tau = one / sqrt( abs( b+c ) )
                     a = temp + p
                     d = temp - p
                     b = b - c
                     c = zero
                     cs1 = sab*tau
                     sn1 = sac*tau
                     temp = cs*cs1 - sn*sn1
                     sn = cs*sn1 + sn*cs1
                     cs = temp
                  END IF
               ELSE
                  b = -c
                  c = zero
                  temp = cs
                  cs = -sn
                  sn = temp
               END IF
            END IF
         END IF
*
      END IF
*
*     Store eigenvalues in (RT1R,RT1I) and (RT2R,RT2I).
*
      rt1r = a
      rt2r = d
      IF( c.EQ.zero ) THEN
         rt1i = zero
         rt2i = zero
      ELSE
         rt1i = sqrt( abs( b ) )*sqrt( abs( c ) )
         rt2i = -rt1i
      END IF
      RETURN
*
*     End of SLANV2
*
      END