claed8()

subroutine claed8	(	integer	K,
		integer	N,
		integer	QSIZ,
		complex, dimension( ldq, * )	Q,
		integer	LDQ,
		real, dimension( * )	D,
		real	RHO,
		integer	CUTPNT,
		real, dimension( * )	Z,
		real, dimension( * )	DLAMDA,
		complex, dimension( ldq2, * )	Q2,
		integer	LDQ2,
		real, dimension( * )	W,
		integer, dimension( * )	INDXP,
		integer, dimension( * )	INDX,
		integer, dimension( * )	INDXQ,
		integer, dimension( * )	PERM,
		integer	GIVPTR,
		integer, dimension( 2, * )	GIVCOL,
		real, dimension( 2, * )	GIVNUM,
		integer	INFO
	)

CLAED8 used by sstedc. Merges eigenvalues and deflates secular equation. Used when the original matrix is dense.

Download CLAED8 + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CLAED8 merges the two sets of eigenvalues together into a single
 sorted set.  Then it tries to deflate the size of the problem.
 There are two ways in which deflation can occur:  when two or more
 eigenvalues are close together or if there is a tiny element in the
 Z vector.  For each such occurrence the order of the related secular
 equation problem is reduced by one.

Parameters

[out]	K	K is INTEGER Contains the number of non-deflated eigenvalues. This is the order of the related secular equation.
[in]	N	N is INTEGER The dimension of the symmetric tridiagonal matrix. N >= 0.
[in]	QSIZ	QSIZ is INTEGER The dimension of the unitary matrix used to reduce the dense or band matrix to tridiagonal form. QSIZ >= N if ICOMPQ = 1.
[in,out]	Q	Q is COMPLEX array, dimension (LDQ,N) On entry, Q contains the eigenvectors of the partially solved system which has been previously updated in matrix multiplies with other partially solved eigensystems. On exit, Q contains the trailing (N-K) updated eigenvectors (those which were deflated) in its last N-K columns.
[in]	LDQ	LDQ is INTEGER The leading dimension of the array Q. LDQ >= max( 1, N ).
[in,out]	D	D is REAL array, dimension (N) On entry, D contains the eigenvalues of the two submatrices to be combined. On exit, D contains the trailing (N-K) updated eigenvalues (those which were deflated) sorted into increasing order.
[in,out]	RHO	RHO is REAL Contains the off diagonal element associated with the rank-1 cut which originally split the two submatrices which are now being recombined. RHO is modified during the computation to the value required by SLAED3.
[in]	CUTPNT	CUTPNT is INTEGER Contains the location of the last eigenvalue in the leading sub-matrix. MIN(1,N) <= CUTPNT <= N.
[in]	Z	Z is REAL array, dimension (N) On input this vector contains the updating vector (the last row of the first sub-eigenvector matrix and the first row of the second sub-eigenvector matrix). The contents of Z are destroyed during the updating process.
[out]	DLAMDA	DLAMDA is REAL array, dimension (N) Contains a copy of the first K eigenvalues which will be used by SLAED3 to form the secular equation.
[out]	Q2	Q2 is COMPLEX array, dimension (LDQ2,N) If ICOMPQ = 0, Q2 is not referenced. Otherwise, Contains a copy of the first K eigenvectors which will be used by SLAED7 in a matrix multiply (SGEMM) to update the new eigenvectors.
[in]	LDQ2	LDQ2 is INTEGER The leading dimension of the array Q2. LDQ2 >= max( 1, N ).
[out]	W	W is REAL array, dimension (N) This will hold the first k values of the final deflation-altered z-vector and will be passed to SLAED3.
[out]	INDXP	INDXP is INTEGER array, dimension (N) This will contain the permutation used to place deflated values of D at the end of the array. On output INDXP(1:K) points to the nondeflated D-values and INDXP(K+1:N) points to the deflated eigenvalues.
[out]	INDX	INDX is INTEGER array, dimension (N) This will contain the permutation used to sort the contents of D into ascending order.
[in]	INDXQ	INDXQ is INTEGER array, dimension (N) This contains the permutation which separately sorts the two sub-problems in D into ascending order. Note that elements in the second half of this permutation must first have CUTPNT added to their values in order to be accurate.
[out]	PERM	PERM is INTEGER array, dimension (N) Contains the permutations (from deflation and sorting) to be applied to each eigenblock.
[out]	GIVPTR	GIVPTR is INTEGER Contains the number of Givens rotations which took place in this subproblem.
[out]	GIVCOL	GIVCOL is INTEGER array, dimension (2, N) Each pair of numbers indicates a pair of columns to take place in a Givens rotation.
[out]	GIVNUM	GIVNUM is REAL array, dimension (2, N) Each number indicates the S value to be used in the corresponding Givens rotation.
[out]	INFO	INFO is INTEGER = 0: successful exit. < 0: if INFO = -i, the i-th argument had an illegal value.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 230 of file claed8.f.

*
*  -- LAPACK computational routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            CUTPNT, GIVPTR, INFO, K, LDQ, LDQ2, N, QSIZ
      REAL               RHO
*     ..
*     .. Array Arguments ..
      INTEGER            GIVCOL( 2, * ), INDX( * ), INDXP( * ),
     $                   INDXQ( * ), PERM( * )
      REAL               D( * ), DLAMDA( * ), GIVNUM( 2, * ), W( * ),
     $                   Z( * )
      COMPLEX            Q( LDQ, * ), Q2( LDQ2, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               MONE, ZERO, ONE, TWO, EIGHT
      parameter( mone = -1.0e0, zero = 0.0e0, one = 1.0e0,
     $                   two = 2.0e0, eight = 8.0e0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IMAX, J, JLAM, JMAX, JP, K2, N1, N1P1, N2
      REAL               C, EPS, S, T, TAU, TOL
*     ..
*     .. External Functions ..
      INTEGER            ISAMAX
      REAL               SLAMCH, SLAPY2
      EXTERNAL           isamax, slamch, slapy2
*     ..
*     .. External Subroutines ..
      EXTERNAL           ccopy, clacpy, csrot, scopy, slamrg, sscal,
     $                   xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max, min, sqrt
*     ..
*     .. Executable Statements ..
*
*     Test the input parameters.
*
      info = 0
*
      IF( n.LT.0 ) THEN
         info = -2
      ELSE IF( qsiz.LT.n ) THEN
         info = -3
      ELSE IF( ldq.LT.max( 1, n ) ) THEN
         info = -5
      ELSE IF( cutpnt.LT.min( 1, n ) .OR. cutpnt.GT.n ) THEN
         info = -8
      ELSE IF( ldq2.LT.max( 1, n ) ) THEN
         info = -12
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'CLAED8', -info )
         RETURN
      END IF
*
*     Need to initialize GIVPTR to O here in case of quick exit
*     to prevent an unspecified code behavior (usually sigfault)
*     when IWORK array on entry to *stedc is not zeroed
*     (or at least some IWORK entries which used in *laed7 for GIVPTR).
*
      givptr = 0
*
*     Quick return if possible
*
      IF( n.EQ.0 )
     $   RETURN
*
      n1 = cutpnt
      n2 = n - n1
      n1p1 = n1 + 1
*
      IF( rho.LT.zero ) THEN
         CALL sscal( n2, mone, z( n1p1 ), 1 )
      END IF
*
*     Normalize z so that norm(z) = 1
*
      t = one / sqrt( two )
      DO 10 j = 1, n
         indx( j ) = j
   10 CONTINUE
      CALL sscal( n, t, z, 1 )
      rho = abs( two*rho )
*
*     Sort the eigenvalues into increasing order
*
      DO 20 i = cutpnt + 1, n
         indxq( i ) = indxq( i ) + cutpnt
   20 CONTINUE
      DO 30 i = 1, n
         dlamda( i ) = d( indxq( i ) )
         w( i ) = z( indxq( i ) )
   30 CONTINUE
      i = 1
      j = cutpnt + 1
      CALL slamrg( n1, n2, dlamda, 1, 1, indx )
      DO 40 i = 1, n
         d( i ) = dlamda( indx( i ) )
         z( i ) = w( indx( i ) )
   40 CONTINUE
*
*     Calculate the allowable deflation tolerance
*
      imax = isamax( n, z, 1 )
      jmax = isamax( n, d, 1 )
      eps = slamch( 'Epsilon' )
      tol = eight*eps*abs( d( jmax ) )
*
*     If the rank-1 modifier is small enough, no more needs to be done
*     -- except to reorganize Q so that its columns correspond with the
*     elements in D.
*
      IF( rho*abs( z( imax ) ).LE.tol ) THEN
         k = 0
         DO 50 j = 1, n
            perm( j ) = indxq( indx( j ) )
            CALL ccopy( qsiz, q( 1, perm( j ) ), 1, q2( 1, j ), 1 )
   50    CONTINUE
         CALL clacpy( 'A', qsiz, n, q2( 1, 1 ), ldq2, q( 1, 1 ), ldq )
         RETURN
      END IF
*
*     If there are multiple eigenvalues then the problem deflates.  Here
*     the number of equal eigenvalues are found.  As each equal
*     eigenvalue is found, an elementary reflector is computed to rotate
*     the corresponding eigensubspace so that the corresponding
*     components of Z are zero in this new basis.
*
      k = 0
      k2 = n + 1
      DO 60 j = 1, n
         IF( rho*abs( z( j ) ).LE.tol ) THEN
*
*           Deflate due to small z component.
*
            k2 = k2 - 1
            indxp( k2 ) = j
            IF( j.EQ.n )
     $         GO TO 100
         ELSE
            jlam = j
            GO TO 70
         END IF
   60 CONTINUE
   70 CONTINUE
      j = j + 1
      IF( j.GT.n )
     $   GO TO 90
      IF( rho*abs( z( j ) ).LE.tol ) THEN
*
*        Deflate due to small z component.
*
         k2 = k2 - 1
         indxp( k2 ) = j
      ELSE
*
*        Check if eigenvalues are close enough to allow deflation.
*
         s = z( jlam )
         c = z( j )
*
*        Find sqrt(a**2+b**2) without overflow or
*        destructive underflow.
*
         tau = slapy2( c, s )
         t = d( j ) - d( jlam )
         c = c / tau
         s = -s / tau
         IF( abs( t*c*s ).LE.tol ) THEN
*
*           Deflation is possible.
*
            z( j ) = tau
            z( jlam ) = zero
*
*           Record the appropriate Givens rotation
*
            givptr = givptr + 1
            givcol( 1, givptr ) = indxq( indx( jlam ) )
            givcol( 2, givptr ) = indxq( indx( j ) )
            givnum( 1, givptr ) = c
            givnum( 2, givptr ) = s
            CALL csrot( qsiz, q( 1, indxq( indx( jlam ) ) ), 1,
     $                  q( 1, indxq( indx( j ) ) ), 1, c, s )
            t = d( jlam )*c*c + d( j )*s*s
            d( j ) = d( jlam )*s*s + d( j )*c*c
            d( jlam ) = t
            k2 = k2 - 1
            i = 1
   80       CONTINUE
            IF( k2+i.LE.n ) THEN
               IF( d( jlam ).LT.d( indxp( k2+i ) ) ) THEN
                  indxp( k2+i-1 ) = indxp( k2+i )
                  indxp( k2+i ) = jlam
                  i = i + 1
                  GO TO 80
               ELSE
                  indxp( k2+i-1 ) = jlam
               END IF
            ELSE
               indxp( k2+i-1 ) = jlam
            END IF
            jlam = j
         ELSE
            k = k + 1
            w( k ) = z( jlam )
            dlamda( k ) = d( jlam )
            indxp( k ) = jlam
            jlam = j
         END IF
      END IF
      GO TO 70
   90 CONTINUE
*
*     Record the last eigenvalue.
*
      k = k + 1
      w( k ) = z( jlam )
      dlamda( k ) = d( jlam )
      indxp( k ) = jlam
*
  100 CONTINUE
*
*     Sort the eigenvalues and corresponding eigenvectors into DLAMDA
*     and Q2 respectively.  The eigenvalues/vectors which were not
*     deflated go into the first K slots of DLAMDA and Q2 respectively,
*     while those which were deflated go into the last N - K slots.
*
      DO 110 j = 1, n
         jp = indxp( j )
         dlamda( j ) = d( jp )
         perm( j ) = indxq( indx( jp ) )
         CALL ccopy( qsiz, q( 1, perm( j ) ), 1, q2( 1, j ), 1 )
  110 CONTINUE
*
*     The deflated eigenvalues and their corresponding vectors go back
*     into the last N - K slots of D and Q respectively.
*
      IF( k.LT.n ) THEN
         CALL scopy( n-k, dlamda( k+1 ), 1, d( k+1 ), 1 )
         CALL clacpy( 'A', qsiz, n-k, q2( 1, k+1 ), ldq2, q( 1, k+1 ),
     $                ldq )
      END IF
*
      RETURN
*
*     End of CLAED8
*

Here is the call graph for this function:

Here is the caller graph for this function: