clansp.f

Go to the documentation of this file.

*> \brief \b CLANSP returns the value of the 1-norm, or the Frobenius norm, or the infinity norm, or the element of largest absolute value of a symmetric matrix supplied in packed form.
*
*  =========== DOCUMENTATION ===========
*
* Online html documentation available at
*            http://www.netlib.org/lapack/explore-html/
*
*> \htmlonly
*> Download CLANSP + dependencies
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.tgz?format=tgz&filename=/lapack/lapack_routine/clansp.f">
*> [TGZ]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.zip?format=zip&filename=/lapack/lapack_routine/clansp.f">
*> [ZIP]</a>
*> <a href="http://www.netlib.org/cgi-bin/netlibfiles.txt?format=txt&filename=/lapack/lapack_routine/clansp.f">
*> [TXT]</a>
*> \endhtmlonly
*
*  Definition:
*  ===========
*
*       REAL             FUNCTION CLANSP( NORM, UPLO, N, AP, WORK )
*
*       .. Scalar Arguments ..
*       CHARACTER          NORM, UPLO
*       INTEGER            N
*       ..
*       .. Array Arguments ..
*       REAL               WORK( * )
*       COMPLEX            AP( * )
*       ..
*
*
*> \par Purpose:
*  =============
*>
*> \verbatim
*>
*> CLANSP  returns the value of the one norm,  or the Frobenius norm, or
*> the  infinity norm,  or the  element of  largest absolute value  of a
*> complex symmetric matrix A,  supplied in packed form.
*> \endverbatim
*>
*> \return CLANSP
*> \verbatim
*>
*>    CLANSP = ( max(abs(A(i,j))), NORM = 'M' or 'm'
*>             (
*>             ( norm1(A),         NORM = '1', 'O' or 'o'
*>             (
*>             ( normI(A),         NORM = 'I' or 'i'
*>             (
*>             ( normF(A),         NORM = 'F', 'f', 'E' or 'e'
*>
*> where  norm1  denotes the  one norm of a matrix (maximum column sum),
*> normI  denotes the  infinity norm  of a matrix  (maximum row sum) and
*> normF  denotes the  Frobenius norm of a matrix (square root of sum of
*> squares).  Note that  max(abs(A(i,j)))  is not a consistent matrix norm.
*> \endverbatim
*
*  Arguments:
*  ==========
*
*> \param[in] NORM
*> \verbatim
*>          NORM is CHARACTER*1
*>          Specifies the value to be returned in CLANSP as described
*>          above.
*> \endverbatim
*>
*> \param[in] UPLO
*> \verbatim
*>          UPLO is CHARACTER*1
*>          Specifies whether the upper or lower triangular part of the
*>          symmetric matrix A is supplied.
*>          = 'U':  Upper triangular part of A is supplied
*>          = 'L':  Lower triangular part of A is supplied
*> \endverbatim
*>
*> \param[in] N
*> \verbatim
*>          N is INTEGER
*>          The order of the matrix A.  N >= 0.  When N = 0, CLANSP is
*>          set to zero.
*> \endverbatim
*>
*> \param[in] AP
*> \verbatim
*>          AP is COMPLEX array, dimension (N*(N+1)/2)
*>          The upper or lower triangle of the symmetric matrix A, packed
*>          columnwise in a linear array.  The j-th column of A is stored
*>          in the array AP as follows:
*>          if UPLO = 'U', AP(i + (j-1)*j/2) = A(i,j) for 1<=i<=j;
*>          if UPLO = 'L', AP(i + (j-1)*(2n-j)/2) = A(i,j) for j<=i<=n.
*> \endverbatim
*>
*> \param[out] WORK
*> \verbatim
*>          WORK is REAL array, dimension (MAX(1,LWORK)),
*>          where LWORK >= N when NORM = 'I' or '1' or 'O'; otherwise,
*>          WORK is not referenced.
*> \endverbatim
*
*  Authors:
*  ========
*
*> \author Univ. of Tennessee
*> \author Univ. of California Berkeley
*> \author Univ. of Colorado Denver
*> \author NAG Ltd.
*
*> \date December 2016
*
*> \ingroup complexOTHERauxiliary
*
*  =====================================================================
      REAL             FUNCTION CLANSP( NORM, UPLO, N, AP, WORK )
*
*  -- LAPACK auxiliary routine (version 3.7.0) --
*  -- LAPACK is a software package provided by Univ. of Tennessee,    --
*  -- Univ. of California Berkeley, Univ. of Colorado Denver and NAG Ltd..--
*     December 2016
*
      IMPLICIT NONE
*     .. Scalar Arguments ..
      CHARACTER          norm, uplo
      INTEGER            n
*     ..
*     .. Array Arguments ..
      REAL               work( * )
      COMPLEX            ap( * )
*     ..
*
* =====================================================================
*
*     .. Parameters ..
      REAL               one, zero
      parameter( one = 1.0e+0, zero = 0.0e+0 )
*     ..
*     .. Local Scalars ..
      INTEGER            i, j, k
      REAL               absa, sum, value
*     ..
*     .. Local Arrays ..
      REAL               ssq( 2 ), colssq( 2 )
*     ..
*     .. External Functions ..
      LOGICAL            lsame, sisnan
      EXTERNAL           lsame, sisnan
*     ..
*     .. External Subroutines ..
      EXTERNAL           classq, scombssq
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          abs, aimag, real, sqrt
*     ..
*     .. Executable Statements ..
*
      IF( n.EQ.0 ) THEN
         VALUE = zero
      ELSE IF( lsame( norm, 'M' ) ) THEN
*
*        Find max(abs(A(i,j))).
*
         VALUE = zero
         IF( lsame( uplo, 'U' ) ) THEN
            k = 1
            DO 20 j = 1, n
               DO 10 i = k, k + j - 1
                  sum = abs( ap( i ) )
                  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
   10          CONTINUE
               k = k + j
   20       CONTINUE
         ELSE
            k = 1
            DO 40 j = 1, n
               DO 30 i = k, k + n - j
                  sum = abs( ap( i ) )
                  IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
   30          CONTINUE
               k = k + n - j + 1
   40       CONTINUE
         END IF
      ELSE IF( ( lsame( norm, 'I' ) ) .OR. ( lsame( norm, 'O' ) ) .OR.
     $         ( norm.EQ.'1' ) ) THEN
*
*        Find normI(A) ( = norm1(A), since A is symmetric).
*
         VALUE = zero
         k = 1
         IF( lsame( uplo, 'U' ) ) THEN
            DO 60 j = 1, n
               sum = zero
               DO 50 i = 1, j - 1
                  absa = abs( ap( k ) )
                  sum = sum + absa
                  work( i ) = work( i ) + absa
                  k = k + 1
   50          CONTINUE
               work( j ) = sum + abs( ap( k ) )
               k = k + 1
   60       CONTINUE
            DO 70 i = 1, n
               sum = work( i )
               IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
   70       CONTINUE
         ELSE
            DO 80 i = 1, n
               work( i ) = zero
   80       CONTINUE
            DO 100 j = 1, n
               sum = work( j ) + abs( ap( k ) )
               k = k + 1
               DO 90 i = j + 1, n
                  absa = abs( ap( k ) )
                  sum = sum + absa
                  work( i ) = work( i ) + absa
                  k = k + 1
   90          CONTINUE
               IF( VALUE .LT. sum .OR. sisnan( sum ) ) VALUE = sum
  100       CONTINUE
         END IF
      ELSE IF( ( lsame( norm, 'F' ) ) .OR. ( lsame( norm, 'E' ) ) ) THEN
*
*        Find normF(A).
*        SSQ(1) is scale
*        SSQ(2) is sum-of-squares
*        For better accuracy, sum each column separately.
*
         ssq( 1 ) = zero
         ssq( 2 ) = one
*
*        Sum off-diagonals
*
         k = 2
         IF( lsame( uplo, 'U' ) ) THEN
            DO 110 j = 2, n
               colssq( 1 ) = zero
               colssq( 2 ) = one
               CALL classq( j-1, ap( k ), 1, colssq( 1 ), colssq( 2 ) )
               CALL scombssq( ssq, colssq )
               k = k + j
  110       CONTINUE
         ELSE
            DO 120 j = 1, n - 1
               colssq( 1 ) = zero
               colssq( 2 ) = one
               CALL classq( n-j, ap( k ), 1, colssq( 1 ), colssq( 2 ) )
               CALL scombssq( ssq, colssq )
               k = k + n - j + 1
  120       CONTINUE
         END IF
         ssq( 2 ) = 2*ssq( 2 )
*
*        Sum diagonal
*
         k = 1
         colssq( 1 ) = zero
         colssq( 2 ) = one
         DO 130 i = 1, n
            IF( real( ap( k ) ).NE.zero ) THEN
               absa = abs( real( ap( k ) ) )
               IF( colssq( 1 ).LT.absa ) THEN
                  colssq( 2 ) = one + colssq(2)*( colssq(1) / absa )**2
                  colssq( 1 ) = absa
               ELSE
                  colssq( 2 ) = colssq( 2 ) + ( absa / colssq( 1 ) )**2
               END IF
            END IF
            IF( aimag( ap( k ) ).NE.zero ) THEN
               absa = abs( aimag( ap( k ) ) )
               IF( colssq( 1 ).LT.absa ) THEN
                  colssq( 2 ) = one + colssq(2)*( colssq(1) / absa )**2
                  colssq( 1 ) = absa
               ELSE
                  colssq( 2 ) = colssq( 2 ) + ( absa / colssq( 1 ) )**2
               END IF
            END IF
            IF( lsame( uplo, 'U' ) ) THEN
               k = k + i + 1
            ELSE
               k = k + n - i + 1
            END IF
  130    CONTINUE
         CALL scombssq( ssq, colssq )
         VALUE = ssq( 1 )*sqrt( ssq( 2 ) )
      END IF
*
      clansp = VALUE
      RETURN
*
*     End of CLANSP
*
      END