LAPACK  3.9.0
LAPACK: Linear Algebra PACKage
ztpmqrt.f
Go to the documentation of this file.
1 *> \brief \b ZTPMQRT
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZTPMQRT + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/ztpmqrt.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/ztpmqrt.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/ztpmqrt.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZTPMQRT( SIDE, TRANS, M, N, K, L, NB, V, LDV, T, LDT,
22 * A, LDA, B, LDB, WORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER SIDE, TRANS
26 * INTEGER INFO, K, LDV, LDA, LDB, M, N, L, NB, LDT
27 * ..
28 * .. Array Arguments ..
29 * COMPLEX*16 V( LDV, * ), A( LDA, * ), B( LDB, * ), T( LDT, * ),
30 * $ WORK( * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> ZTPMQRT applies a complex orthogonal matrix Q obtained from a
40 *> "triangular-pentagonal" complex block reflector H to a general
41 *> complex matrix C, which consists of two blocks A and B.
42 *> \endverbatim
43 *
44 * Arguments:
45 * ==========
46 *
47 *> \param[in] SIDE
48 *> \verbatim
49 *> SIDE is CHARACTER*1
50 *> = 'L': apply Q or Q**H from the Left;
51 *> = 'R': apply Q or Q**H from the Right.
52 *> \endverbatim
53 *>
54 *> \param[in] TRANS
55 *> \verbatim
56 *> TRANS is CHARACTER*1
57 *> = 'N': No transpose, apply Q;
58 *> = 'C': Transpose, apply Q**H.
59 *> \endverbatim
60 *>
61 *> \param[in] M
62 *> \verbatim
63 *> M is INTEGER
64 *> The number of rows of the matrix B. M >= 0.
65 *> \endverbatim
66 *>
67 *> \param[in] N
68 *> \verbatim
69 *> N is INTEGER
70 *> The number of columns of the matrix B. N >= 0.
71 *> \endverbatim
72 *>
73 *> \param[in] K
74 *> \verbatim
75 *> K is INTEGER
76 *> The number of elementary reflectors whose product defines
77 *> the matrix Q.
78 *> \endverbatim
79 *>
80 *> \param[in] L
81 *> \verbatim
82 *> L is INTEGER
83 *> The order of the trapezoidal part of V.
84 *> K >= L >= 0. See Further Details.
85 *> \endverbatim
86 *>
87 *> \param[in] NB
88 *> \verbatim
89 *> NB is INTEGER
90 *> The block size used for the storage of T. K >= NB >= 1.
91 *> This must be the same value of NB used to generate T
92 *> in CTPQRT.
93 *> \endverbatim
94 *>
95 *> \param[in] V
96 *> \verbatim
97 *> V is COMPLEX*16 array, dimension (LDV,K)
98 *> The i-th column must contain the vector which defines the
99 *> elementary reflector H(i), for i = 1,2,...,k, as returned by
100 *> CTPQRT in B. See Further Details.
101 *> \endverbatim
102 *>
103 *> \param[in] LDV
104 *> \verbatim
105 *> LDV is INTEGER
106 *> The leading dimension of the array V.
107 *> If SIDE = 'L', LDV >= max(1,M);
108 *> if SIDE = 'R', LDV >= max(1,N).
109 *> \endverbatim
110 *>
111 *> \param[in] T
112 *> \verbatim
113 *> T is COMPLEX*16 array, dimension (LDT,K)
114 *> The upper triangular factors of the block reflectors
115 *> as returned by CTPQRT, stored as a NB-by-K matrix.
116 *> \endverbatim
117 *>
118 *> \param[in] LDT
119 *> \verbatim
120 *> LDT is INTEGER
121 *> The leading dimension of the array T. LDT >= NB.
122 *> \endverbatim
123 *>
124 *> \param[in,out] A
125 *> \verbatim
126 *> A is COMPLEX*16 array, dimension
127 *> (LDA,N) if SIDE = 'L' or
128 *> (LDA,K) if SIDE = 'R'
129 *> On entry, the K-by-N or M-by-K matrix A.
130 *> On exit, A is overwritten by the corresponding block of
131 *> Q*C or Q**H*C or C*Q or C*Q**H. See Further Details.
132 *> \endverbatim
133 *>
134 *> \param[in] LDA
135 *> \verbatim
136 *> LDA is INTEGER
137 *> The leading dimension of the array A.
138 *> If SIDE = 'L', LDC >= max(1,K);
139 *> If SIDE = 'R', LDC >= max(1,M).
140 *> \endverbatim
141 *>
142 *> \param[in,out] B
143 *> \verbatim
144 *> B is COMPLEX*16 array, dimension (LDB,N)
145 *> On entry, the M-by-N matrix B.
146 *> On exit, B is overwritten by the corresponding block of
147 *> Q*C or Q**H*C or C*Q or C*Q**H. See Further Details.
148 *> \endverbatim
149 *>
150 *> \param[in] LDB
151 *> \verbatim
152 *> LDB is INTEGER
153 *> The leading dimension of the array B.
154 *> LDB >= max(1,M).
155 *> \endverbatim
156 *>
157 *> \param[out] WORK
158 *> \verbatim
159 *> WORK is COMPLEX*16 array. The dimension of WORK is
160 *> N*NB if SIDE = 'L', or M*NB if SIDE = 'R'.
161 *> \endverbatim
162 *>
163 *> \param[out] INFO
164 *> \verbatim
165 *> INFO is INTEGER
166 *> = 0: successful exit
167 *> < 0: if INFO = -i, the i-th argument had an illegal value
168 *> \endverbatim
169 *
170 * Authors:
171 * ========
172 *
173 *> \author Univ. of Tennessee
174 *> \author Univ. of California Berkeley
175 *> \author Univ. of Colorado Denver
176 *> \author NAG Ltd.
177 *
178 *> \date November 2017
179 *
180 *> \ingroup complex16OTHERcomputational
181 *
182 *> \par Further Details:
183 * =====================
184 *>
185 *> \verbatim
186 *>
187 *> The columns of the pentagonal matrix V contain the elementary reflectors
188 *> H(1), H(2), ..., H(K); V is composed of a rectangular block V1 and a
189 *> trapezoidal block V2:
190 *>
191 *> V = [V1]
192 *> [V2].
193 *>
194 *> The size of the trapezoidal block V2 is determined by the parameter L,
195 *> where 0 <= L <= K; V2 is upper trapezoidal, consisting of the first L
196 *> rows of a K-by-K upper triangular matrix. If L=K, V2 is upper triangular;
197 *> if L=0, there is no trapezoidal block, hence V = V1 is rectangular.
198 *>
199 *> If SIDE = 'L': C = [A] where A is K-by-N, B is M-by-N and V is M-by-K.
200 *> [B]
201 *>
202 *> If SIDE = 'R': C = [A B] where A is M-by-K, B is M-by-N and V is N-by-K.
203 *>
204 *> The complex orthogonal matrix Q is formed from V and T.
205 *>
206 *> If TRANS='N' and SIDE='L', C is on exit replaced with Q * C.
207 *>
208 *> If TRANS='C' and SIDE='L', C is on exit replaced with Q**H * C.
209 *>
210 *> If TRANS='N' and SIDE='R', C is on exit replaced with C * Q.
211 *>
212 *> If TRANS='C' and SIDE='R', C is on exit replaced with C * Q**H.
213 *> \endverbatim
214 *>
215 * =====================================================================
216  SUBROUTINE ztpmqrt( SIDE, TRANS, M, N, K, L, NB, V, LDV, T, LDT,
217  $ A, LDA, B, LDB, WORK, INFO )
218 *
219 * -- LAPACK computational routine (version 3.8.0) --
220 * -- LAPACK is a software package provided by Univ. of Tennessee, --
221 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
222 * November 2017
223 *
224 * .. Scalar Arguments ..
225  CHARACTER SIDE, TRANS
226  INTEGER INFO, K, LDV, LDA, LDB, M, N, L, NB, LDT
227 * ..
228 * .. Array Arguments ..
229  COMPLEX*16 V( LDV, * ), A( LDA, * ), B( LDB, * ), T( LDT, * ),
230  $ work( * )
231 * ..
232 *
233 * =====================================================================
234 *
235 * ..
236 * .. Local Scalars ..
237  LOGICAL LEFT, RIGHT, TRAN, NOTRAN
238  INTEGER I, IB, MB, LB, KF, LDAQ, LDVQ
239 * ..
240 * .. External Functions ..
241  LOGICAL LSAME
242  EXTERNAL lsame
243 * ..
244 * .. External Subroutines ..
245  EXTERNAL ztprfb, xerbla
246 * ..
247 * .. Intrinsic Functions ..
248  INTRINSIC max, min
249 * ..
250 * .. Executable Statements ..
251 *
252 * .. Test the input arguments ..
253 *
254  info = 0
255  left = lsame( side, 'L' )
256  right = lsame( side, 'R' )
257  tran = lsame( trans, 'C' )
258  notran = lsame( trans, 'N' )
259 *
260  IF ( left ) THEN
261  ldvq = max( 1, m )
262  ldaq = max( 1, k )
263  ELSE IF ( right ) THEN
264  ldvq = max( 1, n )
265  ldaq = max( 1, m )
266  END IF
267  IF( .NOT.left .AND. .NOT.right ) THEN
268  info = -1
269  ELSE IF( .NOT.tran .AND. .NOT.notran ) THEN
270  info = -2
271  ELSE IF( m.LT.0 ) THEN
272  info = -3
273  ELSE IF( n.LT.0 ) THEN
274  info = -4
275  ELSE IF( k.LT.0 ) THEN
276  info = -5
277  ELSE IF( l.LT.0 .OR. l.GT.k ) THEN
278  info = -6
279  ELSE IF( nb.LT.1 .OR. (nb.GT.k .AND. k.GT.0) ) THEN
280  info = -7
281  ELSE IF( ldv.LT.ldvq ) THEN
282  info = -9
283  ELSE IF( ldt.LT.nb ) THEN
284  info = -11
285  ELSE IF( lda.LT.ldaq ) THEN
286  info = -13
287  ELSE IF( ldb.LT.max( 1, m ) ) THEN
288  info = -15
289  END IF
290 *
291  IF( info.NE.0 ) THEN
292  CALL xerbla( 'ZTPMQRT', -info )
293  RETURN
294  END IF
295 *
296 * .. Quick return if possible ..
297 *
298  IF( m.EQ.0 .OR. n.EQ.0 .OR. k.EQ.0 ) RETURN
299 *
300  IF( left .AND. tran ) THEN
301 *
302  DO i = 1, k, nb
303  ib = min( nb, k-i+1 )
304  mb = min( m-l+i+ib-1, m )
305  IF( i.GE.l ) THEN
306  lb = 0
307  ELSE
308  lb = mb-m+l-i+1
309  END IF
310  CALL ztprfb( 'L', 'C', 'F', 'C', mb, n, ib, lb,
311  $ v( 1, i ), ldv, t( 1, i ), ldt,
312  $ a( i, 1 ), lda, b, ldb, work, ib )
313  END DO
314 *
315  ELSE IF( right .AND. notran ) THEN
316 *
317  DO i = 1, k, nb
318  ib = min( nb, k-i+1 )
319  mb = min( n-l+i+ib-1, n )
320  IF( i.GE.l ) THEN
321  lb = 0
322  ELSE
323  lb = mb-n+l-i+1
324  END IF
325  CALL ztprfb( 'R', 'N', 'F', 'C', m, mb, ib, lb,
326  $ v( 1, i ), ldv, t( 1, i ), ldt,
327  $ a( 1, i ), lda, b, ldb, work, m )
328  END DO
329 *
330  ELSE IF( left .AND. notran ) THEN
331 *
332  kf = ((k-1)/nb)*nb+1
333  DO i = kf, 1, -nb
334  ib = min( nb, k-i+1 )
335  mb = min( m-l+i+ib-1, m )
336  IF( i.GE.l ) THEN
337  lb = 0
338  ELSE
339  lb = mb-m+l-i+1
340  END IF
341  CALL ztprfb( 'L', 'N', 'F', 'C', mb, n, ib, lb,
342  $ v( 1, i ), ldv, t( 1, i ), ldt,
343  $ a( i, 1 ), lda, b, ldb, work, ib )
344  END DO
345 *
346  ELSE IF( right .AND. tran ) THEN
347 *
348  kf = ((k-1)/nb)*nb+1
349  DO i = kf, 1, -nb
350  ib = min( nb, k-i+1 )
351  mb = min( n-l+i+ib-1, n )
352  IF( i.GE.l ) THEN
353  lb = 0
354  ELSE
355  lb = mb-n+l-i+1
356  END IF
357  CALL ztprfb( 'R', 'C', 'F', 'C', m, mb, ib, lb,
358  $ v( 1, i ), ldv, t( 1, i ), ldt,
359  $ a( 1, i ), lda, b, ldb, work, m )
360  END DO
361 *
362  END IF
363 *
364  RETURN
365 *
366 * End of ZTPMQRT
367 *
368  END
ztprfb
subroutine ztprfb(SIDE, TRANS, DIRECT, STOREV, M, N, K, L, V, LDV, T, LDT, A, LDA, B, LDB, WORK, LDWORK)
ZTPRFB applies a real or complex "triangular-pentagonal" blocked reflector to a real or complex matri...
Definition: ztprfb.f:253
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
ztpmqrt
subroutine ztpmqrt(SIDE, TRANS, M, N, K, L, NB, V, LDV, T, LDT, A, LDA, B, LDB, WORK, INFO)
ZTPMQRT
Definition: ztpmqrt.f:218