LAPACK  3.9.0
LAPACK: Linear Algebra PACKage

◆ zlanhe()

double precision function zlanhe ( character  NORM,
character  UPLO,
integer  N,
complex*16, dimension( lda, * )  A,
integer  LDA,
double precision, dimension( * )  WORK 
)

ZLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a complex Hermitian matrix.

Download ZLANHE + dependencies [TGZ] [ZIP] [TXT]

Purpose:
 ZLANHE  returns the value of the one norm,  or the Frobenius norm, or
 the  infinity norm,  or the  element of  largest absolute value  of a
 complex hermitian matrix A.
Returns
ZLANHE 
    ZLANHE = ( max(abs(A(i,j))), NORM = 'M' or 'm'
             (
             ( norm1(A),         NORM = '1', 'O' or 'o'
             (
             ( normI(A),         NORM = 'I' or 'i'
             (
             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'

 where  norm1  denotes the  one norm of a matrix (maximum column sum),
 normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
 normF  denotes the  Frobenius norm of a matrix (square root of sum of
 squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
Parameters
[in]NORM
          NORM is CHARACTER*1
          Specifies the value to be returned in ZLANHE as described
          above.
[in]UPLO
          UPLO is CHARACTER*1
          Specifies whether the upper or lower triangular part of the
          hermitian matrix A is to be referenced.
          = 'U':  Upper triangular part of A is referenced
          = 'L':  Lower triangular part of A is referenced
[in]N
          N is INTEGER
          The order of the matrix A.  N >= 0.  When N = 0, ZLANHE is
          set to zero.
[in]A
          A is COMPLEX*16 array, dimension (LDA,N)
          The hermitian matrix A.  If UPLO = 'U', the leading n by n
          upper triangular part of A contains the upper triangular part
          of the matrix A, and the strictly lower triangular part of A
          is not referenced.  If UPLO = 'L', the leading n by n lower
          triangular part of A contains the lower triangular part of
          the matrix A, and the strictly upper triangular part of A is
          not referenced. Note that the imaginary parts of the diagonal
          elements need not be set and are assumed to be zero.
[in]LDA
          LDA is INTEGER
          The leading dimension of the array A.  LDA >= max(N,1).
[out]WORK
          WORK is DOUBLE PRECISION array, dimension (MAX(1,LWORK)),
          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
          WORK is not referenced.
Author
Univ. of Tennessee
Univ. of California Berkeley
Univ. of Colorado Denver
NAG Ltd.
Date
December 2016

Definition at line 126 of file zlanhe.f.

126 *
127 * -- LAPACK auxiliary routine (version 3.7.0) --
128 * -- LAPACK is a software package provided by Univ. of Tennessee, --
129 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
130 * December 2016
131 *
132  IMPLICIT NONE
133 * .. Scalar Arguments ..
134  CHARACTER NORM, UPLO
135  INTEGER LDA, N
136 * ..
137 * .. Array Arguments ..
138  DOUBLE PRECISION WORK( * )
139  COMPLEX*16 A( LDA, * )
140 * ..
141 *
142 * =====================================================================
143 *
144 * .. Parameters ..
145  DOUBLE PRECISION ONE, ZERO
146  parameter( one = 1.0d+0, zero = 0.0d+0 )
147 * ..
148 * .. Local Scalars ..
149  INTEGER I, J
150  DOUBLE PRECISION ABSA, SUM, VALUE
151 * ..
152 * .. Local Arrays ..
153  DOUBLE PRECISION SSQ( 2 ), COLSSQ( 2 )
154 * ..
155 * .. External Functions ..
156  LOGICAL LSAME, DISNAN
157  EXTERNAL lsame, disnan
158 * ..
159 * .. External Subroutines ..
160  EXTERNAL zlassq, dcombssq
161 * ..
162 * .. Intrinsic Functions ..
163  INTRINSIC abs, dble, sqrt
164 * ..
165 * .. Executable Statements ..
166 *
167  IF( n.EQ.0 ) THEN
168  VALUE = zero
169  ELSE IF( lsame( norm, 'M' ) ) THEN
170 *
171 * Find max(abs(A(i,j))).
172 *
173  VALUE = zero
174  IF( lsame( uplo, 'U' ) ) THEN
175  DO 20 j = 1, n
176  DO 10 i = 1, j - 1
177  sum = abs( a( i, j ) )
178  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
179  10 CONTINUE
180  sum = abs( dble( a( j, j ) ) )
181  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
182  20 CONTINUE
183  ELSE
184  DO 40 j = 1, n
185  sum = abs( dble( a( j, j ) ) )
186  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
187  DO 30 i = j + 1, n
188  sum = abs( a( i, j ) )
189  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
190  30 CONTINUE
191  40 CONTINUE
192  END IF
193  ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
194  $ ( norm.EQ.'1' ) ) THEN
195 *
196 * Find normI(A) ( = norm1(A), since A is hermitian).
197 *
198  VALUE = zero
199  IF( lsame( uplo, 'U' ) ) THEN
200  DO 60 j = 1, n
201  sum = zero
202  DO 50 i = 1, j - 1
203  absa = abs( a( i, j ) )
204  sum = sum + absa
205  work( i ) = work( i ) + absa
206  50 CONTINUE
207  work( j ) = sum + abs( dble( a( j, j ) ) )
208  60 CONTINUE
209  DO 70 i = 1, n
210  sum = work( i )
211  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
212  70 CONTINUE
213  ELSE
214  DO 80 i = 1, n
215  work( i ) = zero
216  80 CONTINUE
217  DO 100 j = 1, n
218  sum = work( j ) + abs( dble( a( j, j ) ) )
219  DO 90 i = j + 1, n
220  absa = abs( a( i, j ) )
221  sum = sum + absa
222  work( i ) = work( i ) + absa
223  90 CONTINUE
224  IF( VALUE .LT. sum .OR. disnan( sum ) ) VALUE = sum
225  100 CONTINUE
226  END IF
227  ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
228 *
229 * Find normF(A).
230 * SSQ(1) is scale
231 * SSQ(2) is sum-of-squares
232 * For better accuracy, sum each column separately.
233 *
234  ssq( 1 ) = zero
235  ssq( 2 ) = one
236 *
237 * Sum off-diagonals
238 *
239  IF( lsame( uplo, 'U' ) ) THEN
240  DO 110 j = 2, n
241  colssq( 1 ) = zero
242  colssq( 2 ) = one
243  CALL zlassq( j-1, a( 1, j ), 1,
244  $ colssq( 1 ), colssq( 2 ) )
245  CALL dcombssq( ssq, colssq )
246  110 CONTINUE
247  ELSE
248  DO 120 j = 1, n - 1
249  colssq( 1 ) = zero
250  colssq( 2 ) = one
251  CALL zlassq( n-j, a( j+1, j ), 1,
252  $ colssq( 1 ), colssq( 2 ) )
253  CALL dcombssq( ssq, colssq )
254  120 CONTINUE
255  END IF
256  ssq( 2 ) = 2*ssq( 2 )
257 *
258 * Sum diagonal
259 *
260  DO 130 i = 1, n
261  IF( dble( a( i, i ) ).NE.zero ) THEN
262  absa = abs( dble( a( i, i ) ) )
263  IF( ssq( 1 ).LT.absa ) THEN
264  ssq( 2 ) = one + ssq( 2 )*( ssq( 1 ) / absa )**2
265  ssq( 1 ) = absa
266  ELSE
267  ssq( 2 ) = ssq( 2 ) + ( absa / ssq( 1 ) )**2
268  END IF
269  END IF
270  130 CONTINUE
271  VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
272  END IF
273 *
274  zlanhe = VALUE
275  RETURN
276 *
277 * End of ZLANHE
278 *
Here is the call graph for this function:
Here is the caller graph for this function:
zlassq
subroutine zlassq(N, X, INCX, SCALE, SUMSQ)
ZLASSQ updates a sum of squares represented in scaled form.
Definition: zlassq.f:108
disnan
logical function disnan(DIN)
DISNAN tests input for NaN.
Definition: disnan.f:61
zlanhe
double precision function zlanhe(NORM, UPLO, N, A, LDA, WORK)
ZLANHE returns the value of the 1-norm, or the Frobenius norm, or the infinity norm,...
Definition: zlanhe.f:126
lsame
logical function lsame(CA, CB)
LSAME
Definition: lsame.f:55
dcombssq
subroutine dcombssq(V1, V2)
DCOMBSSQ adds two scaled sum of squares quantities.
Definition: dcombssq.f:62