sla_porcond.f

Go to the documentation of this file.

*> \brief \b SLA_PORCOND estimates the Skeel condition number for a symmetric positive-definite matrix.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download SLA_PORCOND + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/sla_porcond.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/sla_porcond.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/sla_porcond.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       REAL FUNCTION SLA_PORCOND( UPLO, N, A, LDA, AF, LDAF, CMODE, C,
*                                  INFO, WORK, IWORK )
*
*       .. Scalar Arguments ..
*       CHARACTER          UPLO
*       INTEGER            N, LDA, LDAF, INFO, CMODE
*       REAL               A( LDA, * ), AF( LDAF, * ), WORK( * ),
*      $                   C( * )
*       ..
*       .. Array Arguments ..
*       INTEGER            IWORK( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*>    SLA_PORCOND Estimates the Skeel condition number of  op(A) * op2(C)
*>    where op2 is determined by CMODE as follows
*>    CMODE =  1    op2(C) = C
*>    CMODE =  0    op2(C) = I
*>    CMODE = -1    op2(C) = inv(C)
*>    The Skeel condition number  cond(A) = norminf( |inv(A)||A| )
*>    is computed by computing scaling factors R such that
*>    diag(R)*A*op2(C) is row equilibrated and computing the standard
*>    infinity-norm condition number.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>       = 'U':  Upper triangle of A is stored;
*>       = 'L':  Lower triangle of A is stored.
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>     The number of linear equations, i.e., the order of the
*>     matrix A.  N >= 0.
*> \endverbatim
*>
*> \param[in] A
*> \verbatim
*>          A is REAL array, dimension (LDA,N)
*>     On entry, the N-by-N matrix A.
*> \endverbatim
*>
*> \param[in] LDA
*> \verbatim
*>          LDA is INTEGER
*>     The leading dimension of the array A.  LDA >= max(1,N).
*> \endverbatim
*>
*> \param[in] AF
*> \verbatim
*>          AF is REAL array, dimension (LDAF,N)
*>     The triangular factor U or L from the Cholesky factorization
*>     A = U**T*U or A = L*L**T, as computed by SPOTRF.
*> \endverbatim
*>
*> \param[in] LDAF
*> \verbatim
*>          LDAF is INTEGER
*>     The leading dimension of the array AF.  LDAF >= max(1,N).
*> \endverbatim
*>
*> \param[in] CMODE
*> \verbatim
*>          CMODE is INTEGER
*>     Determines op2(C) in the formula op(A) * op2(C) as follows:
*>     CMODE =  1    op2(C) = C
*>     CMODE =  0    op2(C) = I
*>     CMODE = -1    op2(C) = inv(C)
*> \endverbatim
*>
*> \param[in] C
*> \verbatim
*>          C is REAL array, dimension (N)
*>     The vector C in the formula op(A) * op2(C).
*> \endverbatim
*>
*> \param[out] INFO
*> \verbatim
*>          INFO is INTEGER
*>       = 0:  Successful exit.
*>     i > 0:  The ith argument is invalid.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (3*N).
*>     Workspace.
*> \endverbatim
*>
*> \param[out] IWORK
*> \verbatim
*>          IWORK is INTEGER array, dimension (N).
*>     Workspace.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date December 2016
*
*> \ingroup realPOcomputational
*
*  =====================================================================
      REAL FUNCTION SLA_PORCOND( UPLO, N, A, LDA, AF, LDAF, CMODE, C,
     $                           INFO, WORK, IWORK )
*
*  -- LAPACK computational routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      CHARACTER          uplo
      INTEGER            n, lda, ldaf, info, cmode
      REAL               a( lda, * ), af( ldaf, * ), work( * ),
     $                   c( * )
*     ..
*     .. Array Arguments ..
      INTEGER            iwork( * )
*     ..
*
*  =====================================================================
*
*     .. Local Scalars ..
      INTEGER            kase, i, j
      REAL               ainvnm, tmp
      LOGICAL            up
*     ..
*     .. Array Arguments ..
      INTEGER            isave( 3 )
*     ..
*     .. External Functions ..
      LOGICAL            lsame
      EXTERNAL           lsame
*     ..
*     .. External Subroutines ..
      EXTERNAL           slacn2, spotrs, xerbla
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, max
*     ..
*     .. Executable Statements ..
*
      sla_porcond = 0.0
*
      info = 0
      IF( n.LT.0 ) THEN
         info = -2
      END IF
      IF( info.NE.0 ) THEN
         CALL xerbla( 'SLA_PORCOND', -info )
         RETURN
      END IF
 
      IF( n.EQ.0 ) THEN
         sla_porcond = 1.0
         RETURN
      END IF
      up = .false.
      IF ( lsame( uplo, 'U' ) ) up = .true.
*
*     Compute the equilibration matrix R such that
*     inv(R)*A*C has unit 1-norm.
*
      IF ( up ) THEN
         DO i = 1, n
            tmp = 0.0
            IF ( cmode .EQ. 1 ) THEN
               DO j = 1, i
                  tmp = tmp + abs( a( j, i ) * c( j ) )
               END DO
               DO j = i+1, n
                  tmp = tmp + abs( a( i, j ) * c( j ) )
               END DO
            ELSE IF ( cmode .EQ. 0 ) THEN
               DO j = 1, i
                  tmp = tmp + abs( a( j, i ) )
               END DO
               DO j = i+1, n
                  tmp = tmp + abs( a( i, j ) )
               END DO
            ELSE
               DO j = 1, i
                  tmp = tmp + abs( a( j ,i ) / c( j ) )
               END DO
               DO j = i+1, n
                  tmp = tmp + abs( a( i, j ) / c( j ) )
               END DO
            END IF
            work( 2*n+i ) = tmp
         END DO
      ELSE
         DO i = 1, n
            tmp = 0.0
            IF ( cmode .EQ. 1 ) THEN
               DO j = 1, i
                  tmp = tmp + abs( a( i, j ) * c( j ) )
               END DO
               DO j = i+1, n
                  tmp = tmp + abs( a( j, i ) * c( j ) )
               END DO
            ELSE IF ( cmode .EQ. 0 ) THEN
               DO j = 1, i
                  tmp = tmp + abs( a( i, j ) )
               END DO
               DO j = i+1, n
                  tmp = tmp + abs( a( j, i ) )
               END DO
            ELSE
               DO j = 1, i
                  tmp = tmp + abs( a( i, j ) / c( j ) )
               END DO
               DO j = i+1, n
                  tmp = tmp + abs( a( j, i ) / c( j ) )
               END DO
            END IF
            work( 2*n+i ) = tmp
         END DO
      ENDIF
*
*     Estimate the norm of inv(op(A)).
*
      ainvnm = 0.0
 
      kase = 0
   10 CONTINUE
      CALL slacn2( n, work( n+1 ), work, iwork, ainvnm, kase, isave )
      IF( kase.NE.0 ) THEN
         IF( kase.EQ.2 ) THEN
*
*           Multiply by R.
*
            DO i = 1, n
               work( i ) = work( i ) * work( 2*n+i )
            END DO
 
            IF (up) THEN
               CALL spotrs( 'Upper', n, 1, af, ldaf, work, n, info )
            ELSE
               CALL spotrs( 'Lower', n, 1, af, ldaf, work, n, info )
            ENDIF
*
*           Multiply by inv(C).
*
            IF ( cmode .EQ. 1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) / c( i )
               END DO
            ELSE IF ( cmode .EQ. -1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) * c( i )
               END DO
            END IF
         ELSE
*
*           Multiply by inv(C**T).
*
            IF ( cmode .EQ. 1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) / c( i )
               END DO
            ELSE IF ( cmode .EQ. -1 ) THEN
               DO i = 1, n
                  work( i ) = work( i ) * c( i )
               END DO
            END IF
 
            IF ( up ) THEN
               CALL spotrs( 'Upper', n, 1, af, ldaf, work, n, info )
            ELSE
               CALL spotrs( 'Lower', n, 1, af, ldaf, work, n, info )
            ENDIF
*
*           Multiply by R.
*
            DO i = 1, n
               work( i ) = work( i ) * work( 2*n+i )
            END DO
         END IF
         GO TO 10
      END IF
*
*     Compute the estimate of the reciprocal condition number.
*
      IF( ainvnm .NE. 0.0 )
     $   sla_porcond = ( 1.0 / ainvnm )
*
      RETURN
*
      END