LAPACK  3.9.0
LAPACK: Linear Algebra PACKage
zsytrs2.f
Go to the documentation of this file.
1 *> \brief \b ZSYTRS2
2 *
3 * =========== DOCUMENTATION ===========
4 *
5 * Online html documentation available at
6 * http://www.netlib.org/lapack/explore-html/
7 *
8 *> \htmlonly
9 *> Download ZSYTRS2 + dependencies
10 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/zsytrs2.f">
11 *> [TGZ]</a>
12 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/zsytrs2.f">
13 *> [ZIP]</a>
14 *> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/zsytrs2.f">
15 *> [TXT]</a>
16 *> \endhtmlonly
17 *
18 * Definition:
19 * ===========
20 *
21 * SUBROUTINE ZSYTRS2( UPLO, N, NRHS, A, LDA, IPIV, B, LDB,
22 * WORK, INFO )
23 *
24 * .. Scalar Arguments ..
25 * CHARACTER UPLO
26 * INTEGER INFO, LDA, LDB, N, NRHS
27 * ..
28 * .. Array Arguments ..
29 * INTEGER IPIV( * )
30 * COMPLEX*16 A( LDA, * ), B( LDB, * ), WORK( * )
31 * ..
32 *
33 *
34 *> \par Purpose:
35 * =============
36 *>
37 *> \verbatim
38 *>
39 *> ZSYTRS2 solves a system of linear equations A*X = B with a complex
40 *> symmetric matrix A using the factorization A = U*D*U**T or
41 *> A = L*D*L**T computed by ZSYTRF and converted by ZSYCONV.
42 *> \endverbatim
43 *
44 * Arguments:
45 * ==========
46 *
47 *> \param[in] UPLO
48 *> \verbatim
49 *> UPLO is CHARACTER*1
50 *> Specifies whether the details of the factorization are stored
51 *> as an upper or lower triangular matrix.
52 *> = 'U': Upper triangular, form is A = U*D*U**T;
53 *> = 'L': Lower triangular, form is A = L*D*L**T.
54 *> \endverbatim
55 *>
56 *> \param[in] N
57 *> \verbatim
58 *> N is INTEGER
59 *> The order of the matrix A. N >= 0.
60 *> \endverbatim
61 *>
62 *> \param[in] NRHS
63 *> \verbatim
64 *> NRHS is INTEGER
65 *> The number of right hand sides, i.e., the number of columns
66 *> of the matrix B. NRHS >= 0.
67 *> \endverbatim
68 *>
69 *> \param[in,out] A
70 *> \verbatim
71 *> A is COMPLEX*16 array, dimension (LDA,N)
72 *> The block diagonal matrix D and the multipliers used to
73 *> obtain the factor U or L as computed by ZSYTRF.
74 *> Note that A is input / output. This might be counter-intuitive,
75 *> and one may think that A is input only. A is input / output. This
76 *> is because, at the start of the subroutine, we permute A in a
77 *> "better" form and then we permute A back to its original form at
78 *> the end.
79 *> \endverbatim
80 *>
81 *> \param[in] LDA
82 *> \verbatim
83 *> LDA is INTEGER
84 *> The leading dimension of the array A. LDA >= max(1,N).
85 *> \endverbatim
86 *>
87 *> \param[in] IPIV
88 *> \verbatim
89 *> IPIV is INTEGER array, dimension (N)
90 *> Details of the interchanges and the block structure of D
91 *> as determined by ZSYTRF.
92 *> \endverbatim
93 *>
94 *> \param[in,out] B
95 *> \verbatim
96 *> B is COMPLEX*16 array, dimension (LDB,NRHS)
97 *> On entry, the right hand side matrix B.
98 *> On exit, the solution matrix X.
99 *> \endverbatim
100 *>
101 *> \param[in] LDB
102 *> \verbatim
103 *> LDB is INTEGER
104 *> The leading dimension of the array B. LDB >= max(1,N).
105 *> \endverbatim
106 *>
107 *> \param[out] WORK
108 *> \verbatim
109 *> WORK is COMPLEX*16 array, dimension (N)
110 *> \endverbatim
111 *>
112 *> \param[out] INFO
113 *> \verbatim
114 *> INFO is INTEGER
115 *> = 0: successful exit
116 *> < 0: if INFO = -i, the i-th argument had an illegal value
117 *> \endverbatim
118 *
119 * Authors:
120 * ========
121 *
122 *> \author Univ. of Tennessee
123 *> \author Univ. of California Berkeley
124 *> \author Univ. of Colorado Denver
125 *> \author NAG Ltd.
126 *
127 *> \date June 2016
128 *
129 *> \ingroup complex16SYcomputational
130 *
131 * =====================================================================
132  SUBROUTINE zsytrs2( UPLO, N, NRHS, A, LDA, IPIV, B, LDB,
133  $ WORK, INFO )
134 *
135 * -- LAPACK computational routine (version 3.7.0) --
136 * -- LAPACK is a software package provided by Univ. of Tennessee, --
137 * -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
138 * June 2016
139 *
140 * .. Scalar Arguments ..
141  CHARACTER UPLO
142  INTEGER INFO, LDA, LDB, N, NRHS
143 * ..
144 * .. Array Arguments ..
145  INTEGER IPIV( * )
146  COMPLEX*16 A( LDA, * ), B( LDB, * ), WORK( * )
147 * ..
148 *
149 * =====================================================================
150 *
151 * .. Parameters ..
152  COMPLEX*16 ONE
153  parameter( one = (1.0d+0,0.0d+0) )
154 * ..
155 * .. Local Scalars ..
156  LOGICAL UPPER
157  INTEGER I, IINFO, J, K, KP
158  COMPLEX*16 AK, AKM1, AKM1K, BK, BKM1, DENOM
159 * ..
160 * .. External Functions ..
161  LOGICAL LSAME
162  EXTERNAL lsame
163 * ..
164 * .. External Subroutines ..
165  EXTERNAL zscal, zsyconv, zswap, ztrsm, xerbla
166 * ..
167 * .. Intrinsic Functions ..
168  INTRINSIC max
169 * ..
170 * .. Executable Statements ..
171 *
172  info = 0
173  upper = lsame( uplo, 'U' )
174  IF( .NOT.upper .AND. .NOT.lsame( uplo, 'L' ) ) THEN
175  info = -1
176  ELSE IF( n.LT.0 ) THEN
177  info = -2
178  ELSE IF( nrhs.LT.0 ) THEN
179  info = -3
180  ELSE IF( lda.LT.max( 1, n ) ) THEN
181  info = -5
182  ELSE IF( ldb.LT.max( 1, n ) ) THEN
183  info = -8
184  END IF
185  IF( info.NE.0 ) THEN
186  CALL xerbla( 'ZSYTRS2', -info )
187  RETURN
188  END IF
189 *
190 * Quick return if possible
191 *
192  IF( n.EQ.0 .OR. nrhs.EQ.0 )
193  $ RETURN
194 *
195 * Convert A
196 *
197  CALL zsyconv( uplo, 'C', n, a, lda, ipiv, work, iinfo )
198 *
199  IF( upper ) THEN
200 *
201 * Solve A*X = B, where A = U*D*U**T.
202 *
203 * P**T * B
204  k=n
205  DO WHILE ( k .GE. 1 )
206  IF( ipiv( k ).GT.0 ) THEN
207 * 1 x 1 diagonal block
208 * Interchange rows K and IPIV(K).
209  kp = ipiv( k )
210  IF( kp.NE.k )
211  $ CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
212  k=k-1
213  ELSE
214 * 2 x 2 diagonal block
215 * Interchange rows K-1 and -IPIV(K).
216  kp = -ipiv( k )
217  IF( kp.EQ.-ipiv( k-1 ) )
218  $ CALL zswap( nrhs, b( k-1, 1 ), ldb, b( kp, 1 ), ldb )
219  k=k-2
220  END IF
221  END DO
222 *
223 * Compute (U \P**T * B) -> B [ (U \P**T * B) ]
224 *
225  CALL ztrsm('L','U','N','U',n,nrhs,one,a,lda,b,ldb)
226 *
227 * Compute D \ B -> B [ D \ (U \P**T * B) ]
228 *
229  i=n
230  DO WHILE ( i .GE. 1 )
231  IF( ipiv(i) .GT. 0 ) THEN
232  CALL zscal( nrhs, one / a( i, i ), b( i, 1 ), ldb )
233  ELSEIF ( i .GT. 1) THEN
234  IF ( ipiv(i-1) .EQ. ipiv(i) ) THEN
235  akm1k = work(i)
236  akm1 = a( i-1, i-1 ) / akm1k
237  ak = a( i, i ) / akm1k
238  denom = akm1*ak - one
239  DO 15 j = 1, nrhs
240  bkm1 = b( i-1, j ) / akm1k
241  bk = b( i, j ) / akm1k
242  b( i-1, j ) = ( ak*bkm1-bk ) / denom
243  b( i, j ) = ( akm1*bk-bkm1 ) / denom
244  15 CONTINUE
245  i = i - 1
246  ENDIF
247  ENDIF
248  i = i - 1
249  END DO
250 *
251 * Compute (U**T \ B) -> B [ U**T \ (D \ (U \P**T * B) ) ]
252 *
253  CALL ztrsm('L','U','T','U',n,nrhs,one,a,lda,b,ldb)
254 *
255 * P * B [ P * (U**T \ (D \ (U \P**T * B) )) ]
256 *
257  k=1
258  DO WHILE ( k .LE. n )
259  IF( ipiv( k ).GT.0 ) THEN
260 * 1 x 1 diagonal block
261 * Interchange rows K and IPIV(K).
262  kp = ipiv( k )
263  IF( kp.NE.k )
264  $ CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
265  k=k+1
266  ELSE
267 * 2 x 2 diagonal block
268 * Interchange rows K-1 and -IPIV(K).
269  kp = -ipiv( k )
270  IF( k .LT. n .AND. kp.EQ.-ipiv( k+1 ) )
271  $ CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
272  k=k+2
273  ENDIF
274  END DO
275 *
276  ELSE
277 *
278 * Solve A*X = B, where A = L*D*L**T.
279 *
280 * P**T * B
281  k=1
282  DO WHILE ( k .LE. n )
283  IF( ipiv( k ).GT.0 ) THEN
284 * 1 x 1 diagonal block
285 * Interchange rows K and IPIV(K).
286  kp = ipiv( k )
287  IF( kp.NE.k )
288  $ CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
289  k=k+1
290  ELSE
291 * 2 x 2 diagonal block
292 * Interchange rows K and -IPIV(K+1).
293  kp = -ipiv( k+1 )
294  IF( kp.EQ.-ipiv( k ) )
295  $ CALL zswap( nrhs, b( k+1, 1 ), ldb, b( kp, 1 ), ldb )
296  k=k+2
297  ENDIF
298  END DO
299 *
300 * Compute (L \P**T * B) -> B [ (L \P**T * B) ]
301 *
302  CALL ztrsm('L','L','N','U',n,nrhs,one,a,lda,b,ldb)
303 *
304 * Compute D \ B -> B [ D \ (L \P**T * B) ]
305 *
306  i=1
307  DO WHILE ( i .LE. n )
308  IF( ipiv(i) .GT. 0 ) THEN
309  CALL zscal( nrhs, one / a( i, i ), b( i, 1 ), ldb )
310  ELSE
311  akm1k = work(i)
312  akm1 = a( i, i ) / akm1k
313  ak = a( i+1, i+1 ) / akm1k
314  denom = akm1*ak - one
315  DO 25 j = 1, nrhs
316  bkm1 = b( i, j ) / akm1k
317  bk = b( i+1, j ) / akm1k
318  b( i, j ) = ( ak*bkm1-bk ) / denom
319  b( i+1, j ) = ( akm1*bk-bkm1 ) / denom
320  25 CONTINUE
321  i = i + 1
322  ENDIF
323  i = i + 1
324  END DO
325 *
326 * Compute (L**T \ B) -> B [ L**T \ (D \ (L \P**T * B) ) ]
327 *
328  CALL ztrsm('L','L','T','U',n,nrhs,one,a,lda,b,ldb)
329 *
330 * P * B [ P * (L**T \ (D \ (L \P**T * B) )) ]
331 *
332  k=n
333  DO WHILE ( k .GE. 1 )
334  IF( ipiv( k ).GT.0 ) THEN
335 * 1 x 1 diagonal block
336 * Interchange rows K and IPIV(K).
337  kp = ipiv( k )
338  IF( kp.NE.k )
339  $ CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
340  k=k-1
341  ELSE
342 * 2 x 2 diagonal block
343 * Interchange rows K-1 and -IPIV(K).
344  kp = -ipiv( k )
345  IF( k.GT.1 .AND. kp.EQ.-ipiv( k-1 ) )
346  $ CALL zswap( nrhs, b( k, 1 ), ldb, b( kp, 1 ), ldb )
347  k=k-2
348  ENDIF
349  END DO
350 *
351  END IF
352 *
353 * Revert A
354 *
355  CALL zsyconv( uplo, 'R', n, a, lda, ipiv, work, iinfo )
356 *
357  RETURN
358 *
359 * End of ZSYTRS2
360 *
361  END
ztrsm
subroutine ztrsm(SIDE, UPLO, TRANSA, DIAG, M, N, ALPHA, A, LDA, B, LDB)
ZTRSM
Definition: ztrsm.f:182
zsyconv
subroutine zsyconv(UPLO, WAY, N, A, LDA, IPIV, E, INFO)
ZSYCONV
Definition: zsyconv.f:116
xerbla
subroutine xerbla(SRNAME, INFO)
XERBLA
Definition: xerbla.f:62
zswap
subroutine zswap(N, ZX, INCX, ZY, INCY)
ZSWAP
Definition: zswap.f:83
zsytrs2
subroutine zsytrs2(UPLO, N, NRHS, A, LDA, IPIV, B, LDB, WORK, INFO)
ZSYTRS2
Definition: zsytrs2.f:134
zscal
subroutine zscal(N, ZA, ZX, INCX)
ZSCAL
Definition: zscal.f:80