dget03()

subroutine dget03	(	integer	N,
		double precision, dimension( lda, * )	A,
		integer	LDA,
		double precision, dimension( ldainv, * )	AINV,
		integer	LDAINV,
		double precision, dimension( ldwork, * )	WORK,
		integer	LDWORK,
		double precision, dimension( * )	RWORK,
		double precision	RCOND,
		double precision	RESID
	)

DGET03

Purpose:

 DGET03 computes the residual for a general matrix times its inverse:
    norm( I - AINV*A ) / ( N * norm(A) * norm(AINV) * EPS ),
 where EPS is the machine epsilon.

Parameters

[in]	N	N is INTEGER The number of rows and columns of the matrix A. N >= 0.
[in]	A	A is DOUBLE PRECISION array, dimension (LDA,N) The original N x N matrix A.
[in]	LDA	LDA is INTEGER The leading dimension of the array A. LDA >= max(1,N).
[in]	AINV	AINV is DOUBLE PRECISION array, dimension (LDAINV,N) The inverse of the matrix A.
[in]	LDAINV	LDAINV is INTEGER The leading dimension of the array AINV. LDAINV >= max(1,N).
[out]	WORK	WORK is DOUBLE PRECISION array, dimension (LDWORK,N)
[in]	LDWORK	LDWORK is INTEGER The leading dimension of the array WORK. LDWORK >= max(1,N).
[out]	RWORK	RWORK is DOUBLE PRECISION array, dimension (N)
[out]	RCOND	RCOND is DOUBLE PRECISION The reciprocal of the condition number of A, computed as ( 1/norm(A) ) / norm(AINV).
[out]	RESID	RESID is DOUBLE PRECISION norm(I - AINV*A) / ( N * norm(A) * norm(AINV) * EPS )

Author

Univ. of Tennessee

Univ. of California Berkeley

Univ. of Colorado Denver

NAG Ltd.

Date

December 2016

Definition at line 111 of file dget03.f.

*
*  -- LAPACK test routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
*     .. Scalar Arguments ..
      INTEGER            LDA, LDAINV, LDWORK, N
      DOUBLE PRECISION   RCOND, RESID
*     ..
*     .. Array Arguments ..
      DOUBLE PRECISION   A( LDA, * ), AINV( LDAINV, * ), RWORK( * ),
     $                   WORK( LDWORK, * )
*     ..
*
*  =====================================================================
*
*     .. Parameters ..
      DOUBLE PRECISION   ZERO, ONE
      parameter( zero = 0.0d+0, one = 1.0d+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            I
      DOUBLE PRECISION   AINVNM, ANORM, EPS
*     ..
*     .. External Functions ..
      DOUBLE PRECISION   DLAMCH, DLANGE
      EXTERNAL           dlamch, dlange
*     ..
*     .. External Subroutines ..
      EXTERNAL           dgemm
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          dble
*     ..
*     .. Executable Statements ..
*
*     Quick exit if N = 0.
*
      IF( n.LE.0 ) THEN
         rcond = one
         resid = zero
         RETURN
      END IF
*
*     Exit with RESID = 1/EPS if ANORM = 0 or AINVNM = 0.
*
      eps = dlamch( 'Epsilon' )
      anorm = dlange( '1', n, n, a, lda, rwork )
      ainvnm = dlange( '1', n, n, ainv, ldainv, rwork )
      IF( anorm.LE.zero .OR. ainvnm.LE.zero ) THEN
         rcond = zero
         resid = one / eps
         RETURN
      END IF
      rcond = ( one / anorm ) / ainvnm
*
*     Compute I - A * AINV
*
      CALL dgemm( 'No transpose', 'No transpose', n, n, n, -one, ainv,
     $            ldainv, a, lda, zero, work, ldwork )
      DO 10 i = 1, n
         work( i, i ) = one + work( i, i )
   10 CONTINUE
*
*     Compute norm(I - AINV*A) / (N * norm(A) * norm(AINV) * EPS)
*
      resid = dlange( '1', n, n, work, ldwork, rwork )
*
      resid = ( ( resid*rcond ) / eps ) / dble( n )
*
      RETURN
*
*     End of DGET03
*

Here is the call graph for this function:

Here is the caller graph for this function: