drqt02()

subroutine drqt02	(	integer	M,
		integer	N,
		integer	K,
		double precision, dimension( lda, * )	A,
		double precision, dimension( lda, * )	AF,
		double precision, dimension( lda, * )	Q,
		double precision, dimension( lda, * )	R,
		integer	LDA,
		double precision, dimension( * )	TAU,
		double precision, dimension( lwork )	WORK,
		integer	LWORK,
		double precision, dimension( * )	RWORK,
		double precision, dimension( * )	RESULT
	)

DRQT02

Purpose:

 DRQT02 tests DORGRQ, which generates an m-by-n matrix Q with
 orthonornmal rows that is defined as the product of k elementary
 reflectors.

 Given the RQ factorization of an m-by-n matrix A, DRQT02 generates
 the orthogonal matrix Q defined by the factorization of the last k
 rows of A; it compares R(m-k+1:m,n-m+1:n) with
 A(m-k+1:m,1:n)*Q(n-m+1:n,1:n)', and checks that the rows of Q are
 orthonormal.

Parameters

[in]	M	M is INTEGER The number of rows of the matrix Q to be generated. M >= 0.
[in]	N	N is INTEGER The number of columns of the matrix Q to be generated. N >= M >= 0.
[in]	K	K is INTEGER The number of elementary reflectors whose product defines the matrix Q. M >= K >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) The m-by-n matrix A which was factorized by DRQT01.
[in]	AF	AF is DOUBLE PRECISION array, dimension (LDA,N) Details of the RQ factorization of A, as returned by DGERQF. See DGERQF for further details.
[out]	Q	Q is DOUBLE PRECISION array, dimension (LDA,N)
[out]	R	R is DOUBLE PRECISION array, dimension (LDA,M)
[in]	LDA	LDA is INTEGER The leading dimension of the arrays A, AF, Q and L. LDA >= N.
[in]	TAU	TAU is DOUBLE PRECISION array, dimension (M) The scalar factors of the elementary reflectors corresponding to the RQ factorization in AF.
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LWORK)
[in]	LWORK	LWORK is INTEGER The dimension of the array WORK.
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (M)
[out]	RESULT	RESULT is DOUBLE PRECISION array, dimension (2) The test ratios: RESULT(1) = norm( R - A*Q' ) / ( N * norm(A) * EPS ) RESULT(2) = norm( I - Q*Q' ) / ( N * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 138 of file drqt02.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            K, LDA, LWORK, M, N
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), AF( LDA, * ), Q( LDA, * ),
     $                   R( LDA, * ), RESULT( * ), RWORK( * ), TAU( * ),
     $                   WORK( LWORK )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
      DOUBLE PRECISION   ROGUE
      parameter( rogue = -1.0d+10 )
*     ..
*     .. Local Scalars ..
      INTEGER            INFO
      DOUBLE PRECISION   ANORM, EPS, RESID
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE, DLANSY
      EXTERNAL           dlamch, dlange, dlansy
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm, dlacpy, dlaset, dorgrq, dsyrk
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble, max
*     ..
*     .. Scalars in Common ..
      CHARACTER*32       SRNAMT
*     ..
*     .. Common blocks ..
      COMMON             / srnamc / srnamt
*     ..
*     .. Executable Statements ..
*
*     Quick return if possible
*
      IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) THEN
         result( 1 ) = zero
         result( 2 ) = zero
         RETURN
      END IF
*
      eps = dlamch( 'Epsilon' )
*
*     Copy the last k rows of the factorization to the array Q
*
      CALL dlaset( 'Full', m, n, rogue, rogue, q, lda )
      IF( k.LT.n )
     $   CALL dlacpy( 'Full', k, n-k, af( m-k+1, 1 ), lda,
     $                q( m-k+1, 1 ), lda )
      IF( k.GT.1 )
     $   CALL dlacpy( 'Lower', k-1, k-1, af( m-k+2, n-k+1 ), lda,
     $                q( m-k+2, n-k+1 ), lda )
*
*     Generate the last n rows of the matrix Q
*
      srnamt = 'DORGRQ'
      CALL dorgrq( m, n, k, q, lda, tau( m-k+1 ), work, lwork, info )
*
*     Copy R(m-k+1:m,n-m+1:n)
*
      CALL dlaset( 'Full', k, m, zero, zero, r( m-k+1, n-m+1 ), lda )
      CALL dlacpy( 'Upper', k, k, af( m-k+1, n-k+1 ), lda,
     $             r( m-k+1, n-k+1 ), lda )
*
*     Compute R(m-k+1:m,n-m+1:n) - A(m-k+1:m,1:n) * Q(n-m+1:n,1:n)'
*
      CALL dgemm( 'No transpose', 'Transpose', k, m, n, -one,
     $            a( m-k+1, 1 ), lda, q, lda, one, r( m-k+1, n-m+1 ),
     $            lda )
*
*     Compute norm( R - A*Q' ) / ( N * norm(A) * EPS ) .
*
      anorm = dlange( '1', k, n, a( m-k+1, 1 ), lda, rwork )
      resid = dlange( '1', k, m, r( m-k+1, n-m+1 ), lda, rwork )
      IF( anorm.GT.zero ) THEN
         result( 1 ) = ( ( resid / dble( max( 1, n ) ) ) / anorm ) / eps
      ELSE
         result( 1 ) = zero
      END IF
*
*     Compute I - Q*Q'
*
      CALL dlaset( 'Full', m, m, zero, one, r, lda )
      CALL dsyrk( 'Upper', 'No transpose', m, n, -one, q, lda, one, r,
     $            lda )
*
*     Compute norm( I - Q*Q' ) / ( N * EPS ) .
*
      resid = dlansy( '1', 'Upper', m, r, lda, rwork )
*
      result( 2 ) = ( resid / dble( max( 1, n ) ) ) / eps
*
      RETURN
*
*     End of DRQT02
*

Here is the call graph for this function:

Here is the caller graph for this function: