scnrm2()

real function scnrm2	(	integer	N,
		complex, dimension(*)	X,
		integer	INCX
	)

SCNRM2

Purpose:

 SCNRM2 returns the euclidean norm of a vector via the function
 name, so that

    SCNRM2 := sqrt( x**H*x )

Parameters

[in]	N	N is INTEGER number of elements in input vector(s)
[in]	X	X is COMPLEX array, dimension (N) complex vector with N elements
[in]	INCX	INCX is INTEGER storage spacing between elements of X

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

November 2017

Further Details:

  -- This version written on 25-October-1982.
     Modified on 14-October-1993 to inline the call to CLASSQ.
     Sven Hammarling, Nag Ltd.

Definition at line 77 of file scnrm2.f.

*
*  -- Reference BLAS level1 routine (version 3.8.0) --
*  -- Reference BLAS is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     November 2017
*
*     .. Scalar Arguments ..
      INTEGER INCX,N
*     ..
*     .. Array Arguments ..
      COMPLEX X(*)
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL ONE,ZERO
      parameter(one=1.0e+0,zero=0.0e+0)
*     ..
*     .. Local Scalars ..
      REAL NORM,SCALE,SSQ,TEMP
      INTEGER IX
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC abs,aimag,real,sqrt
*     ..
      IF (n.LT.1 .OR. incx.LT.1) THEN
          norm = zero
      ELSE
          scale = zero
          ssq = one
*        The following loop is equivalent to this call to the LAPACK
*        auxiliary routine:
*        CALL CLASSQ( N, X, INCX, SCALE, SSQ )
*
          DO 10 ix = 1,1 + (n-1)*incx,incx
              IF (real(x(ix)).NE.zero) THEN
                  temp = abs(real(x(ix)))
                  IF (scale.LT.temp) THEN
                      ssq = one + ssq* (scale/temp)**2
                      scale = temp
                  ELSE
                      ssq = ssq + (temp/scale)**2
                  END IF
              END IF
              IF (aimag(x(ix)).NE.zero) THEN
                  temp = abs(aimag(x(ix)))
                  IF (scale.LT.temp) THEN
                      ssq = one + ssq* (scale/temp)**2
                      scale = temp
                  ELSE
                      ssq = ssq + (temp/scale)**2
                  END IF
              END IF
   10     CONTINUE
          norm = scale*sqrt(ssq)
      END IF
*
      scnrm2 = norm
      RETURN
*
*     End of SCNRM2.
*

Here is the caller graph for this function: