cunhr_col01.f

Go to the documentation of this file.

*> \brief \b CUNHR_COL01
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*  Definition:
*  ===========
*
*       SUBROUTINE CUNHR_COL01( M, N, MB1, NB1, NB2, RESULT )
*
*       .. Scalar Arguments ..
*       INTEGER           M, N, MB1, NB1, NB2
*       .. Return values ..
*       REAL              RESULT(6)
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CUNHR_COL01 tests CUNHR_COL using CLATSQR, CGEMQRT and CUNGTSQR.
*> Therefore, CLATSQR (part of CGEQR), CGEMQRT (part CGEMQR), CUNGTSQR
*> have to be tested before this test.
*>
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] M
*> \verbatim
*>          M is INTEGER
*>          Number of rows in test matrix.
*> \endverbatim
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          Number of columns in test matrix.
*> \endverbatim
*> \param[in] MB1
*> \verbatim
*>          MB1 is INTEGER
*>          Number of row in row block in an input test matrix.
*> \endverbatim
*>
*> \param[in] NB1
*> \verbatim
*>          NB1 is INTEGER
*>          Number of columns in column block an input test matrix.
*> \endverbatim
*>
*> \param[in] NB2
*> \verbatim
*>          NB2 is INTEGER
*>          Number of columns in column block in an output test matrix.
*> \endverbatim
*>
*> \param[out] RESULT
*> \verbatim
*>          RESULT is REAL array, dimension (6)
*>          Results of each of the six tests below.
*>          ( C is a M-by-N random matrix, D is a N-by-M random matrix )
*>
*>          RESULT(1) = | A - Q * R | / (eps * m * |A|)
*>          RESULT(2) = | I - (Q**H) * Q | / (eps * m )
*>          RESULT(3) = | Q * C - Q * C | / (eps * m * |C|)
*>          RESULT(4) = | (Q**H) * C - (Q**H) * C | / (eps * m * |C|)
*>          RESULT(5) = | (D * Q) - D * Q | / (eps * m * |D|)
*>          RESULT(6) = | D * (Q**H) - D * (Q**H) | / (eps * m * |D|)
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date November 2019
*
*> \ingroup complex16_lin
*
*  =====================================================================
      SUBROUTINE cunhr_col01( M, N, MB1, NB1, NB2, RESULT )
      IMPLICIT NONE
*
*  -- LAPACK test routine (version 3.9.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2019
*
*     .. Scalar Arguments ..
      INTEGER           M, N, MB1, NB1, NB2
*     .. Return values ..
      REAL              RESULT(6)
*
*  =====================================================================
*
*     ..
*     .. Local allocatable arrays
      COMPLEX, ALLOCATABLE ::  A(:,:), AF(:,:), Q(:,:), R(:,:),
     $                   WORK( : ), T1(:,:), T2(:,:), DIAG(:),
     $                   C(:,:), CF(:,:), D(:,:), DF(:,:)
      REAL, ALLOCATABLE :: RWORK(:)
*
*     .. Parameters ..
      REAL               ZERO
      parameter( zero = 0.0e+0 )
      COMPLEX            CONE, CZERO
      parameter( cone = ( 1.0e+0, 0.0e+0 ),
     $                     czero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      LOGICAL            TESTZEROS
      INTEGER            INFO, I, J, K, L, LWORK, NB1_UB, NB2_UB, NRB
      REAL               ANORM, EPS, RESID, CNORM, DNORM
*     ..
*     .. Local Arrays ..
      INTEGER            ISEED( 4 )
      COMPLEX            WORKQUERY( 1 )
*     ..
*     .. External Functions ..
      REAL               SLAMCH, CLANGE, CLANSY
      EXTERNAL           slamch, clange, clansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           clacpy, clarnv, claset, clatsqr, cunhr_col,
     $                   cungtsqr, cscal, cgemm, cgemqrt, cherk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          ceiling, real, max, min
*     ..
*     .. Scalars in Common ..
      CHARACTER(LEN=32)  SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srmnamc / srnamt
*     ..
*     .. Data statements ..
      DATA iseed / 1988, 1989, 1990, 1991 /
*
*     TEST MATRICES WITH HALF OF MATRIX BEING ZEROS
*
      testzeros = .false.
*
      eps = slamch( 'Epsilon' )
      k = min( m, n )
      l = max( m, n, 1)
*
*     Dynamically allocate local arrays
*
      ALLOCATE ( a(m,n), af(m,n), q(l,l), r(m,l), rwork(l),
     $           c(m,n), cf(m,n),
     $           d(n,m), df(n,m) )
*
*     Put random numbers into A and copy to AF
*
      DO j = 1, n
         CALL clarnv( 2, iseed, m, a( 1, j ) )
      END DO
      IF( testzeros ) THEN
         IF( m.GE.4 ) THEN
            DO j = 1, n
               CALL clarnv( 2, iseed, m/2, a( m/4, j ) )
            END DO
         END IF
      END IF
      CALL clacpy( 'Full', m, n, a, m, af, m )
*
*     Number of row blocks in CLATSQR
*
      nrb = max( 1, ceiling( real( m - n ) / real( mb1 - n ) ) )
*
      ALLOCATE ( t1( nb1, n * nrb ) )
      ALLOCATE ( t2( nb2, n ) )
      ALLOCATE ( diag( n ) )
*
*     Begin determine LWORK for the array WORK and allocate memory.
*
*     CLATSQR requires NB1 to be bounded by N.
*
      nb1_ub = min( nb1, n)
*
*     CGEMQRT requires NB2 to be bounded by N.
*
      nb2_ub = min( nb2, n)
*
      CALL clatsqr( m, n, mb1, nb1_ub, af, m, t1, nb1,
     $              workquery, -1, info )
      lwork = int( workquery( 1 ) )
      CALL cungtsqr( m, n, mb1, nb1, af, m, t1, nb1, workquery, -1,
     $               info )
 
      lwork = max( lwork, int( workquery( 1 ) ) )
*
*     In CGEMQRT, WORK is N*NB2_UB if SIDE = 'L',
*                or  M*NB2_UB if SIDE = 'R'.
*
      lwork = max( lwork, nb2_ub * n, nb2_ub * m )
*
      ALLOCATE ( work( lwork ) )
*
*     End allocate memory for WORK.
*
*
*     Begin Householder reconstruction routines
*
*     Factor the matrix A in the array AF.
*
      srnamt = 'CLATSQR'
      CALL clatsqr( m, n, mb1, nb1_ub, af, m, t1, nb1, work, lwork,
     $              info )
*
*     Copy the factor R into the array R.
*
      srnamt = 'CLACPY'
      CALL clacpy( 'U', m, n, af, m, r, m )
*
*     Reconstruct the orthogonal matrix Q.
*
      srnamt = 'CUNGTSQR'
      CALL cungtsqr( m, n, mb1, nb1, af, m, t1, nb1, work, lwork,
     $               info )
*
*     Perform the Householder reconstruction, the result is stored
*     the arrays AF and T2.
*
      srnamt = 'CUNHR_COL'
      CALL cunhr_col( m, n, nb2, af, m, t2, nb2, diag, info )
*
*     Compute the factor R_hr corresponding to the Householder
*     reconstructed Q_hr and place it in the upper triangle of AF to
*     match the Q storage format in CGEQRT. R_hr = R_tsqr * S,
*     this means changing the sign of I-th row of the matrix R_tsqr
*     according to sign of of I-th diagonal element DIAG(I) of the
*     matrix S.
*
      srnamt = 'CLACPY'
      CALL clacpy( 'U', m, n, r, m, af, m )
*
      DO i = 1, n
         IF( diag( i ).EQ.-cone ) THEN
            CALL cscal( n+1-i, -cone, af( i, i ), m )
         END IF
      END DO
*
*     End Householder reconstruction routines.
*
*
*     Generate the m-by-m matrix Q
*
      CALL claset( 'Full', m, m, czero, cone, q, m )
*
      srnamt = 'CGEMQRT'
      CALL cgemqrt( 'L', 'N', m, m, k, nb2_ub, af, m, t2, nb2, q, m,
     $              work, info )
*
*     Copy R
*
      CALL claset( 'Full', m, n, czero, czero, r, m )
*
      CALL clacpy( 'Upper', m, n, af, m, r, m )
*
*     TEST 1
*     Compute |R - (Q**H)*A| / ( eps * m * |A| ) and store in RESULT(1)
*
      CALL cgemm( 'C', 'N', m, n, m, -cone, q, m, a, m, cone, r, m )
*
      anorm = clange( '1', m, n, a, m, rwork )
      resid = clange( '1', m, n, r, m, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = resid / ( eps * max( 1, m ) * anorm )
      ELSE
         result( 1 ) = zero
      END IF
*
*     TEST 2
*     Compute |I - (Q**H)*Q| / ( eps * m ) and store in RESULT(2)
*
      CALL claset( 'Full', m, m, czero, cone, r, m )
      CALL cherk( 'U', 'C', m, m, -cone, q, m, cone, r, m )
      resid = clansy( '1', 'Upper', m, r, m, rwork )
      result( 2 ) = resid / ( eps * max( 1, m ) )
*
*     Generate random m-by-n matrix C
*
      DO j = 1, n
         CALL clarnv( 2, iseed, m, c( 1, j ) )
      END DO
      cnorm = clange( '1', m, n, c, m, rwork )
      CALL clacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as Q*C = CF
*
      srnamt = 'CGEMQRT'
      CALL cgemqrt( 'L', 'N', m, n, k, nb2_ub, af, m, t2, nb2, cf, m,
     $               work, info )
*
*     TEST 3
*     Compute |CF - Q*C| / ( eps *  m * |C| )
*
      CALL cgemm( 'N', 'N', m, n, m, -cone, q, m, c, m, cone, cf, m )
      resid = clange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 3 ) = resid / ( eps * max( 1, m ) * cnorm )
      ELSE
         result( 3 ) = zero
      END IF
*
*     Copy C into CF again
*
      CALL clacpy( 'Full', m, n, c, m, cf, m )
*
*     Apply Q to C as (Q**H)*C = CF
*
      srnamt = 'CGEMQRT'
      CALL cgemqrt( 'L', 'C', m, n, k, nb2_ub, af, m, t2, nb2, cf, m,
     $               work, info )
*
*     TEST 4
*     Compute |CF - (Q**H)*C| / ( eps * m * |C|)
*
      CALL cgemm( 'C', 'N', m, n, m, -cone, q, m, c, m, cone, cf, m )
      resid = clange( '1', m, n, cf, m, rwork )
      IF( cnorm.GT.zero ) THEN
         result( 4 ) = resid / ( eps * max( 1, m ) * cnorm )
      ELSE
         result( 4 ) = zero
      END IF
*
*     Generate random n-by-m matrix D and a copy DF
*
      DO j = 1, m
         CALL clarnv( 2, iseed, n, d( 1, j ) )
      END DO
      dnorm = clange( '1', n, m, d, n, rwork )
      CALL clacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as D*Q = DF
*
      srnamt = 'CGEMQRT'
      CALL cgemqrt( 'R', 'N', n, m, k, nb2_ub, af, m, t2, nb2, df, n,
     $               work, info )
*
*     TEST 5
*     Compute |DF - D*Q| / ( eps * m * |D| )
*
      CALL cgemm( 'N', 'N', n, m, m, -cone, d, n, q, m, cone, df, n )
      resid = clange( '1', n, m, df, n, rwork )
      IF( dnorm.GT.zero ) THEN
         result( 5 ) = resid / ( eps * max( 1, m ) * dnorm )
      ELSE
         result( 5 ) = zero
      END IF
*
*     Copy D into DF again
*
      CALL clacpy( 'Full', n, m, d, n, df, n )
*
*     Apply Q to D as D*QT = DF
*
      srnamt = 'CGEMQRT'
      CALL cgemqrt( 'R', 'C', n, m, k, nb2_ub, af, m, t2, nb2, df, n,
     $               work, info )
*
*     TEST 6
*     Compute |DF - D*(Q**H)| / ( eps * m * |D| )
*
      CALL cgemm( 'N', 'C', n, m, m, -cone, d, n, q, m, cone, df, n )
      resid = clange( '1', n, m, df, n, rwork )
      IF( dnorm.GT.zero ) THEN
         result( 6 ) = resid / ( eps * max( 1, m ) * dnorm )
      ELSE
         result( 6 ) = zero
      END IF
*
*     Deallocate all arrays
*
      DEALLOCATE ( a, af, q, r, rwork, work, t1, t2, diag,
     $             c, d, cf, df )
*
      RETURN
*
*     End of CUNHR_COL01
*
      END