cget51()

subroutine cget51	(	integer	ITYPE,
		integer	N,
		complex, dimension( lda, * )	A,
		integer	LDA,
		complex, dimension( ldb, * )	B,
		integer	LDB,
		complex, dimension( ldu, * )	U,
		integer	LDU,
		complex, dimension( ldv, * )	V,
		integer	LDV,
		complex, dimension( * )	WORK,
		real, dimension( * )	RWORK,
		real	RESULT
	)

CGET51

Purpose:

      CGET51  generally checks a decomposition of the form

              A = U B V**H

      where **H means conjugate transpose and U and V are unitary.

      Specifically, if ITYPE=1

              RESULT = | A - U B V**H | / ( |A| n ulp )

      If ITYPE=2, then:

              RESULT = | A - B | / ( |A| n ulp )

      If ITYPE=3, then:

              RESULT = | I - U U**H | / ( n ulp )

Parameters

[in]	ITYPE	ITYPE is INTEGER Specifies the type of tests to be performed. =1: RESULT = | A - U B V**H | / ( |A| n ulp ) =2: RESULT = | A - B | / ( |A| n ulp ) =3: RESULT = | I - U U**H | / ( n ulp )
[in]	N	N is INTEGER The size of the matrix. If it is zero, CGET51 does nothing. It must be at least zero.
[in]	A	A is COMPLEX array, dimension (LDA, N) The original (unfactored) matrix.
[in]	LDA	LDA is INTEGER The leading dimension of A. It must be at least 1 and at least N.
[in]	B	B is COMPLEX array, dimension (LDB, N) The factored matrix.
[in]	LDB	LDB is INTEGER The leading dimension of B. It must be at least 1 and at least N.
[in]	U	U is COMPLEX array, dimension (LDU, N) The unitary matrix on the left-hand side in the decomposition. Not referenced if ITYPE=2
[in]	LDU	LDU is INTEGER The leading dimension of U. LDU must be at least N and at least 1.
[in]	V	V is COMPLEX array, dimension (LDV, N) The unitary matrix on the left-hand side in the decomposition. Not referenced if ITYPE=2
[in]	LDV	LDV is INTEGER The leading dimension of V. LDV must be at least N and at least 1.
[out]	WORK	WORK is COMPLEX array, dimension (2*N**2)
[out]	RWORK	RWORK is REAL array, dimension (N)
[out]	RESULT	RESULT is REAL The values computed by the test specified by ITYPE. The value is currently limited to 1/ulp, to avoid overflow. Errors are flagged by RESULT=10/ulp.

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 157 of file cget51.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            ITYPE, LDA, LDB, LDU, LDV, N
      REAL               RESULT
*     ..
*     .. Array Arguments ..
      REAL               RWORK( * )
      COMPLEX            A( LDA, * ), B( LDB, * ), U( LDU, * ),
     $                   V( LDV, * ), WORK( * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      REAL               ZERO, ONE, TEN
      parameter( zero = 0.0e+0, one = 1.0e+0, ten = 10.0e+0 )
      COMPLEX            CZERO, CONE
      parameter( czero = ( 0.0e+0, 0.0e+0 ),
     $                   cone = ( 1.0e+0, 0.0e+0 ) )
*     ..
*     .. Local Scalars ..
      INTEGER            JCOL, JDIAG, JROW
      REAL               ANORM, ULP, UNFL, WNORM
*     ..
*     .. External Functions ..
      REAL               CLANGE, SLAMCH
      EXTERNAL           clange, slamch
*     ..
*     .. External Subroutines ..
      EXTERNAL           cgemm, clacpy
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          max, min, real
*     ..
*     .. Executable Statements ..
*
      result = zero
      IF( n.LE.0 )
     $   RETURN
*
*     Constants
*
      unfl = slamch( 'Safe minimum' )
      ulp = slamch( 'Epsilon' )*slamch( 'Base' )
*
*     Some Error Checks
*
      IF( itype.LT.1 .OR. itype.GT.3 ) THEN
         result = ten / ulp
         RETURN
      END IF
*
      IF( itype.LE.2 ) THEN
*
*        Tests scaled by the norm(A)
*
         anorm = max( clange( '1', n, n, a, lda, rwork ), unfl )
*
         IF( itype.EQ.1 ) THEN
*
*           ITYPE=1: Compute W = A - U B V**H
*
            CALL clacpy( ' ', n, n, a, lda, work, n )
            CALL cgemm( 'N', 'N', n, n, n, cone, u, ldu, b, ldb, czero,
     $                  work( n**2+1 ), n )
*
            CALL cgemm( 'N', 'C', n, n, n, -cone, work( n**2+1 ), n, v,
     $                  ldv, cone, work, n )
*
         ELSE
*
*           ITYPE=2: Compute W = A - B
*
            CALL clacpy( ' ', n, n, b, ldb, work, n )
*
            DO 20 jcol = 1, n
               DO 10 jrow = 1, n
                  work( jrow+n*( jcol-1 ) ) = work( jrow+n*( jcol-1 ) )
     $                - a( jrow, jcol )
   10          CONTINUE
   20       CONTINUE
         END IF
*
*        Compute norm(W)/ ( ulp*norm(A) )
*
         wnorm = clange( '1', n, n, work, n, rwork )
*
         IF( anorm.GT.wnorm ) THEN
            result = ( wnorm / anorm ) / ( n*ulp )
         ELSE
            IF( anorm.LT.one ) THEN
               result = ( min( wnorm, n*anorm ) / anorm ) / ( n*ulp )
            ELSE
               result = min( wnorm / anorm, real( n ) ) / ( n*ulp )
            END IF
         END IF
*
      ELSE
*
*        Tests not scaled by norm(A)
*
*        ITYPE=3: Compute  U U**H - I
*
         CALL cgemm( 'N', 'C', n, n, n, cone, u, ldu, u, ldu, czero,
     $               work, n )
*
         DO 30 jdiag = 1, n
            work( ( n+1 )*( jdiag-1 )+1 ) = work( ( n+1 )*( jdiag-1 )+
     $         1 ) - cone
   30    CONTINUE
*
         result = min( clange( '1', n, n, work, n, rwork ),
     $            real( n ) ) / ( n*ulp )
      END IF
*
      RETURN
*
*     End of CGET51
*

Here is the call graph for this function:

Here is the caller graph for this function: