LAPACK  3.9.0
LAPACK: Linear Algebra PACKage

◆ zhetrs_aa()

subroutine zhetrs_aa ( character  UPLO,
integer  N,
integer  NRHS,
complex*16, dimension( lda, * )  A,
integer  LDA,
integer, dimension( * )  IPIV,
complex*16, dimension( ldb, * )  B,
integer  LDB,
complex*16, dimension( * )  WORK,
integer  LWORK,
integer  INFO 
)

ZHETRS_AA

Download ZHETRS_AA + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZHETRS_AA solves a system of linear equations A*X = B with a complex
 hermitian matrix A using the factorization A = U**H*T*U or
 A = L*T*L**H computed by ZHETRF_AA.
Parameters
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the details of the factorization are stored
          as an upper or lower triangular matrix.
          = 'U':  Upper triangular, form is A = U**H*T*U;
          = 'L':  Lower triangular, form is A = L*T*L**H.
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.
[in]NRHS
          NRHS is INTEGER
          The number of right hand sides, i.e., the number of columns
          of the matrix B.  NRHS >= 0.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
          Details of factors computed by ZHETRF_AA.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(1,N).
[in]IPIV
          IPIV is INTEGER array, dimension (N)
          Details of the interchanges as computed by ZHETRF_AA.
[in,out]B
          B is COMPLEX*16 array, dimension (LDB,NRHS)
          On entry, the right hand side matrix B.
          On exit, the solution matrix X.
[in]LDB
          LDB is INTEGER
          The leading dimension of the array B.  LDB >= max(1,N).
[out]WORK
          WORK is COMPLEX*16 array, dimension (MAX(1,LWORK))
[in]LWORK
          LWORK is INTEGER
          The dimension of the array WORK. LWORK >= max(1,3*N-2).
[out]INFO
          INFO is INTEGER
          = 0:  successful exit
          < 0:  if INFO = -i, the i-th argument had an illegal value
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
November 2017

Definition at line 134 of file zhetrs_aa.f.

134 *
135 * -- LAPACK computational routine (version 3.8.0) --
136 * -- LAPACK is a software package provided by Univ. of Tennessee, --
137 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
138 * November 2017
139 *
140  IMPLICIT NONE
141 *
142 * .. Scalar Arguments ..
143  CHARACTER UPLO
144  INTEGER N, NRHS, LDA, LDB, LWORK, INFO
145 * ..
146 * .. Array Arguments ..
147  INTEGER IPIV( * )
148  COMPLEX*16 A( LDA, * ), B( LDB, * ), WORK( * )
149 * ..
150 *
151 * =====================================================================
152 *
153  COMPLEX*16 ONE
154  parameter( one = 1.0d+0 )
155 * ..
156 * .. Local Scalars ..
157  LOGICAL LQUERY, UPPER
158  INTEGER K, KP, LWKOPT
159 * ..
160 * .. External Functions ..
161  LOGICAL LSAME
162  EXTERNAL lsame
163 * ..
164 * .. External Subroutines ..
165  EXTERNAL zgtsv, zswap, ztrsm, zlacgv, zlacpy, xerbla
166 * ..
167 * .. Intrinsic Functions ..
168  INTRINSIC max
169 * ..
170 * .. Executable Statements ..
171 *
172  info = 0
173  upper = lsame( uplo, 'U' )
174  lquery = ( lwork.EQ.-1 )
175  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
176  info = -1
177  ELSE IF( n.LT.0 ) THEN
178  info = -2
179  ELSE IF( nrhs.LT.0 ) THEN
180  info = -3
181  ELSE IF( lda.LT.max( 1, n ) ) THEN
182  info = -5
183  ELSE IF( ldb.LT.max( 1, n ) ) THEN
184  info = -8
185  ELSE IF( lwork.LT.max( 1, 3*n-2 ) .AND. .NOT.lquery ) THEN
186  info = -10
187  END IF
188  IF( info.NE.0 ) THEN
189  CALL xerbla( 'ZHETRS_AA', -info )
190  RETURN
191  ELSE IF( lquery ) THEN
192  lwkopt = (3*n-2)
193  work( 1 ) = lwkopt
194  RETURN
195  END IF
196 *
197 * Quick return if possible
198 *
199  IF( n.EQ.0 .OR. nrhs.EQ.0 )
200  $ RETURN
201 *
202  IF( upper ) THEN
203 *
204 * Solve A*X = B, where A = U**H*T*U.
205 *
206 * 1) Forward substitution with U**H
207 *
208  IF( n.GT.1 ) THEN
209 *
210 * Pivot, P**T * B -> B
211 *
212  DO k = 1, n
213  kp = ipiv( k )
214  IF( kp.NE.k )
215  $ CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
216  END DO
217 *
218 * Compute U**H \ B -> B [ (U**H \P**T * B) ]
219 *
220  CALL ztrsm( 'L', 'U', 'C', 'U', n-1, nrhs, one, a( 1, 2 ),
221  $ lda, b( 2, 1 ), ldb )
222  END IF
223 *
224 * 2) Solve with triangular matrix T
225 *
226 * Compute T \ B -> B [ T \ (U**H \P**T * B) ]
227 *
228  CALL zlacpy( 'F', 1, n, a(1, 1), lda+1, work(n), 1 )
229  IF( n.GT.1 ) THEN
230  CALL zlacpy( 'F', 1, n-1, a( 1, 2 ), lda+1, work( 2*n ), 1)
231  CALL zlacpy( 'F', 1, n-1, a( 1, 2 ), lda+1, work( 1 ), 1 )
232  CALL zlacgv( n-1, work( 1 ), 1 )
233  END IF
234  CALL zgtsv( n, nrhs, work(1), work(n), work(2*n), b, ldb,
235  $ info )
236 *
237 * 3) Backward substitution with U
238 *
239  IF( n.GT.1 ) THEN
240 *
241 * Compute U \ B -> B [ U \ (T \ (U**H \P**T * B) ) ]
242 *
243  CALL ztrsm( 'L', 'U', 'N', 'U', n-1, nrhs, one, a( 1, 2 ),
244  $ lda, b(2, 1), ldb)
245 *
246 * Pivot, P * B [ P * (U**H \ (T \ (U \P**T * B) )) ]
247 *
248  DO k = n, 1, -1
249  kp = ipiv( k )
250  IF( kp.NE.k )
251  $ CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
252  END DO
253  END IF
254 *
255  ELSE
256 *
257 * Solve A*X = B, where A = L*T*L**H.
258 *
259 * 1) Forward substitution with L
260 *
261  IF( n.GT.1 ) THEN
262 *
263 * Pivot, P**T * B -> B
264 *
265  DO k = 1, n
266  kp = ipiv( k )
267  IF( kp.NE.k )
268  $ CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
269  END DO
270 *
271 * Compute L \ B -> B [ (L \P**T * B) ]
272 *
273  CALL ztrsm( 'L', 'L', 'N', 'U', n-1, nrhs, one, a( 2, 1 ),
274  $ lda, b(2, 1), ldb)
275  END IF
276 *
277 * 2) Solve with triangular matrix T
278 *
279 * Compute T \ B -> B [ T \ (L \P**T * B) ]
280 *
281  CALL zlacpy( 'F', 1, n, a(1, 1), lda+1, work(n), 1)
282  IF( n.GT.1 ) THEN
283  CALL zlacpy( 'F', 1, n-1, a( 2, 1 ), lda+1, work( 1 ), 1)
284  CALL zlacpy( 'F', 1, n-1, a( 2, 1 ), lda+1, work( 2*n ), 1)
285  CALL zlacgv( n-1, work( 2*n ), 1 )
286  END IF
287  CALL zgtsv(n, nrhs, work(1), work(n), work(2*n), b, ldb,
288  $ info)
289 *
290 * 3) Backward substitution with L**H
291 *
292  IF( n.GT.1 ) THEN
293 *
294 * Compute L**H \ B -> B [ L**H \ (T \ (L \P**T * B) ) ]
295 *
296  CALL ztrsm( 'L', 'L', 'C', 'U', n-1, nrhs, one, a( 2, 1 ),
297  $ lda, b( 2, 1 ), ldb)
298 *
299 * Pivot, P * B [ P * (L**H \ (T \ (L \P**T * B) )) ]
300 *
301  DO k = n, 1, -1
302  kp = ipiv( k )
303  IF( kp.NE.k )
304  $ CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
305  END DO
306  END IF
307 *
308  END IF
309 *
310  RETURN
311 *
312 * End of ZHETRS_AA
313 *
Here is the call graph for this function:
Here is the caller graph for this function:
zlacgv
subroutine zlacgv(N, X, INCX)
ZLACGV conjugates a complex vector.
Definition: zlacgv.f:76
ztrsm
subroutine ztrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRSM
Definition: ztrsm.f:182
zgtsv
subroutine zgtsv(N, NRHS, DL, D, DU, B, LDB, INFO)
ZGTSV computes the solution to system of linear equations A * X = B for GT matrices
Definition: zgtsv.f:126
zlacpy
subroutine zlacpy(UPLO, M, N, A, LDA, B, LDB)
ZLACPY copies all or part of one two-dimensional array to another.
Definition: zlacpy.f:105
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
lsame
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
zswap
subroutine zswap(N, ZX, INCX, ZY, INCY)
ZSWAP
Definition: zswap.f:83