claein()

subroutine claein	(	logical	RIGHTV,
		logical	NOINIT,
		integer	N,
		complex, dimension( ldh, * )	H,
		integer	LDH,
		complex	W,
		complex, dimension( * )	V,
		complex, dimension( ldb, * )	B,
		integer	LDB,
		real, dimension( * )	RWORK,
		real	EPS3,
		real	SMLNUM,
		integer	INFO
	)

CLAEIN computes a specified right or left eigenvector of an upper Hessenberg matrix by inverse iteration.

Download CLAEIN + dependencies [TGZ] [ZIP] [TXT]

Purpose:

 CLAEIN uses inverse iteration to find a right or left eigenvector
 corresponding to the eigenvalue W of a complex upper Hessenberg
 matrix H.

Parameters

[in]	RIGHTV	RIGHTV is LOGICAL = .TRUE. : compute right eigenvector; = .FALSE.: compute left eigenvector.
[in]	NOINIT	NOINIT is LOGICAL = .TRUE. : no initial vector supplied in V = .FALSE.: initial vector supplied in V.
[in]	N	N is INTEGER The order of the matrix H. N >= 0.
[in]	H	H is COMPLEX array, dimension (LDH,N) The upper Hessenberg matrix H.
[in]	LDH	LDH is INTEGER The leading dimension of the array H. LDH >= max(1,N).
[in]	W	W is COMPLEX The eigenvalue of H whose corresponding right or left eigenvector is to be computed.
[in,out]	V	V is COMPLEX array, dimension (N) On entry, if NOINIT = .FALSE., V must contain a starting vector for inverse iteration; otherwise V need not be set. On exit, V contains the computed eigenvector, normalized so that the component of largest magnitude has magnitude 1; here the magnitude of a complex number (x,y) is taken to be |x| + |y|.
[out]	B	B is COMPLEX array, dimension (LDB,N)
[in]	LDB	LDB is INTEGER The leading dimension of the array B. LDB >= max(1,N).
[out]	RWORK	RWORK is REAL array, dimension (N)
[in]	EPS3	EPS3 is REAL A small machine-dependent value which is used to perturb close eigenvalues, and to replace zero pivots.
[in]	SMLNUM	SMLNUM is REAL A machine-dependent value close to the underflow threshold.
[out]	INFO	INFO is INTEGER = 0: successful exit = 1: inverse iteration did not converge; V is set to the last iterate.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 151 of file claein.f.

*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      LOGICAL            NOINIT, RIGHTV
      INTEGER            INFO, LDB, LDH, N
      REAL               EPS3, SMLNUM
      COMPLEX            W
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * )
      COMPLEX            B( LDB, * ), H( LDH, * ), V( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ONE, TENTH
      parameter( one = 1.0e+0, tenth = 1.0e-1 )
      COMPLEX            ZERO
      parameter( zero = ( 0.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      CHARACTER          NORMIN, TRANS
      INTEGER            I, IERR, ITS, J
      REAL               GROWTO, NRMSML, ROOTN, RTEMP, SCALE, VNORM
      COMPLEX            CDUM, EI, EJ, TEMP, X
*     ..
*     .. External Functions ..
      INTEGER            ICAMAX
      REAL               SCASUM, SCNRM2
      COMPLEX            CLADIV
      EXTERNAL           icamax, scasum, scnrm2, cladiv
*     ..
*     .. External Subroutines ..
      EXTERNAL           clatrs, csscal
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, max, real, sqrt
*     ..
*     .. Statement Functions ..
      REAL               CABS1
*     ..
*     .. Statement Function definitions ..
      cabs1( cdum ) = abs( real( cdum ) ) + abs( aimag( cdum ) )
*     ..
*     .. Executable Statements ..
*
      info = 0
*
*     GROWTO is the threshold used in the acceptance test for an
*     eigenvector.
*
      rootn = sqrt( real( n ) )
      growto = tenth / rootn
      nrmsml = max( one, eps3*rootn )*smlnum
*
*     Form B = H - W*I (except that the subdiagonal elements are not
*     stored).
*
      DO 20 j = 1, n
         DO 10 i = 1, j - 1
            b( i, j ) = h( i, j )
   10    CONTINUE
         b( j, j ) = h( j, j ) - w
   20 CONTINUE
*
      IF( noinit ) THEN
*
*        Initialize V.
*
         DO 30 i = 1, n
            v( i ) = eps3
   30    CONTINUE
      ELSE
*
*        Scale supplied initial vector.
*
         vnorm = scnrm2( n, v, 1 )
         CALL csscal( n, ( eps3*rootn ) / max( vnorm, nrmsml ), v, 1 )
      END IF
*
      IF( rightv ) THEN
*
*        LU decomposition with partial pivoting of B, replacing zero
*        pivots by EPS3.
*
         DO 60 i = 1, n - 1
            ei = h( i+1, i )
            IF( cabs1( b( i, i ) ).LT.cabs1( ei ) ) THEN
*
*              Interchange rows and eliminate.
*
               x = cladiv( b( i, i ), ei )
               b( i, i ) = ei
               DO 40 j = i + 1, n
                  temp = b( i+1, j )
                  b( i+1, j ) = b( i, j ) - x*temp
                  b( i, j ) = temp
   40          CONTINUE
            ELSE
*
*              Eliminate without interchange.
*
               IF( b( i, i ).EQ.zero )
     $            b( i, i ) = eps3
               x = cladiv( ei, b( i, i ) )
               IF( x.NE.zero ) THEN
                  DO 50 j = i + 1, n
                     b( i+1, j ) = b( i+1, j ) - x*b( i, j )
   50             CONTINUE
               END IF
            END IF
   60    CONTINUE
         IF( b( n, n ).EQ.zero )
     $      b( n, n ) = eps3
*
         trans = 'N'
*
      ELSE
*
*        UL decomposition with partial pivoting of B, replacing zero
*        pivots by EPS3.
*
         DO 90 j = n, 2, -1
            ej = h( j, j-1 )
            IF( cabs1( b( j, j ) ).LT.cabs1( ej ) ) THEN
*
*              Interchange columns and eliminate.
*
               x = cladiv( b( j, j ), ej )
               b( j, j ) = ej
               DO 70 i = 1, j - 1
                  temp = b( i, j-1 )
                  b( i, j-1 ) = b( i, j ) - x*temp
                  b( i, j ) = temp
   70          CONTINUE
            ELSE
*
*              Eliminate without interchange.
*
               IF( b( j, j ).EQ.zero )
     $            b( j, j ) = eps3
               x = cladiv( ej, b( j, j ) )
               IF( x.NE.zero ) THEN
                  DO 80 i = 1, j - 1
                     b( i, j-1 ) = b( i, j-1 ) - x*b( i, j )
   80             CONTINUE
               END IF
            END IF
   90    CONTINUE
         IF( b( 1, 1 ).EQ.zero )
     $      b( 1, 1 ) = eps3
*
         trans = 'C'
*
      END IF
*
      normin = 'N'
      DO 110 its = 1, n
*
*        Solve U*x = scale*v for a right eigenvector
*          or U**H *x = scale*v for a left eigenvector,
*        overwriting x on v.
*
         CALL clatrs( 'Upper', trans, 'Nonunit', normin, n, b, ldb, v,
     $                scale, rwork, ierr )
         normin = 'Y'
*
*        Test for sufficient growth in the norm of v.
*
         vnorm = scasum( n, v, 1 )
         IF( vnorm.GE.growto*scale )
     $      GO TO 120
*
*        Choose new orthogonal starting vector and try again.
*
         rtemp = eps3 / ( rootn+one )
         v( 1 ) = eps3
         DO 100 i = 2, n
            v( i ) = rtemp
  100    CONTINUE
         v( n-its+1 ) = v( n-its+1 ) - eps3*rootn
  110 CONTINUE
*
*     Failure to find eigenvector in N iterations.
*
      info = 1
*
  120 CONTINUE
*
*     Normalize eigenvector.
*
      i = icamax( n, v, 1 )
      CALL csscal( n, one / cabs1( v( i ) ), v, 1 )
*
      RETURN
*
*     End of CLAEIN
*

Here is the call graph for this function:

Here is the caller graph for this function: