LAPACK  3.9.0
LAPACK: Linear Algebra PACKage

◆ zhegst()

subroutine zhegst ( integer  ITYPE,
character  UPLO,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
complex*16, dimension( ldb, * )  B,
integer  LDB,
integer  INFO 
)

ZHEGST

Download ZHEGST + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZHEGST reduces a complex Hermitian-definite generalized
 eigenproblem to standard form.

 If ITYPE = 1, the problem is A*x = lambda*B*x,
 and A is overwritten by inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H)

 If ITYPE = 2 or 3, the problem is A*B*x = lambda*x or
 B*A*x = lambda*x, and A is overwritten by U*A*U**H or L**H*A*L.

 B must have been previously factorized as U**H*U or L*L**H by ZPOTRF.
Parameters
[in]ITYPE
          ITYPE is INTEGER
          = 1: compute inv(U**H)*A*inv(U) or inv(L)*A*inv(L**H);
          = 2 or 3: compute U*A*U**H or L**H*A*L.
[in]UPLO
          UPLO is CHARACTER*1
          = 'U':  Upper triangle of A is stored and B is factored as
                  U**H*U;
          = 'L':  Lower triangle of A is stored and B is factored as
                  L*L**H.
[in]N
          N is INTEGER
          The order of the matrices A and B.  N >= 0.
[in,out]A
          A is COMPLEX*16 array, dimension (LDA,N)
          On entry, the Hermitian matrix A.  If UPLO = 'U', the leading
          N-by-N upper triangular part of A contains the upper
          triangular part of the matrix A, and the strictly lower
          triangular part of A is not referenced.  If UPLO = 'L', the
          leading N-by-N lower triangular part of A contains the lower
          triangular part of the matrix A, and the strictly upper
          triangular part of A is not referenced.

          On exit, if INFO = 0, the transformed matrix, stored in the
          same format as A.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in,out]B
          B is COMPLEX*16 array, dimension (LDB,N)
          The triangular factor from the Cholesky factorization of B,
          as returned by ZPOTRF.
          B is modified by the routine but restored on exit.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 130 of file zhegst.f.

130 *
131 * -- LAPACK computational routine (version 3.7.0) --
132 * -- LAPACK is a software package provided by Univ. of Tennessee, --
133 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
134 * December 2016
135 *
136 * .. Scalar Arguments ..
137  CHARACTER UPLO
138  INTEGER INFO, ITYPE, LDA, LDB, N
139 * ..
140 * .. Array Arguments ..
141  COMPLEX*16 A( LDA, * ), B( LDB, * )
142 * ..
143 *
144 * =====================================================================
145 *
146 * .. Parameters ..
147  DOUBLE PRECISION ONE
148  parameter( one = 1.0d+0 )
149  COMPLEX*16 CONE, HALF
150  parameter( cone = ( 1.0d+0, 0.0d+0 ),
151  $ half = ( 0.5d+0, 0.0d+0 ) )
152 * ..
153 * .. Local Scalars ..
154  LOGICAL UPPER
155  INTEGER K, KB, NB
156 * ..
157 * .. External Subroutines ..
158  EXTERNAL xerbla, zhegs2, zhemm, zher2k, ztrmm, ztrsm
159 * ..
160 * .. Intrinsic Functions ..
161  INTRINSIC max, min
162 * ..
163 * .. External Functions ..
164  LOGICAL LSAME
165  INTEGER ILAENV
166  EXTERNAL lsame, ilaenv
167 * ..
168 * .. Executable Statements ..
169 *
170 * Test the input parameters.
171 *
172  info = 0
173  upper = lsame( uplo, 'U' )
174  IF( itype.LT.1 .OR. itype.GT.3 ) THEN
175  info = -1
176  ELSE IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
177  info = -2
178  ELSE IF( n.LT.0 ) THEN
179  info = -3
180  ELSE IF( lda.LT.max( 1, n ) ) THEN
181  info = -5
182  ELSE IF( ldb.LT.max( 1, n ) ) THEN
183  info = -7
184  END IF
185  IF( info.NE.0 ) THEN
186  CALL xerbla( 'ZHEGST', -info )
187  RETURN
188  END IF
189 *
190 * Quick return if possible
191 *
192  IF( n.EQ.0 )
193  $ RETURN
194 *
195 * Determine the block size for this environment.
196 *
197  nb = ilaenv( 1, 'ZHEGST', uplo, n, -1, -1, -1 )
198 *
199  IF( nb.LE.1 .OR. nb.GE.n ) THEN
200 *
201 * Use unblocked code
202 *
203  CALL zhegs2( itype, uplo, n, a, lda, b, ldb, info )
204  ELSE
205 *
206 * Use blocked code
207 *
208  IF( itype.EQ.1 ) THEN
209  IF( upper ) THEN
210 *
211 * Compute inv(U**H)*A*inv(U)
212 *
213  DO 10 k = 1, n, nb
214  kb = min( n-k+1, nb )
215 *
216 * Update the upper triangle of A(k:n,k:n)
217 *
218  CALL zhegs2( itype, uplo, kb, a( k, k ), lda,
219  $ b( k, k ), ldb, info )
220  IF( k+kb.LE.n ) THEN
221  CALL ztrsm( 'Left', uplo, 'Conjugate transpose',
222  $ 'Non-unit', kb, n-k-kb+1, cone,
223  $ b( k, k ), ldb, a( k, k+kb ), lda )
224  CALL zhemm( 'Left', uplo, kb, n-k-kb+1, -half,
225  $ a( k, k ), lda, b( k, k+kb ), ldb,
226  $ cone, a( k, k+kb ), lda )
227  CALL zher2k( uplo, 'Conjugate transpose', n-k-kb+1,
228  $ kb, -cone, a( k, k+kb ), lda,
229  $ b( k, k+kb ), ldb, one,
230  $ a( k+kb, k+kb ), lda )
231  CALL zhemm( 'Left', uplo, kb, n-k-kb+1, -half,
232  $ a( k, k ), lda, b( k, k+kb ), ldb,
233  $ cone, a( k, k+kb ), lda )
234  CALL ztrsm( 'Right', uplo, 'No transpose',
235  $ 'Non-unit', kb, n-k-kb+1, cone,
236  $ b( k+kb, k+kb ), ldb, a( k, k+kb ),
237  $ lda )
238  END IF
239  10 CONTINUE
240  ELSE
241 *
242 * Compute inv(L)*A*inv(L**H)
243 *
244  DO 20 k = 1, n, nb
245  kb = min( n-k+1, nb )
246 *
247 * Update the lower triangle of A(k:n,k:n)
248 *
249  CALL zhegs2( itype, uplo, kb, a( k, k ), lda,
250  $ b( k, k ), ldb, info )
251  IF( k+kb.LE.n ) THEN
252  CALL ztrsm( 'Right', uplo, 'Conjugate transpose',
253  $ 'Non-unit', n-k-kb+1, kb, cone,
254  $ b( k, k ), ldb, a( k+kb, k ), lda )
255  CALL zhemm( 'Right', uplo, n-k-kb+1, kb, -half,
256  $ a( k, k ), lda, b( k+kb, k ), ldb,
257  $ cone, a( k+kb, k ), lda )
258  CALL zher2k( uplo, 'No transpose', n-k-kb+1, kb,
259  $ -cone, a( k+kb, k ), lda,
260  $ b( k+kb, k ), ldb, one,
261  $ a( k+kb, k+kb ), lda )
262  CALL zhemm( 'Right', uplo, n-k-kb+1, kb, -half,
263  $ a( k, k ), lda, b( k+kb, k ), ldb,
264  $ cone, a( k+kb, k ), lda )
265  CALL ztrsm( 'Left', uplo, 'No transpose',
266  $ 'Non-unit', n-k-kb+1, kb, cone,
267  $ b( k+kb, k+kb ), ldb, a( k+kb, k ),
268  $ lda )
269  END IF
270  20 CONTINUE
271  END IF
272  ELSE
273  IF( upper ) THEN
274 *
275 * Compute U*A*U**H
276 *
277  DO 30 k = 1, n, nb
278  kb = min( n-k+1, nb )
279 *
280 * Update the upper triangle of A(1:k+kb-1,1:k+kb-1)
281 *
282  CALL ztrmm( 'Left', uplo, 'No transpose', 'Non-unit',
283  $ k-1, kb, cone, b, ldb, a( 1, k ), lda )
284  CALL zhemm( 'Right', uplo, k-1, kb, half, a( k, k ),
285  $ lda, b( 1, k ), ldb, cone, a( 1, k ),
286  $ lda )
287  CALL zher2k( uplo, 'No transpose', k-1, kb, cone,
288  $ a( 1, k ), lda, b( 1, k ), ldb, one, a,
289  $ lda )
290  CALL zhemm( 'Right', uplo, k-1, kb, half, a( k, k ),
291  $ lda, b( 1, k ), ldb, cone, a( 1, k ),
292  $ lda )
293  CALL ztrmm( 'Right', uplo, 'Conjugate transpose',
294  $ 'Non-unit', k-1, kb, cone, b( k, k ), ldb,
295  $ a( 1, k ), lda )
296  CALL zhegs2( itype, uplo, kb, a( k, k ), lda,
297  $ b( k, k ), ldb, info )
298  30 CONTINUE
299  ELSE
300 *
301 * Compute L**H*A*L
302 *
303  DO 40 k = 1, n, nb
304  kb = min( n-k+1, nb )
305 *
306 * Update the lower triangle of A(1:k+kb-1,1:k+kb-1)
307 *
308  CALL ztrmm( 'Right', uplo, 'No transpose', 'Non-unit',
309  $ kb, k-1, cone, b, ldb, a( k, 1 ), lda )
310  CALL zhemm( 'Left', uplo, kb, k-1, half, a( k, k ),
311  $ lda, b( k, 1 ), ldb, cone, a( k, 1 ),
312  $ lda )
313  CALL zher2k( uplo, 'Conjugate transpose', k-1, kb,
314  $ cone, a( k, 1 ), lda, b( k, 1 ), ldb,
315  $ one, a, lda )
316  CALL zhemm( 'Left', uplo, kb, k-1, half, a( k, k ),
317  $ lda, b( k, 1 ), ldb, cone, a( k, 1 ),
318  $ lda )
319  CALL ztrmm( 'Left', uplo, 'Conjugate transpose',
320  $ 'Non-unit', kb, k-1, cone, b( k, k ), ldb,
321  $ a( k, 1 ), lda )
322  CALL zhegs2( itype, uplo, kb, a( k, k ), lda,
323  $ b( k, k ), ldb, info )
324  40 CONTINUE
325  END IF
326  END IF
327  END IF
328  RETURN
329 *
330 * End of ZHEGST
331 *
Here is the call graph for this function:
Here is the caller graph for this function:
zher2k
subroutine zher2k(UPLO, TRANS, N, K, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
ZHER2K
Definition: zher2k.f:200
ztrsm
subroutine ztrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRSM
Definition: ztrsm.f:182
zhemm
subroutine zhemm(SIDE, UPLO, M, N, ALPHA, A, LDA, B, LDB, BETA, C, LDC)
ZHEMM
Definition: zhemm.f:193
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
lsame
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
ztrmm
subroutine ztrmm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRMM
Definition: ztrmm.f:179
ilaenv
integer function ilaenv(ISPEC, NAME, OPTS, N1, N2, N3, N4)
ILAENV
Definition: tstiee.f:83
zhegs2
subroutine zhegs2(ITYPE, UPLO, N, A, LDA, B, LDB, INFO)
ZHEGS2 reduces a Hermitian definite generalized eigenproblem to standard form, using the factorizatio...
Definition: zhegs2.f:130